[gentoo-commits] repo/gentoo:master commit in: app-misc/lsx/

["Patrice Clement" <monsieurp@gentoo.org>]

commit:     f7999690404f400eec1a2da59586c4d0a3b61f9a
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 17 22:51:58 2017 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Tue Jan 17 22:52:13 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f7999690

app-misc/lsx: EAPI 6 bump.

Package-Manager: portage-2.3.0

 app-misc/lsx/lsx-0.1-r1.ebuild | 47 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/app-misc/lsx/lsx-0.1-r1.ebuild b/app-misc/lsx/lsx-0.1-r1.ebuild
new file mode 100644
index 00000000..aea9562
--- /dev/null
+++ b/app-misc/lsx/lsx-0.1-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="list executables"
+HOMEPAGE="http://tools.suckless.org/lsx"
+SRC_URI="http://suckless.org/download/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DOCS=( README )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s/.*strip.*//" \
+		Makefile || die "sed failed"
+
+	sed -i \
+		-e "s/CFLAGS = -Os/CFLAGS +=/" \
+		-e "s/LDFLAGS =/LDFLAGS +=/" \
+		config.mk || die "sed failed"
+}
+
+src_compile() {
+	emake CC=$(tc-getCC)
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install
+
+	# collision with net-dialup/lrzsz
+	mv "${D}/usr/bin/${PN}" "${D}/usr/bin/${PN}-suckless" || die
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	elog "Run ${PN} with ${PN}-suckless"
+}