[gentoo-commits] repo/gentoo:master commit in: media-gfx/mypaint/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     762049d5a2ff59532a3917e639c2699c30b69f4b
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 22 00:18:28 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sun Jan 22 00:18:28 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=762049d5

media-gfx/mypaint: Bump to version 1.2.1

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 media-gfx/mypaint/mypaint-1.2.1.ebuild | 89 ++++++++++++++++++++++++++++++++++
 1 file changed, 89 insertions(+)

diff --git a/media-gfx/mypaint/mypaint-1.2.1.ebuild b/media-gfx/mypaint/mypaint-1.2.1.ebuild
new file mode 100644
index 00000000..b88de18
--- /dev/null
+++ b/media-gfx/mypaint/mypaint-1.2.1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit fdo-mime gnome2-utils multilib scons-utils toolchain-funcs python-single-r1
+
+DESCRIPTION="fast and easy graphics application for digital painters"
+HOMEPAGE="http://mypaint.org/"
+SRC_URI="https://github.com/mypaint/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+LANGS="cs de en_CA en_GB es fr hu id it ja ko nb nn_NO pl pt_BR ro ru sl sv uk zh_CN zh_TW"
+for x in ${LANGS}; do
+	IUSE+="linguas_${x} "
+done
+
+RDEPEND="
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pycairo-1.4[${PYTHON_USEDEP}]
+	dev-libs/protobuf[python,${PYTHON_USEDEP}]
+	>=dev-libs/json-c-0.11:=
+	media-libs/lcms:2
+	>=media-libs/libmypaint-1.3.0
+	media-libs/libpng:0=
+	gnome-base/librsvg
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}
+	dev-lang/swig
+	virtual/pkgconfig"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# multilib support
+	sed -i -e "s:lib\/${PN}:$(get_libdir)\/${PN}:" \
+		SConstruct SConscript || die
+}
+
+src_compile() {
+	#workaround scons bug with locales. Bug #352700
+	export LANG="en_US.UTF-8"
+	tc-export CC CXX
+	escons
+}
+
+src_install () {
+	escons prefix="${D}/usr" install
+	newicon pixmaps/${PN}_logo.png ${PN}.png
+	for x in ${LANGS}; do
+		if ! has ${x} ${LINGUAS}; then
+			rm -rf "${ED}"/usr/share/locale/${x} || die
+		fi
+	done
+
+	python_optimize "${D}"usr/share/${PN}
+	# not used and broken
+	rm -r "${ED}"/usr/{include/,lib/libmypaint.a,lib/pkgconfig/} || die
+	# already provided by system-libmypaint
+	rm "${ED}"/usr/share/locale/*/LC_MESSAGES/libmypaint* || die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}