[gentoo-commits] repo/gentoo:master commit in: dev-libs/qoauth/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     5daee0b96948535deae6b5d1a651065403d5a1fe
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Jan  7 16:52:32 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Jan  7 17:22:14 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5daee0b9

dev-libs/qoauth: Drop broken USE=static-libs, fix DEPEND, bump EAPI 6

Package-Manager: portage-2.3.0

 dev-libs/qoauth/qoauth-2.0.1_pre20160315-r1.ebuild | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/dev-libs/qoauth/qoauth-2.0.1_pre20160315-r1.ebuild b/dev-libs/qoauth/qoauth-2.0.1_pre20160315-r1.ebuild
new file mode 100644
index 00000000..80398f3
--- /dev/null
+++ b/dev-libs/qoauth/qoauth-2.0.1_pre20160315-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit qmake-utils
+
+DESCRIPTION="Qt-based library for OAuth support"
+HOMEPAGE="https://wiki.github.com/ayoy/qoauth"
+SRC_URI="https://dev.gentoo.org/~johu/distfiles/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="debug doc test"
+
+COMMON_DEPEND="
+	app-crypt/qca:2[debug?,qt5]
+	dev-qt/qtnetwork:5
+"
+DEPEND="${COMMON_DEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-qt/qttest:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	app-crypt/qca:2[ssl]
+	!dev-libs/qoauth:0
+"
+
+# disable functional tests that require network connection
+# and rely on 3rd party external server (bug #341267)
+PATCHES=( "${FILESDIR}/${PN}-1.0.1-disable-ft.patch" )
+
+src_prepare() {
+	default
+
+	if ! use test; then
+		sed -i -e '/SUBDIRS/s/tests//' ${PN}.pro || die "sed failed"
+	fi
+
+	sed -i -e '/^ *docs \\$/d' \
+		-e '/^ *build_all \\$/d' \
+		-e 's/^\#\(!macx\)/\1/' \
+		src/src.pro || die "sed failed"
+
+	sed -i -e "s/\(.*\)lib$/\1$(get_libdir)/" src/pcfile.sh || die "sed failed"
+}
+
+src_configure() {
+	eqmake5 qoauth.pro
+}
+
+src_install() {
+	if use doc; then
+		doxygen "${S}"/Doxyfile || die "failed to generate documentation"
+		HTML_DOCS=( "${S}"/doc/html/. )
+	fi
+
+	INSTALL_ROOT="${D}" default
+}