[gentoo-commits] repo/gentoo:master commit in: dev-libs/appstream/

["Johannes Huber" <johu@gentoo.org>]

commit:     fa87e35f256a5f3b87ea3e7f1e7c2122cc470659
Author:     Johannes Huber <johu <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 14 10:12:37 2017 +0000
Commit:     Johannes Huber <johu <AT> gentoo <DOT> org>
CommitDate: Sat Jan 14 10:12:37 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa87e35f

dev-libs/appstream: New package

Import from kde overlay. Ebuild by me. Requuired for Plasma 5.9 + KDE
Frameworks 5.30.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 dev-libs/appstream/Manifest                |  1 +
 dev-libs/appstream/appstream-0.10.5.ebuild | 56 ++++++++++++++++++++++++++++++
 dev-libs/appstream/metadata.xml            | 11 ++++++
 3 files changed, 68 insertions(+)

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
new file mode 100644
index 00000000..f1bb86e
--- /dev/null
+++ b/dev-libs/appstream/Manifest
@@ -0,0 +1 @@
+DIST appstream-0.10.5.tar.gz 1797978 SHA256 b3f17f49c4ad7a503954f7baee16f47ba0f845c5e684798b1109db881bba2a06 SHA512 c427234049c8e8e158a7d64dc2dab6c3ea155dfe6fc0df1c2a5cd5ab611c65e36bf86ac57de69eb3dcff5ed5f71f37aef5d239e356e8e0a7a4fa763f246efb14 WHIRLPOOL bc127f66a20df1a946cdf64e66c6e4e3ea4c50653f174d6afc6f7eaa136d55352c7df2bb178ce452100ba95ab59304009546f5515f11221145b5be4274eb6841

diff --git a/dev-libs/appstream/appstream-0.10.5.ebuild b/dev-libs/appstream/appstream-0.10.5.ebuild
new file mode 100644
index 00000000..55829e7
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.10.5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+KDE_AUTODEPS="false"
+KDE_TEST="true"
+inherit kde5
+
+if [[ ${KDE_BUILD_TYPE} = live ]]; then
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	inherit versionator
+	MY_PV="$(replace_all_version_separators '_')"
+	MY_P="APPSTREAM_${MY_PV}"
+	SRC_URI="https://github.com/ximion/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${MY_P}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check APPSTREAM_LIB_API_LEVEL
+SLOT="0/4"
+IUSE="apt doc qt5"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer
+	qt5? ( dev-qt/qtcore:5 )
+"
+DEPEND="${RDEPEND}
+	dev-util/itstool
+	sys-devel/gettext
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DSTEMMING=ON
+		-DL18N=ON
+		-DVAPI=OFF
+		-DMAINTAINER=OFF
+		-DSANITIZERS=OFF
+		-DDOCUMENTATION=OFF
+		-DAPT_SUPPORT=$(usex apt)
+		-DINSTALL_PREBUILT_DOCS=$(usex doc)
+		-DQT=$(usex qt5)
+	)
+
+	kde5_src_configure
+}

diff --git a/dev-libs/appstream/metadata.xml b/dev-libs/appstream/metadata.xml
new file mode 100644
index 00000000..245719f
--- /dev/null
+++ b/dev-libs/appstream/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<use>
+		<flag name="apt">Enables Debians APT support</flag>
+	</use>
+</pkgmetadata>