From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-920229-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id B497B139085
for <garchives@archives.gentoo.org>; Fri, 30 Dec 2016 21:58:35 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 0BBD921C072;
Fri, 30 Dec 2016 21:58:35 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id CC0E721C072
for <gentoo-commits@lists.gentoo.org>; Fri, 30 Dec 2016 21:58:34 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id C267D3416D3
for <gentoo-commits@lists.gentoo.org>; Fri, 30 Dec 2016 21:58:33 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 3DE994A8
for <gentoo-commits@lists.gentoo.org>; Fri, 30 Dec 2016 21:58:32 +0000 (UTC)
From: "Patrice Clement" <monsieurp@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Patrice Clement" <monsieurp@gentoo.org>
Message-ID: <1483134891.f6c5ac0de170ab7ad1b3701738c74e8c58c9c740.monsieurp@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-misc/lirc/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-misc/lirc/Manifest app-misc/lirc/lirc-0.9.4c.ebuild app-misc/lirc/metadata.xml
X-VCS-Directories: app-misc/lirc/
X-VCS-Committer: monsieurp
X-VCS-Committer-Name: Patrice Clement
X-VCS-Revision: f6c5ac0de170ab7ad1b3701738c74e8c58c9c740
X-VCS-Branch: master
Date: Fri, 30 Dec 2016 21:58:32 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 87909eb4-f1d6-47ce-b06a-03c9a1cc5806
X-Archives-Hash: a9cde70a89953d37a4fcf8631f321024
commit: f6c5ac0de170ab7ad1b3701738c74e8c58c9c740
Author: Craig Andrews <candrews <AT> integralblue <DOT> com>
AuthorDate: Sun Dec 18 02:39:47 2016 +0000
Commit: Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Fri Dec 30 21:54:51 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f6c5ac0d
app-misc/lirc-0.9.4c: version bump.
* Clean up dependencies.
* Remove irman and iguanair use flags: these have been moved out of lirc upstream.
* Use xdg-utils.eclass to cleanup XDG_* env causing sandbox violation.
* Fix dependencies for lirc-setup.
Gentoo-Bug: https://bugs.gentoo.org/602978
Gentoo-Bug: https://bugs.gentoo.org/587770
Gentoo-Bug: https://bugs.gentoo.org/591264
Closes: https://github.com/gentoo/gentoo/pull/3150
app-misc/lirc/Manifest | 1 +
app-misc/lirc/lirc-0.9.4c.ebuild | 150 +++++++++++++++++++++++++++++++++++++++
app-misc/lirc/metadata.xml | 1 +
3 files changed, 152 insertions(+)
diff --git a/app-misc/lirc/Manifest b/app-misc/lirc/Manifest
index 244e890..7cb5196 100644
--- a/app-misc/lirc/Manifest
+++ b/app-misc/lirc/Manifest
@@ -1,2 +1,3 @@
DIST lirc-0.9.0.tar.bz2 857286 SHA256 6323afae6ad498d4369675f77ec3dbb680fe661bea586aa296e67f2e2daba4ff SHA512 e91534c63e6065bd7da3b15e1676edf1672b8beb21864a6825df86247d7d165bf2dee6f8191732933e24e42a406e46afc55559948e4061eed2de7b08fac13431 WHIRLPOOL 0a1c00b07898aa7a5d78865fb73c6d26c6331dd0a4945773a801d29e40298b365eb58cae113a95fcf73be678a24ac082ad0868e8051303d732882fb82a859a7b
DIST lirc-0.9.4a.tar.bz2 2292119 SHA256 386086a74c7d12e7e8f26f7dbc8f40d20b9968c9ad2a42599483a51dd2da03ba SHA512 16be0ac5dd9b07d717ceba63cdc38c0db4a2bdcfc373ca6346d7cd4ab2cd2973aa7585d10b045fcaea952a3aabf7617c564ccb8268db6c62b172683a4b2cc188 WHIRLPOOL 93431c43d2dd31081e97113e2d49134de7feb29be53508900b3360408f7a099becf169fcebd0f6fc196280c594dc83d1299617ee54b65452828492db9bcd09ad
+DIST lirc-0.9.4c.tar.bz2 2311300 SHA256 8974fe5dc8eaa717daab6785d2aefeec27615f01ec24b96d31e3381b2f70726a SHA512 0a0d0e025b87a55ec919c92824d8288bfaf35cfebae0ee97d86e344109f584baa72a2eff6d24fbc526900671d6092e0eebef8d1566559b0d153e122e3127c0cb WHIRLPOOL a614fc10b0e40831e81c558439ea528ae0628d64e55b272b9b5a97cb93cba2b8759062a5258c732fa97c2be7966226c3aca2efe2de84aad1f62211146d202efc
diff --git a/app-misc/lirc/lirc-0.9.4c.ebuild b/app-misc/lirc/lirc-0.9.4c.ebuild
new file mode 100644
index 00000000..b90eeb8
--- /dev/null
+++ b/app-misc/lirc/lirc-0.9.4c.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_4 python3_5 )
+
+inherit eutils flag-o-matic python-single-r1 systemd xdg-utils
+
+DESCRIPTION="decode and send infra-red signals of many commonly used remote controls"
+HOMEPAGE="http://www.lirc.org/"
+
+LIRC_DRIVER_DEVICE="/dev/lirc0"
+
+MY_P=${PN}-${PV/_/}
+
+if [[ "${PV/_pre/}" = "${PV}" ]]; then
+ SRC_URI="mirror://sourceforge/lirc/${MY_P}.tar.bz2"
+else
+ SRC_URI="http://www.lirc.org/software/snapshots/${MY_P}.tar.bz2"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audio doc ftdi gtk inputlirc static-libs systemd usb X"
+
+REQUIRED_USE="
+ gtk? ( X )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+COMMON_DEPEND="
+ ${PYTHON_DEPS}
+ audio? (
+ >media-libs/portaudio-18
+ media-libs/alsa-lib
+ )
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ ftdi? ( dev-embedded/libftdi:0 )
+ systemd? ( sys-apps/systemd )
+ usb? ( virtual/libusb:0 )
+ X? (
+ x11-libs/libICE
+ x11-libs/libSM
+ x11-libs/libX11
+ )
+"
+
+DEPEND="
+ ${COMMON_DEPEND}
+ dev-libs/libxslt
+ doc? ( app-doc/doxygen )
+ sys-apps/kmod
+ sys-kernel/linux-headers
+"
+
+RDEPEND="
+ ${COMMON_DEPEND}
+ gtk? (
+ x11-libs/vte[introspection]
+ dev-python/pygobject[${PYTHON_USEDEP}]
+ )
+ inputlirc? ( app-misc/inputlircd )
+"
+
+PATCHES=(
+ # https://bugs.gentoo.org/show_bug.cgi?id=589246 https://sourceforge.net/p/lirc/tickets/214/
+ "${FILESDIR}"/lirc-0.9.4-doc-path-fix.patch
+)
+
+src_configure() {
+ xdg_environment_reset
+ econf \
+ --localstatedir="${EPREFIX}/var" \
+ $(use_enable static-libs static) \
+ $(use_with X x)
+}
+
+src_install() {
+ default
+
+ if use !gtk ; then
+ # lirc-setup requires gtk
+ rm "${ED%/}"/usr/bin/lirc-setup
+ fi
+
+ newinitd "${FILESDIR}"/lircd-0.8.6-r2 lircd
+ newinitd "${FILESDIR}"/lircmd-0.9.4a-r2 lircmd
+ newconfd "${FILESDIR}"/lircd.conf.4 lircd
+ newconfd "${FILESDIR}"/lircmd.conf lircmd
+
+ insinto /etc/modprobe.d/
+ newins "${FILESDIR}"/modprobed.lirc lirc.conf
+
+ newinitd "${FILESDIR}"/irexec-initd-0.9.4a-r2 irexec
+ newconfd "${FILESDIR}"/irexec-confd irexec
+
+ keepdir /etc/lirc
+ if [[ -e "${ED%/}"/etc/lirc/lircd.conf ]]; then
+ newdoc "${ED%/}"/etc/lirc/lircd.conf lircd.conf.example
+ fi
+
+ find "${ED}" -name '*.la' -delete || die
+
+ # Avoid QA notice
+ rm -d "${ED%/}"/var/run/lirc || die
+ rm -d "${ED%/}"/var/run || die
+}
+
+pkg_preinst() {
+ local dir="${EROOT%/}/etc/modprobe.d"
+ if [[ -a "${dir}"/lirc && ! -a "${dir}"/lirc.conf ]]; then
+ elog "Renaming ${dir}/lirc to lirc.conf"
+ mv -f "${dir}/lirc" "${dir}/lirc.conf" || die
+ fi
+
+ # copy the first file that can be found
+ if [[ -f "${EROOT%/}"/etc/lirc/lircd.conf ]]; then
+ cp "${EROOT%/}"/etc/lirc/lircd.conf "${T}"/lircd.conf || die
+ elif [[ -f "${EROOT%/}"/etc/lircd.conf ]]; then
+ cp "${EROOT%/}"/etc/lircd.conf "${T}"/lircd.conf || die
+ MOVE_OLD_LIRCD_CONF=1
+ elif [[ -f "${ED%/}"/etc/lirc/lircd.conf ]]; then
+ cp "${ED%/}"/etc/lirc/lircd.conf "${T}"/lircd.conf || die
+ fi
+
+ # stop portage from touching the config file
+ if [[ -e "${ED%/}"/etc/lirc/lircd.conf ]]; then
+ rm -f "${ED%/}"/etc/lirc/lircd.conf || die
+ fi
+}
+
+pkg_postinst() {
+ # copy config file to new location
+ # without portage knowing about it
+ # so it will not delete it on unmerge or ever touch it again
+ if [[ -e "${T}"/lircd.conf ]]; then
+ cp "${T}"/lircd.conf "${EROOT%/}"/etc/lirc/lircd.conf || die
+ if [[ "$MOVE_OLD_LIRCD_CONF" = "1" ]]; then
+ elog "Moved /etc/lircd.conf to /etc/lirc/lircd.conf"
+ rm -f "${EROOT%/}"/etc/lircd.conf || die
+ fi
+ fi
+
+ einfo "The new default location for lircd.conf is inside of"
+ einfo "${EROOT%/}/etc/lirc/ directory"
+}
diff --git a/app-misc/lirc/metadata.xml b/app-misc/lirc/metadata.xml
index 3d42ab3..e563da1 100644
--- a/app-misc/lirc/metadata.xml
+++ b/app-misc/lirc/metadata.xml
@@ -19,6 +19,7 @@
<flag name="audio">Support using an audio device connected to an IR receiver</flag>
<flag name="iguanair">Support iguanaIR devices</flag>
<flag name="ftdi">Support FTDI devices</flag>
+ <flag name="gtk">Include GTK support which enables the use of lirc-setup</flag>
</use>
<upstream>
<remote-id type="sourceforge">lirc</remote-id>