[gentoo-commits] repo/gentoo:master commit in: dev-libs/libprelude/

["Göktürk Yüksek" <gokturk@gentoo.org>]

commit:     927321dabe666d9a3b63ed01d5a65296bc37cc6c
Author:     Thomas Andrejak <thomas.andrejak <AT> gmail <DOT> com>
AuthorDate: Sun Nov 27 22:35:17 2016 +0000
Commit:     Göktürk Yüksek <gokturk <AT> gentoo <DOT> org>
CommitDate: Tue Dec  6 17:27:10 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=927321da

dev-libs/libprelude: Bump version 3.1.0

 dev-libs/libprelude/Manifest                |  1 +
 dev-libs/libprelude/libprelude-3.1.0.ebuild | 77 +++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/dev-libs/libprelude/Manifest b/dev-libs/libprelude/Manifest
index 8cbf82a..a1b27cc 100644
--- a/dev-libs/libprelude/Manifest
+++ b/dev-libs/libprelude/Manifest
@@ -1 +1,2 @@
 DIST libprelude-3.0.0.tar.gz 2900153 SHA256 8dd1acdd49ec42b3c54642c33987c574ced43b92feb9a523998e07317434cec2 SHA512 a1fd51aa3bb1b68759a00dd1636cb96379f0e954a66f4e39887ab20a5b4c191a0455dd6bd5f41b20ad94d06fff59af7f89b258f42e1c0dd4cfc99185a77d1797 WHIRLPOOL 5ee5a90d0448c8079977dbf84a5c3650bc00aff8c6fe4355a7926313b2364824281d2fea898d92e80bc8b7cb17190c6f7e36b2c9de2ebc62f8b4411417541d58
+DIST libprelude-3.1.0.tar.gz 2949462 SHA256 b8fbaaa1f2536bd54a7f69fe905ac84d936435962c8fc9de67b2f2b375c7ac96 SHA512 f2878b19b4ba3cc74b0530f8741525ecf1425540d30356d182c4e0a797dbb5f4023792351bd059105dafc6b7818d4caa2e9c8b39be9a7039a89680244fcf1239 WHIRLPOOL 0507f1f90606b90159979180402c00a7a22f0b531f4df0b8606cdfce51dbd734578e2920564adc56d3675858dcd481f9a12106384e9244aa8dee569e63d0bb84

diff --git a/dev-libs/libprelude/libprelude-3.1.0.ebuild b/dev-libs/libprelude/libprelude-3.1.0.ebuild
new file mode 100644
index 00000000..ba42472
--- /dev/null
+++ b/dev-libs/libprelude/libprelude-3.1.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5}} )
+
+USE_RUBY="ruby21"
+
+inherit autotools python-r1 ruby-single
+
+DESCRIPTION="Prelude-SIEM Framework Library"
+HOMEPAGE="https://www.prelude-siem.org"
+SRC_URI="https://www.prelude-siem.org/pkg/src/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc lua python ruby perl"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-libs/libgcrypt:0=
+	net-libs/gnutls:=
+	perl? ( dev-lang/perl:= virtual/perl-ExtUtils-MakeMaker )
+	lua? ( dev-lang/lua:* )
+	ruby? ( ${RUBY_DEPS} )
+	python? ( ${PYTHON_DEPS} )"
+
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	sys-devel/flex
+	virtual/yacc
+	>=dev-lang/swig-3.0.7
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# Avoid null runpaths in Perl bindings.
+	sed -e 's/ LD_RUN_PATH=""//' -i "${S}/bindings/Makefile.am" || die "sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	local python2_configure=--without-python2
+	local python3_configure=--without-python3
+
+	chk_python() {
+		if [[ ${EPYTHON} == python2* ]]; then
+			python2_configure=--with-python2
+		elif [[ ${EPYTHON} == python3* ]]; then
+			python3_configure=--with-python3
+		fi
+	}
+
+	if use python; then
+		python_foreach_impl chk_python
+	fi
+
+	econf \
+		--enable-easy-bindings \
+		--with-swig \
+		$(use_with perl) \
+		$(use_enable doc gtk-doc) \
+		$(use_with lua) \
+		$(use_with ruby) \
+		${python2_configure} \
+		${python3_configure}
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}