From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-936278-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id BA645139694
	for <garchives@archives.gentoo.org>; Sat,  4 Mar 2017 12:11:23 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 050BB21C09D;
	Sat,  4 Mar 2017 12:11:23 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id C762521C09D
	for <gentoo-commits@lists.gentoo.org>; Sat,  4 Mar 2017 12:11:22 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 680CB34163C
	for <gentoo-commits@lists.gentoo.org>; Sat,  4 Mar 2017 12:11:21 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 0639F5C0F
	for <gentoo-commits@lists.gentoo.org>; Sat,  4 Mar 2017 12:11:20 +0000 (UTC)
From: "Jeroen Roovers" <jer@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Jeroen Roovers" <jer@gentoo.org>
Message-ID: <1488629477.2a6a39552364f462996fce206b3b1ab34a19c79f.jer@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-analyzer/wireshark/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-analyzer/wireshark/Manifest net-analyzer/wireshark/wireshark-2.2.5.ebuild
X-VCS-Directories: net-analyzer/wireshark/
X-VCS-Committer: jer
X-VCS-Committer-Name: Jeroen Roovers
X-VCS-Revision: 2a6a39552364f462996fce206b3b1ab34a19c79f
X-VCS-Branch: master
Date: Sat,  4 Mar 2017 12:11:20 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: f0ff6010-68b7-41aa-8aaf-c5d3001c9d7e
X-Archives-Hash: eba969121e18d4c929a67c120e2cc506

commit:     2a6a39552364f462996fce206b3b1ab34a19c79f
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  4 12:10:56 2017 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sat Mar  4 12:11:17 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2a6a3955

net-analyzer/wireshark: Version bump.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 net-analyzer/wireshark/Manifest               |   1 +
 net-analyzer/wireshark/wireshark-2.2.5.ebuild | 259 ++++++++++++++++++++++++++
 2 files changed, 260 insertions(+)

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index f2e9ebdf509..07789feccd6 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -1 +1,2 @@
 DIST wireshark-2.2.4.tar.bz2 32336156 SHA256 42a7fb35eed5a32478153e24601a284bb50148b7ba919c3e8452652f4c2a3911 SHA512 f3ff6979fdd1c7cf6abe386ec476fee12045ae6df3c8162568d521532045d5eb6ad689262c38b1766c75c9fc1068f480fcd64f0aa077b3a0ceea7c16dbdabc65 WHIRLPOOL 826f88d9df625809309728c2a60cc90e52d4586b9b933548c9594e9521b8aefb619deac00320f09b2180f97816dd4856aa4439322eb64982adc28c71614fe164
+DIST wireshark-2.2.5.tar.bz2 32297102 SHA256 75dd88d3d6336559e5b0b72077d8a772a988197d571f00029986225fef609ac8 SHA512 c419950683eb399f851e10cc268d541cbd6e75a957f412650fa9564760908864fcd0d5d6c3520e656d93c31cd5f1216a514be154dfa950fcfd2804e66155985e WHIRLPOOL 2c65d7806673adb550dcdd8fa032a4dce8e1087e5c57b132c9ac53d6d93d6fb0da3219573bc2ecb12df7865a9a32a1a28378e03b3e3439853200186d42f18e7d

