[gentoo-commits] repo/gentoo:master commit in: net-mail/notmuch/

["Amadeusz Piotr Żołnowski" <aidecoe@gentoo.org>]

commit:     31feae51923c224e818eb1e3601817a08bcf6a13
Author:     Amadeusz Żołnowski <aidecoe <AT> gentoo <DOT> org>
AuthorDate: Sun Feb  5 10:30:55 2017 +0000
Commit:     Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo <DOT> org>
CommitDate: Sun Feb  5 11:17:27 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=31feae51

net-mail/notmuch: Remove older patch version

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 net-mail/notmuch/Manifest              |   1 -
 net-mail/notmuch/notmuch-0.23.4.ebuild | 201 ---------------------------------
 2 files changed, 202 deletions(-)

diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index b43ef2d..e5fb63d 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -2,5 +2,4 @@ DIST database-v1.tar.xz 204876 SHA256 4299e051b10e1fa7b33ea2862790a09ebfe9685968
 DIST notmuch-0.21.tar.gz 663600 SHA256 d06f8ffed168c7d53ffc449dd611038b5fa90f7ee22d58f3bec3b379571e25b3 SHA512 2485c422433be21f6bf89aaf997e1468c31a52029ddc8336e78a632b292c659569448c29813ea550ed27fb6815558522a451a7fa10e8fb3f87d9538b4dd7b01a WHIRLPOOL 303c6427822272834e3d95ac94760f0fbaf3f2947a984a6770a9b2918fe0fbad289ef95fb9a8300cb6db08ab3ef0ff56810b3a60879c6a2a3eac524689f0a2f0
 DIST notmuch-0.22.2.tar.gz 683796 SHA256 6cd19c61634079981b2d8f4b7cb4eb953cba2a36272520603682d813d2bd7ed1 SHA512 cc11feb8d1c2c7959a42e032c1e36e828290a8e8477af8936a27654117fbc2e080c71fe69ec92bd80763d9d3b163d45b7c0fa9fe9c4ec649600fa928110da4ee WHIRLPOOL 6aa41fa26a92a11393193b6f7e147b69de00f57fe712486805b2b7019d9bf9887d6d10962ef4144ca9ef07d6f63bbb1ddb2f7104c6eb89841285620d439743be
 DIST notmuch-0.23.3.tar.gz 691361 SHA256 0f5da5cf0203b774e345c50d56e975a87c2fc5407ef4ea284b6e2b55a8951882 SHA512 232a4133d70d074e6d38b00471145ecec342a5e138822cce01b6915e2b3de29fc1181e116d1df30e2fea04d519f53297fd8ea0e9d0df91bc8d6fce549feed1e3 WHIRLPOOL 82c30f3137132504ed41c42619c3645b74680d01a835e6074122b6ff3ab8d1a5dfe138a583872d09ea9f70a7312021fafa1bd2c08c3b6b9a319f55e5c81f28ff
-DIST notmuch-0.23.4.tar.gz 691851 SHA256 106dd6e39c4955871a49a84488d06394c1cecf66c1542b11834f8e8d5c66453b SHA512 a90dcb822a01c1a8e07a3fce6c63f210af482e34cbf329fd56db3ea4934e7950ec641c060104729373fc3fc0b42eb1e2937f653f3a42ddae7e7e15e9927c3dff WHIRLPOOL 3f916356896f1e23a286d8c4207c869ded9b766781fd625ad90c1a24d0fcb8f15bb5c09013424080e382afa69ba59443f394878346696c4f6ff0e91fcdf2cbd1
 DIST notmuch-0.23.5.tar.gz 691921 SHA256 c62694b3c5f04db48ed3bbf37a801ea2a03439826c6be318e23b34de749ac267 SHA512 703b685737c779008484a1a5064a0a6b4c93d0c20c48a9c417e0a471b8807f5ee3151a67f0161eb6b376dce56ab42a285dd80532ec9ff79451e982a7c0f25fa1 WHIRLPOOL 687fa8939970124b21cb0725681f2a98c326ee803bf38f0d38d8d8ec1f0e40e99f7be1f72c3bdb721deb4ccc2fecb32bef2067a5baa7b0572a9de2c7d80c51aa

