From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-936254-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id CF7F3139694
for <garchives@archives.gentoo.org>; Sat, 4 Mar 2017 09:18:40 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 156B3E0C38;
Sat, 4 Mar 2017 09:18:40 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id D8709E0C38
for <gentoo-commits@lists.gentoo.org>; Sat, 4 Mar 2017 09:18:39 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id CB4903416B8
for <gentoo-commits@lists.gentoo.org>; Sat, 4 Mar 2017 09:18:38 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 4418E5BED
for <gentoo-commits@lists.gentoo.org>; Sat, 4 Mar 2017 09:18:37 +0000 (UTC)
From: "Dirkjan Ochtman" <djc@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Dirkjan Ochtman" <djc@gentoo.org>
Message-ID: <1488619109.a6938c624e471212591593bee055a216146df4ae.djc@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-vcs/mercurial/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-vcs/mercurial/Manifest dev-vcs/mercurial/mercurial-4.1.1.ebuild
X-VCS-Directories: dev-vcs/mercurial/
X-VCS-Committer: djc
X-VCS-Committer-Name: Dirkjan Ochtman
X-VCS-Revision: a6938c624e471212591593bee055a216146df4ae
X-VCS-Branch: master
Date: Sat, 4 Mar 2017 09:18:37 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: e5effe87-5b41-4cba-a8b2-afbd77317a6c
X-Archives-Hash: 7011dbd2406e354352fb24445c7f35ef
commit: a6938c624e471212591593bee055a216146df4ae
Author: Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 4 09:18:29 2017 +0000
Commit: Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
CommitDate: Sat Mar 4 09:18:29 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a6938c62
dev-vcs/mercurial: version bump to 4.1.1
Package-Manager: Portage-2.3.3, Repoman-2.3.1
dev-vcs/mercurial/Manifest | 1 +
dev-vcs/mercurial/mercurial-4.1.1.ebuild | 134 +++++++++++++++++++++++++++++++
2 files changed, 135 insertions(+)
diff --git a/dev-vcs/mercurial/Manifest b/dev-vcs/mercurial/Manifest
index e8ed03f1596..0d6e63e339b 100644
--- a/dev-vcs/mercurial/Manifest
+++ b/dev-vcs/mercurial/Manifest
@@ -3,4 +3,5 @@ DIST mercurial-3.9.2.tar.gz 4798958 SHA256 69046a427c05e83097bf0145a1e37975ae0b6
DIST mercurial-4.0.1.tar.gz 4851421 SHA256 6aa4ade93c1b5e11937820880a466ebf1c824086d443cd799fc46e2617250d40 SHA512 145bb80d5dbefb5b770a8d74ce31929fafbd235bb3f641bcaa54b1f5278b2abef4298025152aaba212f639c307741d3aaf75be83e3fc52eaf440c86e4a804459 WHIRLPOOL d1cc3786e16d5a11b7d0a1a10e30190199c72cc281a6e2f3dd9c12829fc967d2b28fce902fb226dfc72531770db042333c5a23565a8c01129fab3a348b11a6f1
DIST mercurial-4.0.2.tar.gz 4852027 SHA256 ae6659dba27508a9a6417d535a89e282d5c8a5ea77b6e00af102822145b06d02 SHA512 774defa1d747a3a12d4ac99873320f8422f62ba163ecff1b628f07a1e95bff11eb35afca0b300374f085d14bd1d5637a543ae533ef840f0c8c1ac113fa14aed9 WHIRLPOOL f5c3fbe60c3a9966e289f684ec2270a5a2ba4fef3ee98025a9ea1e000c599e50293e960f8de46376f1dc8b3f508fa492df2fa22eb6dd5c73c3d2ca6506757bb8
DIST mercurial-4.0.tar.gz 4850316 SHA256 24be080745230840f214d93e9f9fb4e25510f9abbbec2e56fab18543fedc43a7 SHA512 8c1974a00efc4d0bcdaca1ce86a172528de58857ac0a78d8cac5c1182dcdd340c7f0f680c8dba82d384ffd3557abbfbdc2e473b5b0b8f05160bd6dbb915e76e4 WHIRLPOOL b4dad09ee488a2630ba37e4f24454de0d171a5b480bd5d161c28a1ec03f60f05efdc25c66c9626d638becebae1ace420312660f66cc9fbd834efca9824c5fbd6
+DIST mercurial-4.1.1.tar.gz 5132169 SHA256 63571be1202f83c72041eb8ca2a2ebaeda284d2031fd708919fc610589d3359e SHA512 b076336a10d524e85a7eb46e0da7b1b5adb34ca377ec162ebf0b3fc1f3749db10bd9144ce046dda63aa0e6ad65d10e288919d65a88d5a9346b26a47d4b21bd49 WHIRLPOOL a5679e03249dbb840de08ec024afa45f4023b6e001abb0a26960d135aa05ca327e1ee6222c9cdcc99af343168a93f5016346bd19624fd83c608a81dd9f078500
DIST mercurial-4.1.tar.gz 5125009 SHA256 7b33c32cdd1d518bc2e2ae223e6ef63c486cf52e9d01a45b99cf8eab7bea5274 SHA512 02e4aabe47473194961870909d4512a4be6814cccb51b727dfa9a34dd0aa5f92bfad7b03e6b58ce6c7e2531df52dac530f02264df28dcfc801036fe103cd4471 WHIRLPOOL 9fc1bfdc0f1515122edaa0d342427709e4a3aa87dcd6315d33328fed25cb5e6aad143774e294363db33f38dda2aa87c4eb4a785efd55550768abca4422850c1f
diff --git a/dev-vcs/mercurial/mercurial-4.1.1.ebuild b/dev-vcs/mercurial/mercurial-4.1.1.ebuild
new file mode 100644
index 00000000000..0a65710cff2
--- /dev/null
+++ b/dev-vcs/mercurial/mercurial-4.1.1.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads"
+
+inherit bash-completion-r1 elisp-common eutils distutils-r1 flag-o-matic
+
+DESCRIPTION="Scalable distributed SCM"
+HOMEPAGE="https://www.mercurial-scm.org/"
+SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="bugzilla emacs gpg test tk"
+
+RDEPEND="bugzilla? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+ gpg? ( app-crypt/gnupg )
+ tk? ( dev-lang/tk )
+ app-misc/ca-certificates"
+DEPEND="emacs? ( virtual/emacs )
+ test? ( app-arch/unzip
+ dev-python/pygments[${PYTHON_USEDEP}] )"
+
+SITEFILE="70${PN}-gentoo.el"
+
+PATCHES=( "${FILESDIR}/${PN}-3.0.1-po_fixes.patch" )
+
+python_prepare_all() {
+ # fix up logic that won't work in Gentoo Prefix (also won't outside in
+ # certain cases), bug #362891
+ sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+ strip-flags -ftracer -ftree-vectorize
+ # Note: make it impl-conditional if py3 is supported
+ append-flags -fno-strict-aliasing
+
+ "${PYTHON}" setup.py build_mo || die
+}
+
+python_compile_all() {
+ rm -r contrib/{win32,macosx} || die
+ if use emacs; then
+ cd contrib || die
+ elisp-compile mercurial.el || die "elisp-compile failed!"
+ fi
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ newbashcomp contrib/bash_completion hg
+
+ insinto /usr/share/zsh/site-functions
+ newins contrib/zsh_completion _hg
+
+ rm -f doc/*.?.txt
+ dodoc CONTRIBUTORS
+ cp hgweb*.cgi "${ED}"/usr/share/doc/${PF}/ || die
+
+ dobin hgeditor
+ dobin contrib/hgk
+ python_foreach_impl python_doscript contrib/hg-ssh
+
+ if use emacs; then
+ elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
+ elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+ fi
+
+ local RM_CONTRIB=(hgk hg-ssh bash_completion zsh_completion wix buildrpm plan9
+ *.el mercurial.spec)
+ for f in ${RM_CONTRIB[@]}; do
+ rm -r contrib/$f || die
+ done
+
+ dodoc -r contrib
+ docompress -x /usr/share/doc/${PF}/contrib
+ doman doc/*.?
+
+ insinto /etc/mercurial/hgrc.d
+ doins "${FILESDIR}/cacerts.rc"
+}
+
+src_test() {
+ pushd tests &>/dev/null || die
+ rm -rf *svn* # Subversion tests fail with 1.5
+ rm -f test-archive* # Fails due to verbose tar output changes
+ rm -f test-convert-baz* # GNU Arch baz
+ rm -f test-convert-cvs* # CVS
+ rm -f test-convert-darcs* # Darcs
+ rm -f test-convert-git* # git
+ rm -f test-convert-mtn* # monotone
+ rm -f test-convert-tla* # GNU Arch tla
+ #rm -f test-doctest* # doctest always fails with python 2.5.x
+ rm -f test-largefiles* # tends to time out
+
+ popd &>/dev/null || die
+ distutils-r1_src_test
+}
+
+python_test() {
+ local TEST_DIR
+
+ rm -rf "${TMPDIR}"/test
+ distutils_install_for_testing
+ cd tests || die
+ "${PYTHON}" run-tests.py --verbose \
+ --tmpdir="${TMPDIR}"/test \
+ --with-hg="${TEST_DIR}"/scripts/hg \
+ || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ elog "If you want to convert repositories from other tools using convert"
+ elog "extension please install correct tool:"
+ elog " dev-vcs/cvs"
+ elog " dev-vcs/darcs"
+ elog " dev-vcs/git"
+ elog " dev-vcs/monotone"
+ elog " dev-vcs/subversion"
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}