diff --git a/net-analyzer/wireshark/wireshark-2.2.5.ebuild b/net-analyzer/wireshark/wireshark-2.2.5.ebuild
new file mode 100644
index 00000000000..e6842e6fd3b
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-2.2.5.ebuild
@@ -0,0 +1,259 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils fcaps flag-o-matic multilib qmake-utils user
+
+DESCRIPTION="A network protocol analyzer formerly known as ethereal"
+HOMEPAGE="https://www.wireshark.org/"
+SRC_URI="${HOMEPAGE}download/src/all-versions/${P/_/}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="
+	adns androiddump +caps ciscodump cpu_flags_x86_sse4_2 crypt doc doc-pdf
+	geoip +gtk kerberos lua +netlink +pcap portaudio +qt5 sbc selinux smi
+	libssh randpkt randpktdump sshdump ssl tfshark zlib
+"
+REQUIRED_USE="
+	ciscodump? ( libssh )
+	sshdump? ( libssh )
+	ssl? ( crypt )
+"
+
+S=${WORKDIR}/${P/_/}
+
+CDEPEND="
+	>=dev-libs/glib-2.14:2
+	netlink? ( dev-libs/libnl:3 )
+	adns? ( >=net-dns/c-ares-1.5 )
+	crypt? ( dev-libs/libgcrypt:0 )
+	caps? ( sys-libs/libcap )
+	geoip? ( dev-libs/geoip )
+	gtk? (
+		x11-libs/gdk-pixbuf
+		x11-libs/gtk+:3
+		x11-libs/pango
+		x11-misc/xdg-utils
+	)
+	kerberos? ( virtual/krb5 )
+	libssh? ( >=net-libs/libssh-0.6 )
+	lua? ( >=dev-lang/lua-5.1:* )
+	pcap? ( net-libs/libpcap )
+	portaudio? ( media-libs/portaudio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+		media-libs/speex
+		x11-misc/xdg-utils
+	)
+	sbc? ( media-libs/sbc )
+	smi? ( net-libs/libsmi )
+	ssl? ( net-libs/gnutls:= )
+	zlib? ( sys-libs/zlib !=sys-libs/zlib-1.2.4 )
+"
+# We need perl for `pod2html`.  The rest of the perl stuff is to block older
+# and broken installs. #455122
+DEPEND="
+	${CDEPEND}
+	dev-lang/perl
+	!<virtual/perl-Pod-Simple-3.170
+	!<perl-core/Pod-Simple-3.170
+	doc? (
+		app-doc/doxygen
+		app-text/asciidoc
+		dev-libs/libxml2
+		dev-libs/libxslt
+		doc-pdf? ( dev-java/fop )
+		www-client/lynx
+	)
+	qt5? (
+		dev-qt/linguist-tools:5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+RDEPEND="
+	${CDEPEND}
+	gtk? ( virtual/freedesktop-icon-theme )
+	qt5? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.99.8-qtchooser.patch
+	"${FILESDIR}"/${PN}-2.1.0-sse4_2-r1.patch
+	"${FILESDIR}"/${PN}-99999999-androiddump.patch
+)
+
+pkg_setup() {
+	enewgroup wireshark
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				myconf+=( "--with-ssl" )
+				;;
+		esac
+	fi
+
+	# Enable wireshark binary with any supported GUI toolkit (bug #473188)
+	if use gtk || use qt5; then
+		myconf+=( "--enable-wireshark" )
+	else
+		myconf+=( "--disable-wireshark" )
+	fi
+
+	if ! use qt5; then
+		myconf+=( "--with-qt=no" )
+	fi
+
+	if use qt5; then
+		export QT_MIN_VERSION=5.3.0
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# Hack around inability to disable doxygen/fop doc generation
+	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
+	use doc-pdf || export ac_cv_prog_HAVE_FOP=false
+
+	# dumpcap requires libcap
+	# --disable-profile-build bugs #215806, #292991, #479602
+	econf \
+		$(use androiddump && use pcap && echo --enable-androiddump-use-libpcap=yes) \
+		$(use_enable androiddump) \
+		$(use_enable ciscodump) \
+		$(use_enable randpkt) \
+		$(use_enable randpktdump) \
+		$(use_enable sshdump) \
+		$(use_enable tfshark) \
+		$(use_with adns c-ares) \
+		$(use_with caps libcap) \
+		$(use_with crypt gcrypt) \
+		$(use_with geoip) \
+		$(use_with gtk gtk 3) \
+		$(use_with kerberos krb5) \
+		$(use_with libssh ssh) \
+		$(use_with lua) \
+		$(use_with pcap dumpcap-group wireshark) \
+		$(use_with pcap) \
+		$(use_with portaudio) \
+		$(use_with sbc) \
+		$(use_with smi libsmi) \
+		$(use_with ssl gnutls) \
+		$(use_with zlib) \
+		$(usex cpu_flags_x86_sse4_2 --enable-sse4_2 '') \
+		$(usex netlink --with-libnl=3 --without-libnl) \
+		$(usex qt5 --with-qt=5 '') \
+		$(usex qt5 LRELEASE=$(qt5_get_bindir)/lrelease '') \
+		$(usex qt5 MOC=$(qt5_get_bindir)/moc '') \
+		$(usex qt5 RCC=$(qt5_get_bindir)/rcc '') \
+		$(usex qt5 UIC=$(qt5_get_bindir)/uic '') \
+		--disable-profile-build \
+		--disable-warnings-as-errors \
+		--sysconfdir="${EPREFIX}"/etc/wireshark \
+		${myconf[@]}
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		emake -j1 -C docbook
+		if use doc-pdf; then
+			addpredict "/root/.java"
+			emake -C docbook all-pdf
+		fi
+	fi
+}
+
+src_install() {
+	default
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
+		doc/{randpkt.txt,README*}
+
+	if use doc; then
+		docinto /usr/share/doc/${PF}/html
+		dodoc -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
+		if use doc-pdf; then
+			docinto /usr/share/doc/${PF}/pdf/
+			dodoc docbook/{developer,user}-guide-{a4,us}.pdf docbook/release-notes.pdf
+		fi
+	fi
+
+	# install headers
+	local wsheader
+	for wsheader in \
+		config.h \
+		epan/*.h \
+		epan/crypt/*.h \
+		epan/dfilter/*.h \
+		epan/dissectors/*.h \
+		epan/ftypes/*.h \
+		epan/wmem/*.h \
+		register.h \
+		wiretap/*.h \
+		ws_diag_control.h \
+		ws_symbol_export.h \
+		wsutil/*.h
+	do
+		insinto /usr/include/wireshark/$( dirname ${wsheader} )
+		doins ${wsheader}
+	done
+
+	#with the above this really shouldn't be needed, but things may be looking in wiretap/ instead of wireshark/wiretap/
+	insinto /usr/include/wiretap
+	doins wiretap/wtap.h
+
+	if use gtk || use qt5; then
+		local c d
+		for c in hi lo; do
+			for d in 16 32 48; do
+				insinto /usr/share/icons/${c}color/${d}x${d}/apps
+				newins image/${c}${d}-app-wireshark.png wireshark.png
+			done
+		done
+		for d in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${d}x${d}/mimetypes
+			newins image/WiresharkDoc-${d}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	# Add group for users allowed to sniff.
+	enewgroup wireshark
+
+	if use pcap; then
+		fcaps -o 0 -g wireshark -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the wireshark group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}