[gentoo-commits] repo/gentoo:master commit in: app-backup/dar/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     adff8e999f59c5dd33e75d97cd56db8f709c28f0
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 21 23:25:04 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sat Jan 21 23:28:42 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=adff8e99

app-backup/dar: Bump to versions 2.4.24 and 2.5.9

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 app-backup/dar/Manifest          |  2 +
 app-backup/dar/dar-2.4.24.ebuild | 69 ++++++++++++++++++++++++++++
 app-backup/dar/dar-2.5.9.ebuild  | 97 ++++++++++++++++++++++++++++++++++++++++
 3 files changed, 168 insertions(+)

diff --git a/app-backup/dar/Manifest b/app-backup/dar/Manifest
index c49fcd9..511de3b 100644
--- a/app-backup/dar/Manifest
+++ b/app-backup/dar/Manifest
@@ -1,4 +1,6 @@
 DIST dar-2.4.20.tar.gz 1804634 SHA256 f0f66108692de8b27e76b1832d9013d9d1dbf45d2aaaaf5c222dde3c6f1b308d SHA512 1ed2e43df05082c01f6a53aa8c1c7328cb27fc3d84115d3f4a07de943fc814b614155f673464cd1a455e3b8c21e30f95da03ed9f72883b58ae005e3696de8143 WHIRLPOOL b3ce8c59efe2f9f988133613b73fe1ec14af39746e7c5fff0c83fa2146218fad3e912f586e9b677af809696105fa9d72dc35122ec3b3ca3ad63b2cdd75fce954
 DIST dar-2.4.23.tar.gz 1819248 SHA256 2338b5bdd17168db10aed75a2cf6abb99e8058a4e67eba3bfaaec457c04725b1 SHA512 c9c737f9310eb84aaf0743139b9bacc07dab853a6cc0572882f54a80b6e15aac41af6151b6ca38db61b131fdb05d5cd0e9e6269cdf5bdd3698ce0df754a152c8 WHIRLPOOL 35a6e80d7f0dfa8dd7f5385c33ee0ee375f284223a0f268c1eb3a77f8ef2f222a7ae8a5e2d78e60ff5b2d59d9aa106f0b14449e61d3166564a8ca23cfbf3e5e4
+DIST dar-2.4.24.tar.gz 1820097 SHA256 cb9f0935f4aa1c10daaceef3fbcf165ca73524fd6ce50948cb91e926080825f0 SHA512 3e5fbaaac7ab8e25776d20c11accba94c30abcbc898e7700e9faa98dee94995e742a9481740f2d286149a198ce661d876d2737fed85f1a2555073436175c5f10 WHIRLPOOL 659ac04d22c4781595863b22372755a357f060ab7325623d54e7d258aa36701111c026a884775444c2cea232fc3a0410d6c85c06a5f56a14cc39022c72237fe6
 DIST dar-2.5.7.tar.gz 1881075 SHA256 f4fa3b5d8d38a299e4463dbf77e104c572be669838e16a3d507dce7173d1561d SHA512 b8b81e31c63713fbacb79a1da17c5b2be4506e44b64667fe32ffbd5e5720798c7d34b000a6c78cb3ae482c77da00bd0f4169827c030b441a93861171dc73e98a WHIRLPOOL 5ef24ef7c4913474e5c6746e821f6d979fee118e1757a228742b444155998a280fccb32d108c777d1cf01904a9b38a07850e9d35bff43626217accee611f2f31
 DIST dar-2.5.8.tar.gz 1882127 SHA256 4f2968bb6f769ccfc4db880db4e3bd5596565b4674fa92000d2a17c7bdd4e825 SHA512 4cb2305173b4ae0ecd6649f69356c2e2972e67ae526a2ab03a2980ea57b18288887a351f79ca44171f2869cfd488b907204d03cc45ade7e790d775d49967b27a WHIRLPOOL 32a8cec804fc0e03389dabdf00ad15661e49d84612a350aeda7920991d106023ee655104ce54dbbdf76197b963abc83df29788279faa11ff6314874cfdd7c783
+DIST dar-2.5.9.tar.gz 1886232 SHA256 6973614afa970d095719bf43d91855c450d0fa5dcf0a45b580055625500ba92e SHA512 ee7b9180fb5f937b3fdd9a2f615dfecc66bd0c39f95e067ac55fa6c6f038e5abbe8ec8ab639e3eb51dd2cc7e4221a42fb5e783ed2039e0deabaa75e6f93abdac WHIRLPOOL f0eef9ef3b44860b5693414e5de62becec1195099697ffe424d2ee805b7d2bffa03710d1e95ef49922334ccb708b46e62f7cafa612c74abaaa667a4244212ba3

