[gentoo-commits] repo/gentoo:master commit in: x11-misc/xmountains/

["David Seifert" <soap@gentoo.org>]

commit:     b4f8b8fae3ad4f7337ca9b8cb1a7a19a559049b2
Author:     Harri Nieminen <moikkis <AT> gmail <DOT> com>
AuthorDate: Thu Mar  2 09:10:01 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Mar  4 15:18:41 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b4f8b8fa

x11-misc/xmountains: EAPI bump 4 -> 6

Package-Manager: Portage-2.3.4, Repoman-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/4098

 x11-misc/xmountains/xmountains-2.9-r1.ebuild | 48 ++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/x11-misc/xmountains/xmountains-2.9-r1.ebuild b/x11-misc/xmountains/xmountains-2.9-r1.ebuild
new file mode 100644
index 00000000000..7bf5d4f892c
--- /dev/null
+++ b/x11-misc/xmountains/xmountains-2.9-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+MY_P=${P/-/_}
+
+DESCRIPTION="Fractal terrains of snow-capped mountains near water"
+HOMEPAGE="https://spbooth.github.io/xmountains/"
+SRC_URI="http://www.epcc.ed.ac.uk/~spb/${PN}/${MY_P}.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND="
+	x11-libs/libX11
+	x11-misc/xbitmaps"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+S=${WORKDIR}
+
+src_prepare() {
+	default
+	# add missing include for strcmp
+	sed -i xmountains.c -e '1a#include <string.h> /* strcmp() */' || die
+	# remove obsolete references to global.*
+	sed -i Makefile.alt README -e 's|global\..||g' || die
+}
+
+src_compile() {
+	emake \
+		-f Makefile.alt \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		${PN}
+}
+
+src_install() {
+	dobin ${PN}
+	newman ${PN}.man ${PN}.1
+	einstalldocs
+}