[gentoo-commits] repo/gentoo:master commit in: x11-misc/macopix/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     5f1d0abb93f66bb347deea1dc4c844811293b1b2
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 22 10:48:14 2017 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Wed Feb 22 10:48:39 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5f1d0abb

x11-misc/macopix: Ignore windres (bug #560622).

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 x11-misc/macopix/macopix-1.7.4-r1.ebuild | 87 ++++++++++++++++++++++++++++++++
 1 file changed, 87 insertions(+)

diff --git a/x11-misc/macopix/macopix-1.7.4-r1.ebuild b/x11-misc/macopix/macopix-1.7.4-r1.ebuild
new file mode 100644
index 0000000000..6392b64eef
--- /dev/null
+++ b/x11-misc/macopix/macopix-1.7.4-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit flag-o-matic
+
+DESCRIPTION="MaCoPiX (Mascot Constructive Pilot for X) is a desktop mascot application"
+HOMEPAGE="http://rosegray.sakura.ne.jp/macopix/index-e.html"
+
+BASE_URI="http://rosegray.sakura.ne.jp/macopix"
+SRC_URI="${BASE_URI}/${P}.tar.bz2"
+
+# NOTE: These mascots are not redistributable on commercial CD-ROM.
+# The author granted to use them under Gentoo Linux.
+MY_MASCOTS="
+	macopix-mascot-HxB-euc-ja-0.30
+	macopix-mascot-marimite-euc-ja-2.20
+	macopix-mascot-cosmos-euc-ja-1.02
+	macopix-mascot-mizuiro-euc-ja-1.02
+	macopix-mascot-pia2-euc-ja-1.02
+	macopix-mascot-tsukihime-euc-ja-1.02
+	macopix-mascot-triangle_heart-euc-ja-1.02
+	macopix-mascot-comic_party-euc-ja-1.02
+	macopix-mascot-kanon-euc-ja-1.02
+	macopix-mascot-one-euc-ja-1.02
+"
+
+for i in ${MY_MASCOTS} ; do
+	SRC_URI="${SRC_URI} ${BASE_URI}/${i}.tar.gz"
+done
+
+# programme itself is GPL-2, and mascots are free-noncomm
+LICENSE="GPL-2 free-noncomm"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gnutls nls"
+
+RDEPEND="
+	dev-libs/glib:2
+	media-libs/libpng:0=
+	x11-libs/gtk+:2
+	nls? ( >=sys-devel/gettext-0.10 )
+	gnutls? ( net-libs/gnutls )
+	!gnutls? ( dev-libs/openssl:0= )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	sed -i -e 's|HAVE_WINDRES_TRUE|HAVE_WINDRES_FALSE|g' src/Makefile.in || die
+
+	append-libs -lX11
+}
+
+src_configure() {
+	econf \
+		--with-gtk2 \
+		$(use_enable nls) \
+		$(use_with gnutls)
+}
+
+src_install() {
+	default
+
+	dodoc AUTHORS ChangeLog* NEWS *README*
+
+	# install mascots
+	for d in ${MY_MASCOTS} ; do
+		einfo "Installing ${d}..."
+		cd "${WORKDIR}/${d}" || die
+		insinto /usr/share/"${PN}"
+		for i in *.mcpx *.menu ; do
+			doins "$i" || die
+		done
+		insinto /usr/share/"${PN}"/pixmap
+		for i in *.png ; do
+			doins "$i"
+		done
+		docinto "${d}"
+		dodoc README.jp
+	done
+}