[gentoo-commits] repo/gentoo:master commit in: media-libs/gst-plugins-bad/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     29b0d74fd1a43b05358b7d8ccbd25a41566a698d
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 20 14:44:36 2016 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Sun Nov 20 14:44:50 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=29b0d74f

media-libs/gst-plugins-bad: disable vnmc and nsf plugins to resolve CVE-2016-9445, CVE-2016-9446 and CVE-2016-9447

Gentoo-bug: 600142
Acked-by: Mart Raudsepp <leio <AT> gentoo.org>

Package-Manager: portage-2.3.2

 .../gst-plugins-bad-0.10.23-r4.ebuild              | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r4.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r4.ebuild
new file mode 100644
index 00000000..e267e95
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-bad"
+inherit eutils flag-o-matic gstreamer
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+SRC_URI+=" https://dev.gentoo.org/~tetromino/distfiles/${PN}/${P}-h264-patches.tar.xz"
+
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="+orc"
+
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-0.10.36:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-0.10.36:${SLOT}[${MULTILIB_USEDEP}]
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+RDEPEND="${RDEPEND}
+	!<media-plugins/gst-plugins-farsight-0.12.11:${SLOT}"
+
+src_prepare() {
+	# Patches from 0.10 branch fixing h264 baseline decoding; bug #446384
+	epatch "${WORKDIR}/${P}-h264-patches"/*.patch
+	# Fix CVE-2015-0797, bug #553742
+	epatch "${FILESDIR}"/${P}-CVE-2015-0797.patch
+}
+
+src_configure() {
+	strip-flags
+	replace-flags "-O3" "-O2"
+	filter-flags "-fprefetch-loop-arrays" # (Bug #22249)
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	# Disable vnmc and nsf plugins due to security bug 600142
+	gstreamer_multilib_src_configure \
+		--disable-nsf \
+		--disable-vmnc \
+		$(use_enable orc) \
+		--disable-examples \
+		--disable-debug \
+		--disable-static
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}