[gentoo-commits] repo/gentoo:master commit in: app-backup/deja-dup/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     6719689a637fb34b48a3f9d57bafa2fd12aebdc8
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Mon Dec  5 10:03:57 2016 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Mon Dec  5 11:17:26 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6719689a

app-backup/deja-dup: Version bump

Package-Manager: portage-2.3.2

 app-backup/deja-dup/Manifest             |  1 +
 app-backup/deja-dup/deja-dup-34.3.ebuild | 75 ++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/app-backup/deja-dup/Manifest b/app-backup/deja-dup/Manifest
index 0a3a987..8deb8de 100644
--- a/app-backup/deja-dup/Manifest
+++ b/app-backup/deja-dup/Manifest
@@ -1 +1,2 @@
 DIST deja-dup-34.2.tar.xz 698788 SHA256 ff30732f28233e2422d069f1769a725d4a39c91a279c3bf885c4162fd85818bb SHA512 1c00026b5df53273916031cf72e4fc987d739b7985a9931641cef2afeff4b203e6bd2d9a97e255dd12a0de997d1fe9377c8b9106639312065a55a8206fcaa65f WHIRLPOOL 95c1200061ace9a09ac2309ba6253a608886c462e020da0cc9c14298392aab511b64dbb1aead6114e820408e5a366fa0e89d413fb11ab4daf692b63487d55420
+DIST deja-dup-34.3.tar.xz 702708 SHA256 c90a098c2b60fa73d6bcc51d7f8a33fc7c279f2556b677145d50ad0b83c90cf7 SHA512 0e703c18041fa5ca6d2f272f5b0e65ad31ff1094147432107834d1cd25e2ec14b87bdfac6faf727c97339d20d1681f3251c5f74b6edbee4368014839b1f04f06 WHIRLPOOL 619ca85ee559624370243cd057b6997334c784f25602ce63feb9d89bebfd8a826dd3e3c6adb3124e02a2b9bda04fe29d091e1f3382a0443152c84d602c447dcf

diff --git a/app-backup/deja-dup/deja-dup-34.3.ebuild b/app-backup/deja-dup/deja-dup-34.3.ebuild
new file mode 100644
index 00000000..957d622
--- /dev/null
+++ b/app-backup/deja-dup/deja-dup-34.3.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GCONF_DEBUG="no"
+
+inherit cmake-utils eutils gnome2 vala
+
+DESCRIPTION="Simple backup tool using duplicity back-end"
+HOMEPAGE="https://launchpad.net/deja-dup/"
+SRC_URI="https://launchpad.net/${PN}/34/${PV}/+download/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nautilus test"
+RESTRICT="test" # bug#????
+
+COMMON_DEPEND="
+	app-admin/packagekit-base
+	app-crypt/libsecret[vala]
+	>=dev-libs/glib-2.34:2[dbus]
+	>=dev-libs/libpeas-1.0
+	>=x11-libs/gtk+-3.10:3
+	>=x11-libs/libnotify-0.7
+
+	>=app-backup/duplicity-0.6.23
+	dev-libs/dbus-glib
+
+	nautilus? ( gnome-base/nautilus )
+"
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/dconf
+	gnome-base/gvfs[fuse]
+"
+DEPEND="${COMMON_DEPEND}
+	$(vala_depend)
+	app-text/yelp-tools
+	dev-perl/Locale-gettext
+	virtual/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext
+"
+
+src_prepare() {
+	sed \
+		-e '/RPATH/s:PKG_LIBEXECDIR:PKG_LIBDIR:g' \
+		-i CMakeLists.txt || die
+	vala_src_prepare
+	gnome2_src_prepare
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DVALA_EXECUTABLE="${VALAC}"
+		-DENABLE_CCPANEL=OFF
+		-DENABLE_PK=OFF
+		-DENABLE_UNITY=OFF
+		-DENABLE_UNITY_CCPANEL=OFF
+		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}"/etc
+		-DENABLE_NAUTILUS="$(usex nautilus)"
+		-DENABLE_TESTING="$(usex test)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+}