[gentoo-commits] repo/gentoo:master commit in: sci-libs/Shapely/

["Tiziano Müller" <dev-zero@gentoo.org>]

commit:     a90e779dc40fe495a58b5b8ebd88c7e8bd16ca60
Author:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
AuthorDate: Sun Dec  4 15:17:51 2016 +0000
Commit:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
CommitDate: Sun Dec  4 15:17:51 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a90e779d

sci-libs/Shapely: rev-bump for EAPI 6 bump and fixed deps and tests

Package-Manager: portage-2.3.2

 sci-libs/Shapely/Shapely-1.5.17-r1.ebuild | 48 +++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/sci-libs/Shapely/Shapely-1.5.17-r1.ebuild b/sci-libs/Shapely/Shapely-1.5.17-r1.ebuild
new file mode 100644
index 00000000..14cfe97
--- /dev/null
+++ b/sci-libs/Shapely/Shapely-1.5.17-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Geometric objects, predicates, and operations"
+HOMEPAGE="https://pypi.python.org/pypi/Shapely"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/Toblerity/${PN}.git"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="test"
+
+RDEPEND=">=sci-libs/geos-3.3
+	dev-python/numpy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# fix install path for Cython definition file
+	sed -i \
+		-e "s|\(data_files.*\)'shapely'|\1'share/shapely'|" \
+		setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}/lib" || die
+	cp -r "${S}/tests" . || die
+	py.test tests || die
+}