From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-922119-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 06521139085
	for <garchives@archives.gentoo.org>; Mon,  9 Jan 2017 05:48:22 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 07BD721C04E;
	Mon,  9 Jan 2017 05:48:20 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id C827021C04E
	for <gentoo-commits@lists.gentoo.org>; Mon,  9 Jan 2017 05:48:19 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 5D50F341142
	for <gentoo-commits@lists.gentoo.org>; Mon,  9 Jan 2017 05:48:18 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id C900F24C5
	for <gentoo-commits@lists.gentoo.org>; Mon,  9 Jan 2017 05:48:16 +0000 (UTC)
From: "Eray Aslan" <eras@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Eray Aslan" <eras@gentoo.org>
Message-ID: <1483940864.7e84470da566dd3c1d2196904d5489504877c32f.eras@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-mail/mailutils/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-mail/mailutils/Manifest net-mail/mailutils/mailutils-3.1.1.ebuild
X-VCS-Directories: net-mail/mailutils/
X-VCS-Committer: eras
X-VCS-Committer-Name: Eray Aslan
X-VCS-Revision: 7e84470da566dd3c1d2196904d5489504877c32f
X-VCS-Branch: master
Date: Mon,  9 Jan 2017 05:48:16 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 1e50d769-5c22-4306-88be-f7d17a1bff12
X-Archives-Hash: f258fc47b93cabb1099ca593599d68d4

commit:     7e84470da566dd3c1d2196904d5489504877c32f
Author:     Eray Aslan <eras <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  9 05:47:44 2017 +0000
Commit:     Eray Aslan <eras <AT> gentoo <DOT> org>
CommitDate: Mon Jan  9 05:47:44 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7e84470d

net-mail/mailutils: version bump to mailutils-3.1.1

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 net-mail/mailutils/Manifest               |   1 +
 net-mail/mailutils/mailutils-3.1.1.ebuild | 135 ++++++++++++++++++++++++++++++
 2 files changed, 136 insertions(+)

diff --git a/net-mail/mailutils/Manifest b/net-mail/mailutils/Manifest
index 0fbdd33..b9411a8 100644
--- a/net-mail/mailutils/Manifest
+++ b/net-mail/mailutils/Manifest
@@ -1,4 +1,5 @@
 DIST mailutils-2.99.98.tar.xz 2505252 SHA256 62e2c28aed77e451e05ed15e68b5abc3932bcc3d2d6caf9b4a6864258c6a7b1a SHA512 fc20d97b3eed0f0ff7f1d7885e59f8de6ffd5b4646cd06c3636bda4a6bc9f7a0d5acdc7bb3bb573cdc80d63dfdc0be6464033ef2f6d88514bd2190f6611a1083 WHIRLPOOL c0f6f4f9dc2d60074c06a6c8f604fa4d92df4dafd6e205df8c360e97663e96c9b64a02aab9af7eab0659abc39e8aed70bbb0761b7d5a21b5873beabbcd409030
 DIST mailutils-2.99.99.tar.xz 2796000 SHA256 fd7743673e81ceb864e0c5876f9304616ca3759d69c662c27d6e093a9919f31d SHA512 a65f9cde0732f27cdea69385b72806e0f44c774006ad7613039644e7a822f26789c46bb06127ca0fa13dbc3e4ad0382e0a7bee6124e240ff58b394ba8a125bfb WHIRLPOOL 7790095392c7111ed858c547145ceb70687c8dae11c1b7cdc4df319ebe28ea07d941d7936d20d6a4e191418f22914d1ef65da194e2e7573f53688a4ce82d9325
 DIST mailutils-3.0.tar.xz 2729524 SHA256 3226ca41a9e6b39a96cc212a3adfba82aafe2a03dcbbe452f67e1c61a76e7d3d SHA512 833e0142ed7431553db5bdc6cb3846a8d74d35b23825fcbeaa9d81b81b4823c9b825b8e0154615c719341297e0ff7ba219f022016fb745fadbebe4ff6dd0372d WHIRLPOOL 61df116765cdaa9942e89cec1229a23769ea15122912a599f0ad3a25a195a4a5d0da7103c4618cb0de16a90d99a3c0bd9a484c34ab2f3dc1c9a53d877602e784
+DIST mailutils-3.1.1.tar.xz 2759000 SHA256 e5a07994924f63d8f29efe94e63ba6b110ac70b2b7f61ffa6f54ae4c9287bc21 SHA512 68a6f530935118f60503550aff925c799fee4de77377e726548f418e05687b1c8f29210bcb97e1b1033f9414bdbceeaa41e65496b0648a6356c8363554955e8c WHIRLPOOL 37c475e488f1967658e0f204cd9a47d402976f2af31566de6f9b815a4c4e1cace83a9367e8e343eb575a7128653f3e82f114c4966b1b1ac32c7512aa2246baf2
 DIST mailutils-3.1.tar.xz 2755692 SHA256 af7833d88296967465c00392787dfa342eb1ac9cc6d554e354431f3ae64f5fce SHA512 538968bedf729564915924804368dbb0391cf44d5cff253874bfd5fcabdd5a576356efc54cd17f07cff52e56248f0fa99577961cfd7992c4f6f0fb27d8a58a96 WHIRLPOOL 3420297ec2e1494ebbf3f4152c15a039f059356ae511eae52aeb704809cd1775d423676dbca21f4d11652c563540e325f4372a9aa990a59767f623cd90f5c907