diff --git a/app-backup/dar/dar-2.4.24.ebuild b/app-backup/dar/dar-2.4.24.ebuild
new file mode 100644
index 00000000..c925e3f0
--- /dev/null
+++ b/app-backup/dar/dar-2.4.24.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="acl dar32 dar64 doc gcrypt lzo nls static static-libs"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND=">=sys-libs/zlib-1.2.3:=
+	!static? ( app-arch/bzip2:= )
+	acl? ( !static? ( sys-apps/attr:= ) )
+	gcrypt? ( dev-libs/libgcrypt:0= )
+	lzo? ( !static? ( dev-libs/lzo:= ) )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	static? ( app-arch/bzip2[static-libs] )
+	static? ( sys-libs/zlib[static-libs] )
+	acl? ( static? ( sys-apps/attr[static-libs] ) )
+	lzo? ( static? ( dev-libs/lzo[static-libs] ) )
+	nls? ( sys-devel/gettext )
+	doc? ( app-doc/doxygen )"
+
+REQUIRED_USE="?? ( dar32 dar64 )"
+
+DOCS="AUTHORS ChangeLog NEWS README THANKS TODO"
+
+src_configure() {
+	local myconf="--disable-upx"
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	use acl || myconf="${myconf} --disable-ea-support"
+	use dar32 && myconf="${myconf} --enable-mode=32"
+	use dar64 && myconf="${myconf} --enable-mode=64"
+	use doc || myconf="${myconf} --disable-build-html"
+	# use examples && myconf="${myconf} --enable-examples"
+	use gcrypt || myconf="${myconf} --disable-libgcrypt-linking"
+	use lzo || myconf="${myconf} --disable-liblzo2-linking"
+	use nls || myconf="${myconf} --disable-nls"
+	if ! use static ; then
+		myconf="${myconf} --disable-dar-static"
+		if ! use static-libs ; then
+			myconf="${myconf} --disable-static"
+		fi
+	fi
+
+	econf ${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	einstalldocs
+
+	if ! use static-libs ; then
+		prune_libtool_files --all
+	fi
+}

diff --git a/app-backup/dar/dar-2.5.9.ebuild b/app-backup/dar/dar-2.5.9.ebuild
new file mode 100644
index 00000000..78edc49
--- /dev/null
+++ b/app-backup/dar/dar-2.5.9.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit confutils flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="dar32 dar64 doc gcrypt gpg lzo nls static static-libs xattr"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND=">=sys-libs/zlib-1.2.3:=
+	!static? (
+		app-arch/bzip2:=
+		app-arch/xz-utils:=
+		sys-libs/libcap
+		gcrypt? ( dev-libs/libgcrypt:0= )
+		gpg? ( app-crypt/gpgme )
+		lzo? ( dev-libs/lzo:= )
+		xattr? ( sys-apps/attr:= )
+	)"
+
+DEPEND="${RDEPEND}
+	static? (
+		app-arch/bzip2[static-libs]
+		app-arch/xz-utils[static-libs]
+		sys-libs/libcap[static-libs]
+		sys-libs/zlib[static-libs]
+		gcrypt? ( dev-libs/libgcrypt:0=[static-libs] )
+		gpg? (
+			app-crypt/gpgme[static-libs]
+			dev-libs/libassuan[static-libs]
+			dev-libs/libgpg-error[static-libs]
+		)
+		lzo? ( dev-libs/lzo[static-libs] )
+		xattr? ( sys-apps/attr[static-libs] )
+	)
+	nls? (
+		sys-devel/gettext
+		virtual/libintl
+	)
+	doc? ( app-doc/doxygen )"
+
+REQUIRED_USE="?? ( dar32 dar64 )
+		gpg? ( gcrypt )"
+
+#PATCHES=(
+#)
+
+src_configure() {
+	local myconf=( --disable-upx )
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	# configure.ac is totally funked up regarding the AC_ARG_ENABLE
+	# logic.
+	# For example "--enable-dar-static" causes configure to DISABLE
+	# static builds of dar.
+	# Do _not_ use $(use_enable) until you have verified that the
+	# logic has been fixed by upstream.
+	use xattr || myconf+=( --disable-ea-support )
+	use dar32 && myconf+=( --enable-mode=32 )
+	use dar64 && myconf+=( --enable-mode=64 )
+	use doc || myconf+=( --disable-build-html )
+	# use examples && myconf+=( --enable-examples )
+	use gcrypt || myconf+=( --disable-libgcrypt-linking )
+	use gpg || myconf+=( --disable-gpgme-linking )
+	use lzo || myconf+=( --disable-liblzo2-linking )
+	use nls || myconf+=( --disable-nls )
+	if ! use static ; then
+		myconf+=( --disable-dar-static )
+		if ! use static-libs ; then
+			myconf+=( --disable-static )
+		fi
+	fi
+
+	econf ${myconf[@]}
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	local DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+	einstalldocs
+
+	if ! use static-libs ; then
+		prune_libtool_files --all
+	fi
+}