[gentoo-commits] repo/gentoo:master commit in: media-sound/mpd/files/, media-sound/mpd/

["Robin H. Johnson" <robbat2@gentoo.org>]

commit:     85a7d334d007da5ceda79b67a21326066c06def8
Author:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 16 20:27:04 2017 +0000
Commit:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
CommitDate: Fri Feb 17 00:50:03 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=85a7d334

media-sound/mpd: bump.

Package-Manager: portage-2.3.2

 media-sound/mpd/Manifest                   |   1 +
 media-sound/mpd/files/mpd-0.20.4.init      |  33 ++++
 media-sound/mpd/files/mpd-0.20.4.logrotate |   6 +
 media-sound/mpd/mpd-0.20.4.ebuild          | 254 +++++++++++++++++++++++++++++
 4 files changed, 294 insertions(+)

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index f64143d00a..279658485f 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -1,2 +1,3 @@
 DIST mpd-0.19.19.tar.xz 707356 SHA256 bc856cda4136403446d53d11576f86990b61d1fe4668f6008e9eae47450d4e1d SHA512 949bfab2aa5dffb4089ce2023accc934648091d36768f8e4c75f62b4038e21db1e2ef3bb07a0f1cf6a91d0532cac8e7146be948d84dc4d7cdc5b252b7d815b64 WHIRLPOOL 1b2c68d998a26de41bca25cbeab0c6478406c831ac4322162d2c258622224137a1a2dcd88b690ee1869c7f2652201fd534ee773a6e51f6e61bdb5926783f4d75
 DIST mpd-0.19.21.tar.xz 708512 SHA256 8305b8bc026f4b6bde28b8dd09bfdddbe5590acf36358eed4d083a396e301730 SHA512 a65690012a74def273ffb4e87465d8f3f7f2ce6f6e9117e35aa0891cd638f904df0ef4c4923c39e9a0c3e1d93d09aab713979adf5c191b54fa7e8b5b81abd232 WHIRLPOOL 397bc2158591137ab8a30e3377458dcef0ea600e218723831977ea7ec9f5b14ae1221b2b7456daa9e249b3aa95c61f7a1f0742656ace42c837e28892dd3d7604
+DIST mpd-0.20.4.tar.xz 770132 SHA256 712b25351c12616630c580204e1c3dcba3ae2993a56cff1c346c87e334d69728 SHA512 d0c01ae6a3fd59e5ccdc24225bd9bb9e63620f1a395d317573499cc045de81f2abd803ca87eb1b2ca1d26d25167aaa6f5523e96f9512619272b857190efa0a72 WHIRLPOOL 9446b7096c6d2eb41a9421ad8e58e7a70a66e7abb381e75edabf0718c0098646e82ca16d7157e6c453836825eb03a2eca09ff7f80e95918718e42da85ae30c9e

diff --git a/media-sound/mpd/files/mpd-0.20.4.init b/media-sound/mpd/files/mpd-0.20.4.init
new file mode 100644
index 0000000000..e7f99fdf48
--- /dev/null
+++ b/media-sound/mpd/files/mpd-0.20.4.init
@@ -0,0 +1,33 @@
+#!/sbin/openrc-run
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+: CFGFILE=${CFGFILE:=/etc/mpd.conf}
+
+depend() {
+	need localmount
+	use net netmount nfsmount alsasound esound pulseaudio
+	config ${CFGFILE}
+}
+
+get_config() {
+	x=$1
+	test -e ${CFGFILE} || return 1
+	sed -n \
+	  -e '/^[ \t]*'${x}'/{s:^[ \t]*'${x}'[ \t]\+"\?\([^#"]\+\)[^"]*"\?$:\1: ; p }' \
+	  ${CFGFILE}
+}
+
+extra_started_commands='reload'
+command=/usr/bin/mpd
+command_args=${opts:=${CFGFILE}}
+required_files=${CFGFILE}
+pidfile=$(get_config pid_file)
+description="Music Player Daemon"
+
+reload() {
+	ebegin "Reloading ${SVCNAME}"
+	kill -HUP `cat ${pidfile}`
+	eend $?
+}

diff --git a/media-sound/mpd/files/mpd-0.20.4.logrotate b/media-sound/mpd/files/mpd-0.20.4.logrotate
new file mode 100644
index 0000000000..ff47d1098c
--- /dev/null
+++ b/media-sound/mpd/files/mpd-0.20.4.logrotate
@@ -0,0 +1,6 @@
+/var/lib/mpd/log {
+	missingok
+	postrotate
+	/etc/init.d/mpd reload
+	endscript
+}

