[gentoo-commits] repo/gentoo:master commit in: sys-kernel/cryptodev/

["Marek Szuba" <marecki@gentoo.org>]

commit:     2d3c92e5d6daa6b96321c3392abc319cc8bb8098
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 22 09:38:26 2017 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Wed Mar 22 09:38:26 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2d3c92e5

sys-kernel/cryptodev: add live ebuild

Requested-By: Corentin Labbe <clabbe.montjoie <AT> gmail.com>

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 sys-kernel/cryptodev/cryptodev-9999.ebuild | 56 ++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/sys-kernel/cryptodev/cryptodev-9999.ebuild b/sys-kernel/cryptodev/cryptodev-9999.ebuild
new file mode 100644
index 00000000000..1576432f236
--- /dev/null
+++ b/sys-kernel/cryptodev/cryptodev-9999.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit linux-info linux-mod
+
+DESCRIPTION="device that allows access to Linux kernel cryptographic drivers"
+HOMEPAGE="http://cryptodev-linux.org/index.html"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://github.com/cryptodev-linux/cryptodev-linux.git"
+	S="${WORKDIR}/${PN}-${PV}"
+else
+	SRC_URI="http://download.gna.org/cryptodev-linux/${PN}-linux-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S=${WORKDIR}/${PN}-linux-${PV}
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="examples"
+
+DEPEND="virtual/linux-sources"
+RDEPEND=""
+#test now compile, but need the module to run
+RESTRICT="test"
+
+MODULE_NAMES="cryptodev(extra:${S})"
+
+pkg_pretend() {
+	if use kernel_linux ; then
+		CONFIG_CHECK="~CRYPTO ~CRYPTO_BLKCIPHER ~CRYPTO_AEAD"
+		check_extra_config
+	fi
+}
+
+pkg_setup() {
+	if use kernel_linux ; then
+		linux-mod_pkg_setup
+	else
+		die "cryptodev ebuild only support linux"
+	fi
+	BUILD_TARGETS="build"
+	export KERNEL_DIR
+}
+
+src_install() {
+	linux-mod_src_install
+	if use examples ; then
+		docinto examples
+		dodoc example/*
+	fi
+	insinto /usr/include/crypto
+	doins crypto/cryptodev.h
+}