diff --git a/net-mail/mailutils/mailutils-3.1.1.ebuild b/net-mail/mailutils/mailutils-3.1.1.ebuild
new file mode 100644
index 00000000..a39a4cf
--- /dev/null
+++ b/net-mail/mailutils/mailutils-3.1.1.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools eutils flag-o-matic python-single-r1 toolchain-funcs
+
+DESCRIPTION="A useful collection of mail servers, clients, and filters"
+HOMEPAGE="https://www.gnu.org/software/mailutils/mailutils.html"
+#SRC_URI="mirror://gnu/mailutils/${P}.tar.xz"
+SRC_URI="mirror://gnu/mailutils/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~x86 ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="berkdb bidi +clients gdbm sasl guile ipv6 kerberos kyotocabinet ldap \
+	mysql nls pam postgres python servers ssl static-libs +threads tcpd \
+	tokyocabinet"
+
+RDEPEND="!mail-client/nmh
+	!mail-filter/libsieve
+	!mail-client/mailx
+	!mail-client/nail
+	sys-libs/ncurses:=
+	sys-libs/readline:=
+	dev-libs/libltdl:0
+	virtual/mta
+	berkdb? ( sys-libs/db:= )
+	bidi? ( dev-libs/fribidi )
+	gdbm? ( sys-libs/gdbm )
+	guile? ( dev-scheme/guile:= )
+	kerberos? ( virtual/krb5 )
+	kyotocabinet? ( dev-db/kyotocabinet )
+	ldap? ( net-nds/openldap )
+	mysql? ( virtual/mysql )
+	nls? ( sys-devel/gettext )
+	pam? ( virtual/pam )
+	postgres? ( dev-db/postgresql:= )
+	python? ( ${PYTHON_DEPS} )
+	sasl? ( virtual/gsasl )
+	ssl? ( net-libs/gnutls:= )
+	tcpd? ( sys-apps/tcp-wrappers )
+	tokyocabinet? ( dev-db/tokyocabinet )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	servers? ( tcpd )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable bytecompilation of Python modules.
+	echo "#!/bin/sh" > build-aux/py-compile
+	eapply "${FILESDIR}/${PN}-2.99.98-readline-6.3.patch" #503954
+	# bug 567976
+	sed -i -e /AM_GNU_GETTEXT_VERSION/s/0.18/0.19/ configure.ac || die
+	# add missing tests so that make check doesn't fail
+	cp "${FILESDIR}"/{hdr,nohdr,twomsg,weed}.at "${S}"/readmsg/tests || die
+	if use mysql; then
+		sed -i -e /^INCLUDES/"s:$:$(mysql_config --include):" \
+			sql/Makefile.am || die
+	fi
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	# maildir is the Gentoo default
+	econf MU_DEFAULT_SCHEME=maildir \
+		CURSES_LIBS="$($(tc-getPKG_CONFIG) --libs ncurses)" \
+		$(use_with berkdb berkeley-db) \
+		$(use_with bidi fribidi) \
+		$(use_enable ipv6) \
+		$(use_with gdbm) \
+		$(use_with sasl gsasl) \
+		$(use_with guile) \
+		$(use_with kerberos gssapi) \
+		$(use_with ldap) \
+		$(use_with mysql) \
+		$(use_enable nls) \
+		$(use_enable pam) \
+		$(use_with postgres) \
+		$(use_enable python) \
+		$(use_with ssl gnutls) \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthread) \
+		$(use_with tokyocabinet) \
+		$(use_with kyotocabinet) \
+		$(use_with tcpd tcp-wrappers) \
+		$(use_enable servers build-servers) \
+		$(use_enable clients build-clients) \
+		--with-mail-spool=/var/spool/mail \
+		--with-readline \
+		--enable-sendmail \
+		--disable-debug \
+		--disable-rpath
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	doins "${FILESDIR}/mailutils.rc"
+	keepdir /etc/mailutils.d/
+	insinto /etc/mailutils.d
+	doins "${FILESDIR}/mail"
+
+	if use python; then
+		python_optimize
+		if use static-libs; then
+			rm -r "${D}$(python_get_sitedir)/mailutils"/*.{a,la} || die
+		fi
+	fi
+
+	if use servers; then
+		newinitd "${FILESDIR}"/imap4d.initd imap4d
+		newinitd "${FILESDIR}"/pop3d.initd pop3d
+		newinitd "${FILESDIR}"/comsatd.initd comsatd
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
+
+	# compatibility link
+	use clients && dosym /usr/bin/mail /bin/mail
+
+	use static-libs || find "${D}" -name "*.la" -delete
+}