[gentoo-commits] repo/gentoo:master commit in: xfce-base/thunar/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1f88f4dd70503d71c36ab7a67d4993e21a525948
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 16 20:24:27 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Feb 16 21:06:17 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f88f4dd

xfce-base/thunar: Bump to 1.6.11, EAPI=6

 xfce-base/thunar/Manifest             |  1 +
 xfce-base/thunar/thunar-1.6.11.ebuild | 68 +++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/xfce-base/thunar/Manifest b/xfce-base/thunar/Manifest
index cd3259d2e8..a2d06cdd9a 100644
--- a/xfce-base/thunar/Manifest
+++ b/xfce-base/thunar/Manifest
@@ -1 +1,2 @@
 DIST Thunar-1.6.10.tar.bz2 1948762 SHA256 7e9d24067268900e5e44d3325e60a1a2b2f8f556ec238ec12574fbea15fdee8a SHA512 56f9407907c85a631b390b6bf363ee863b5a126afc32e1b10e34434b997e82b86223737a0b0a1a8faf801258ad1cfa0585c9c3537c167f6968a2c4dac458395a WHIRLPOOL 813e3a1628227fbe27d221739e4946aa38b147ff4b165ff915b6a57b38ae544f54dc8facf19af0519fac5e903924459a34b6372c42985ed00e997e02434f4b71
+DIST Thunar-1.6.11.tar.bz2 1929426 SHA256 b1c7c3121827f59610900ef1cc19aa10a50ab2cc3ae38eee15181b64256e8b42 SHA512 05cdce5bb741f2d7a6ddb2f7d30dac4dc4ff539e41963b31b7f694e69be5b8ae211c442e943dc8745f8c0a634f2eb18734b7a3ea8c9c7d380c1af87a01b64e03 WHIRLPOOL c4c69c30545a9a5e14fadbd48058be13a93bc5c823311483489022fc9c9a6d0af4639bbd9cb3c8692cb830bfd4cbba9e09aa028385aeba2c7f47f84e19f7c383

diff --git a/xfce-base/thunar/thunar-1.6.11.ebuild b/xfce-base/thunar/thunar-1.6.11.ebuild
new file mode 100644
index 0000000000..a135b99723
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.6.11.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit virtualx
+
+MY_P=${P^}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/ http://thunar.xfce.org/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus exif libnotify pcre test udisks +xfce_plugins_trash"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30:=
+	>=x11-libs/gdk-pixbuf-2.14:=
+	>=x11-libs/gtk+-2.24:2=
+	>=xfce-base/exo-0.10:=
+	>=xfce-base/libxfce4ui-4.10:=
+	>=xfce-base/libxfce4util-4.10.1:=
+	>=xfce-base/xfconf-4.10:=
+	dbus? ( >=dev-libs/dbus-glib-0.100:= )
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	udisks? ( virtual/libgudev:= )
+	xfce_plugins_trash? ( >=xfce-base/xfce4-panel-4.10:= )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	dbus? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)
+	xfce_plugins_trash? ( ${GVFS_DEPEND} )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+REQUIRED_USE="xfce_plugins_trash? ( dbus )"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable dbus)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable xfce_plugins_trash tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	virtx emake check
+}