diff --git a/media-sound/mpd/mpd-0.20.4.ebuild b/media-sound/mpd/mpd-0.20.4.ebuild
new file mode 100644
index 0000000000..964f5fe22d
--- /dev/null
+++ b/media-sound/mpd/mpd-0.20.4.ebuild
@@ -0,0 +1,254 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic linux-info multilib systemd user
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~x64-macos"
+IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug +eventfd expat faad
+	+fifo +ffmpeg flac fluidsynth +glib gme +icu +id3tag +inotify +ipv6 jack
+	lame mms libav libmpdclient libsamplerate libsoxr +mad mikmod modplug
+	mpg123 musepack +network nfs ogg openal opus oss pipe pulseaudio recorder
+	samba selinux sid +signalfd sndfile soundcloud sqlite systemd tcpd twolame
+	unicode upnp vorbis wavpack wildmidi zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
+DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	ao? ( glib )
+	gme? ( glib )
+	jack? ( glib )
+	network? ( || ( ${ENCODER_PLUGINS} )
+		glib )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	sid? ( glib )
+	soundcloud? ( glib )
+	sqlite? ( glib )
+	opus? ( ogg )
+	upnp? ( expat )
+	vorbis? ( glib )
+	wavpack? ( glib )"
+
+CDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	adplug? ( media-libs/adplug )
+	alsa? ( media-sound/alsa-utils
+		media-libs/alsa-lib )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio-paranoia )
+	curl? ( net-misc/curl )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	glib? ( dev-libs/glib:2 )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? ( dev-libs/icu:= )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	network? ( >=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
+	nfs? ( net-fs/libnfs )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( || ( <net-fs/samba-4.0.25[smbclient] >=net-fs/samba-4.0.25 ) )
+	sid? ( || ( media-libs/libsidplay:2 media-libs/libsidplayfp ) )
+	sndfile? ( media-libs/libsndfile )
+	soundcloud? ( >=dev-libs/yajl-2 )
+	libsoxr? ( media-libs/soxr )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	upnp? ( net-libs/libupnp )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${CDEPEND}
+	dev-libs/boost
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-mpd )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.18.conf.patch
+	#"${FILESDIR}"/${PN}-0.9.15-systemd.patch # bug 584742, merged upstream
+)
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make
+		sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local mpdconf="--enable-database --disable-roar --disable-documentation
+		--enable-dsd --enable-largefile --disable-osx --disable-shine-encoder
+		--disable-solaris-output --enable-tcp --enable-un --disable-werror
+		--docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use samba || use upnp; then
+		mpdconf+=" --enable-neighbor-plugins"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	econf \
+		$(use_enable eventfd)		\
+		$(use_enable signalfd)		\
+		$(use_enable libmpdclient)	\
+		$(use_enable expat)			\
+		$(use_enable upnp)			\
+		$(use_enable adplug)		\
+		$(use_enable alsa)			\
+		$(use_enable ao)			\
+		$(use_enable audiofile)		\
+		$(use_enable zlib)			\
+		$(use_enable bzip2)			\
+		$(use_enable cdio cdio-paranoia) \
+		$(use_enable curl)			\
+		$(use_enable samba smbclient) \
+		$(use_enable nfs)			\
+		$(use_enable debug)			\
+		$(use_enable ffmpeg)		\
+		$(use_enable fifo)			\
+		$(use_enable flac)			\
+		$(use_enable fluidsynth)	\
+		$(use_enable gme)			\
+		$(use_enable id3tag id3)	\
+		$(use_enable inotify)		\
+		$(use_enable ipv6)			\
+		$(use_enable cdio iso9660)	\
+		$(use_enable jack)			\
+		$(use_enable soundcloud)	\
+		$(use_enable tcpd libwrap)	\
+		$(use_enable libsamplerate lsr) \
+		$(use_enable libsoxr soxr)	\
+		$(use_enable mad)			\
+		$(use_enable mikmod)		\
+		$(use_enable mms)			\
+		$(use_enable modplug)		\
+		$(use_enable musepack mpc)	\
+		$(use_enable mpg123)		\
+		$(use_enable openal)		\
+		$(use_enable opus)			\
+		$(use_enable oss)			\
+		$(use_enable pipe pipe-output) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable recorder recorder-output) \
+		$(use_enable sid sidplay)	\
+		$(use_enable sndfile sndfile) \
+		$(use_enable sqlite)		\
+		$(use_enable systemd) \
+		$(use_enable vorbis)		\
+		$(use_enable wavpack)		\
+		$(use_enable wildmidi)		\
+		$(use_enable zip zzip)		\
+		$(use_enable icu)			\
+		$(use_enable glib)			\
+		$(use_enable faad aac)		\
+		$(use_with zeroconf zeroconf avahi) \
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir) \
+		--with-systemduserunitdir=$(systemd_get_userunitdir) \
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/${PN}-0.20.4.init ${PN}
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${ED}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-0.20.4.logrotate ${PN}
+
+	use prefix || diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}