[gentoo-commits] proj/gentoo-mate:master commit in: mate-base/mate-applets/

["Ettore Di Giacinto" <mudler@gentoo.org>]

commit:     8bf3dd3202cb420864d488a8016716df08ab8d05
Author:     Ettore Di Giacinto <mudler <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 16 14:05:20 2017 +0000
Commit:     Ettore Di Giacinto <mudler <AT> gentoo <DOT> org>
CommitDate: Thu Mar 16 14:05:20 2017 +0000
URL:        https://gitweb.gentoo.org/proj/gentoo-mate.git/commit/?id=8bf3dd32

mate-base/mate-applets: Version bump to 1.18.0

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 mate-base/mate-applets/Manifest                   |  1 +
 mate-base/mate-applets/mate-applets-1.18.0.ebuild | 97 +++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/mate-base/mate-applets/Manifest b/mate-base/mate-applets/Manifest
index f949587..f36147b 100644
--- a/mate-base/mate-applets/Manifest
+++ b/mate-base/mate-applets/Manifest
@@ -1,3 +1,4 @@
 DIST mate-applets-1.12.1.tar.xz 6816716 SHA256 0a3bc19e59c69eccdcc2342f29b7837563e51fbefdb232ca1884ca23d8f69c99 SHA512 c9acac98df31386b4016d42d3d1fe0e9ddd5e8fccc291269cff73e2a4c0853fabb85a649ee14f4aef3200c0f731c1d95f48aefdb3d8baaf014ad8776c1e94234 WHIRLPOOL 9f3569fcdd610935689a54600153bbbb47ac46100b8689f74d0bc37ac227e129edbf06e6f86e3471f7f40454c37c00291382ccc51e95b3dd2fac008b4e865620
 DIST mate-applets-1.14.1.tar.xz 7151156 SHA256 411dc105afae61b2ee0e3b197ea0a00f8670ceb680dd5a549f8ef586289b9d6a SHA512 f7657a4dbeed5ff161dae33bd915bf868c95626d661b3d7e4eea9b86776f75449c4060c647d9a040ccf8a01556979b62a9b21c988b33e0cd8d5d90fd663a331d WHIRLPOOL 90d13900c8aaed4a08e6d4f55adf600f1da82900f164d9bf5c7a8a6c9e51452668bacbe5e8ae7ee4ccaa156d70121dffefe1c8cce8bd12ad190e5c04d42b1c0e
 DIST mate-applets-1.16.0.tar.xz 7150340 SHA256 adcc895478f5b1e1c5c40f3f20537dcf809e0f06802850b890d323602f16d817 SHA512 606fd39b95083e7cff2ce95e75b4acb0ec1f3d66621a15fa726891c6d6319f7757b92c8c26efd3ee05da9da3dc315b16a3a9089fd4bb8d420816d4728f8545af WHIRLPOOL 8a2145970391e337054b2ab4e3449bcdfe2befeb4a8fdb258a3c4820511ec9849537f950b466098a2c3b53a63c132cfb6f9b6d66dfeca268ddd477aa96ae1a28
+DIST mate-applets-1.18.0.tar.xz 7156636 SHA256 e0d17215183be290d1243369a3fff87e2a86d0782bea132b7526544f550130d7 SHA512 72959dc6005caccacd63cb5415b7a0c7d5e2a8cb363a755fb02a8261b0488a6ba3a72ccf9ff5f15573852142be8a288303d4f0754cb7ce793bba43d464c1da8e WHIRLPOOL 2b10f108c46c44608d8579a61f0e785172157caebf84fb40bdd4a7bdc5a851be78ac05f245f1614fc86109d9f9b6ba07eec85a66def0ab587b25a4f530634848

diff --git a/mate-base/mate-applets/mate-applets-1.18.0.ebuild b/mate-base/mate-applets/mate-applets-1.18.0.ebuild
new file mode 100644
index 0000000..d1b6e71
--- /dev/null
+++ b/mate-base/mate-applets/mate-applets-1.18.0.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit mate python-single-r1
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="Applets for the MATE Desktop and Panel"
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+
+IUSE="X ipv6 policykit +upower"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+#cpupower #593470
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/atk:0
+	>=dev-libs/dbus-glib-0.74:0
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/libmateweather-1.17.0
+	>=dev-libs/libxml2-2.5:2
+	dev-python/pygobject:3
+	>=gnome-base/libgtop-2.12.0:2=
+	>=gnome-extra/gucharmap-3.0:2.90
+	>=mate-base/mate-panel-1.17.0
+	>=net-wireless/wireless-tools-28_pre9:0
+	>=sys-apps/dbus-1.1.2:0
+	<sys-power/cpupower-4.7
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.14:3
+	x11-libs/gtksourceview:3.0
+	>=x11-libs/libnotify-0.7:0
+	x11-libs/libX11:0
+	>=x11-libs/libwnck-3.0:3
+	x11-libs/pango:0
+	virtual/libintl:0
+	policykit? ( >=sys-auth/polkit-0.97:0 )
+	upower? (
+		|| (
+			>=sys-power/upower-0.9.23
+			>=sys-power/upower-pm-utils-0.9.23
+		)
+	)
+	!!net-analyzer/mate-netspeed"
+
+RDEPEND="${COMMON_DEPEND}
+	>=mate-base/mate-settings-daemon-1.6"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.3
+	app-text/rarian:0
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools:0
+	>=dev-util/intltool-0.50.1:*
+	dev-libs/libxslt:0
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+PATCHES=( "${FILESDIR}/${PN}-1.14.1-revert-upstream-cpupower-4.7-fix.patch" )
+
+src_configure() {
+	mate_src_configure \
+		--libexecdir=/usr/libexec/mate-applets \
+		--with-cpufreq-lib=cpupower \
+		$(use_with X x) \
+		$(use_with upower) \
+		$(use_enable ipv6) \
+		$(use_enable policykit polkit)
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	emake check
+}
+
+src_install() {
+	python_fix_shebang invest-applet
+	mate_src_install
+
+	local APPLETS="accessx-status battstat charpick command cpufreq drivemount
+			geyes invest-applet mateweather multiload netspeed stickynotes
+			timerapplet trashapplet"
+
+	for applet in ${APPLETS}; do
+		docinto ${applet}
+
+		for d in AUTHORS ChangeLog NEWS README README.themes TODO; do
+			[ -s ${applet}/${d} ] && dodoc ${applet}/${d}
+		done
+	done
+}