diff --git a/net-mail/notmuch/notmuch-0.23.4.ebuild b/net-mail/notmuch/notmuch-0.23.4.ebuild
deleted file mode 100644
index b448318..00000000
--- a/net-mail/notmuch/notmuch-0.23.4.ebuild
+++ /dev/null
@@ -1,201 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=6
-
-DISTUTILS_OPTIONAL=1
-PYTHON_COMPAT=( python{2_7,3_4} )
-
-inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
-	distutils-r1 toolchain-funcs
-
-DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
-HOMEPAGE="http://notmuchmail.org/"
-SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz
-	test? ( ${HOMEPAGE%/}/releases/test-databases/database-v1.tar.xz )"
-
-LICENSE="GPL-3"
-# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y.  Bump of Y is
-# meant to be binary backward compatible.
-SLOT="0/4"
-KEYWORDS="~alpha ~amd64 ~x86"
-REQUIRED_USE="
-	nmbug? ( python )
-	python? ( ${PYTHON_REQUIRED_USE} )
-	test? ( crypt emacs python valgrind )
-	"
-IUSE="crypt doc emacs mutt nmbug python test valgrind"
-
-CDEPEND="
-	>=app-shells/bash-completion-1.9
-	>=dev-libs/glib-2.22:2
-	>=dev-libs/gmime-2.6.20-r2:2.6
-	>=dev-libs/xapian-1.2.7-r2:=
-	dev-python/sphinx[${PYTHON_USEDEP}]
-	>=sys-libs/zlib-1.2.5.2
-	sys-libs/talloc
-	crypt? ( >=dev-libs/gmime-2.6.20-r2:2.6[smime] )
-	emacs? ( >=virtual/emacs-23 )
-	python? ( ${PYTHON_DEPS} )
-	"
-DEPEND="${CDEPEND}
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )
-	test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
-		>=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb
-		crypt? ( app-crypt/gnupg dev-libs/openssl ) )
-	valgrind? ( dev-util/valgrind )
-	"
-RDEPEND="${CDEPEND}
-	crypt? ( app-crypt/gnupg )
-	nmbug? ( dev-vcs/git )
-	mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
-		dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
-		virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
-		virtual/perl-Pod-Parser )
-	"
-
-DOCS=( AUTHORS NEWS README )
-SITEFILE="50${PN}-gentoo.el"
-MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
-
-bindings() {
-	local ret=0
-
-	if use $1; then
-		pushd bindings/$1 || die
-		shift
-		"$@"
-		ret=$?
-		popd || die
-	fi
-
-	return $ret
-}
-
-pkg_pretend() {
-	if has_version '<net-mail/notmuch-0.18'; then
-		ewarn
-		ewarn "There are few not backward compatible changes between"
-		ewarn "<notmuch-0.18 and >=notmuch-0.18.  See NEWS file"
-		ewarn "(0.18 section) for details before first use!"
-		ewarn
-	fi
-}
-
-pkg_setup() {
-	if use emacs; then
-		elisp-need-emacs 23 || die "Emacs version too low"
-	fi
-}
-
-src_unpack() {
-	unpack "${P}".tar.gz
-	if use test; then
-		mkdir -p "${S}"/test/test-databases || die
-		cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
-	fi
-}
-
-src_prepare() {
-	default
-
-	bindings python distutils-r1_src_prepare
-	bindings python mv README README-python || die
-	mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
-
-	# assure that new Makefile.config will be generated
-	rm -f Makefile.config || die
-
-	if use test; then
-		append-cflags -g
-		append-cxxflags -g
-	fi
-}
-
-src_configure() {
-	local myeconfargs=(
-		--bashcompletiondir="$(get_bashcompdir)"
-		--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
-		--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
-		--without-ruby
-		--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
-		$(use_with emacs)
-		$(use_with doc api-docs)
-	)
-	tc-export CC CXX
-	econf "${myeconfargs[@]}"
-}
-
-src_compile() {
-	V=1 default
-	bindings python distutils-r1_src_compile
-
-	if use mutt; then
-		pushd contrib/notmuch-mutt || die
-		emake notmuch-mutt.1
-		popd || die
-	fi
-
-	if use doc; then
-		pydocs() {
-			pushd docs || die
-			emake html
-			rm -r html/_sources || die
-			rm html/{objects.inv,.buildinfo} || die
-			mkdir -p ../html && mv html ../html/python || die
-			popd || die
-		}
-		LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
-	fi
-}
-
-src_test() {
-	pax-mark -m notmuch
-	LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" V=1 default
-	pax-mark -ze notmuch
-}
-
-src_install() {
-	default
-
-	if use emacs; then
-		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
-	fi
-
-	if use nmbug; then
-		dobin devel/nmbug/nmbug
-		dobin devel/nmbug/notmuch-report
-	fi
-
-	if use mutt; then
-		pushd contrib/notmuch-mutt || die
-		dobin notmuch-mutt
-		doman notmuch-mutt.1
-		insinto /etc/mutt
-		doins notmuch-mutt.rc
-		dodoc README-mutt
-		popd || die
-	fi
-
-	DOCS="" bindings python distutils-r1_src_install
-	use doc && bindings python dodoc -r html
-}
-
-pkg_preinst() {
-	if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
-		elog "To enable notmuch support in mutt, add the following line into"
-		elog "your mutt config file, please:"
-		elog ""
-		elog "  source /etc/mutt/notmuch-mutt.rc"
-	fi
-}
-
-pkg_postinst() {
-	use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
-	use emacs && elisp-site-regen
-}