[gentoo-commits] repo/gentoo:master commit in: app-emulation/runc/

["William Hubbs" <williamh@gentoo.org>]

commit:     29bfd92e85389870daafed52c1d3fdb0919a6a41
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 18 17:35:20 2016 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Fri Nov 18 17:35:39 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=29bfd92e

app-emulation/runc: 1.0.0_rc2-r1 revbump to add commit to version output

Package-Manager: portage-2.3.0

 app-emulation/runc/runc-1.0.0_rc2-r1.ebuild | 57 +++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/app-emulation/runc/runc-1.0.0_rc2-r1.ebuild b/app-emulation/runc/runc-1.0.0_rc2-r1.ebuild
new file mode 100644
index 00000000..a9fdebe
--- /dev/null
+++ b/app-emulation/runc/runc-1.0.0_rc2-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+EGO_PN="github.com/opencontainers/${PN}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-vcs
+else
+	MY_PV="${PV/_/-}"
+	EGIT_COMMIT="v${MY_PV}"
+	RUNC_COMMIT="c91b5be" # Change this when you update the ebuild
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc64"
+	inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="runc container cli tools"
+HOMEPAGE="http://runc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="apparmor hardened +seccomp"
+
+RDEPEND="
+	apparmor? ( sys-libs/libapparmor )
+	seccomp? ( sys-libs/libseccomp )
+"
+
+S=${WORKDIR}/${P}/src/${EGO_PN}
+
+src_compile() {
+	# Taken from app-emulation/docker-1.7.0-r1
+	export CGO_CFLAGS="-I${ROOT}/usr/include"
+	export CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')
+		-L${ROOT}/usr/$(get_libdir)"
+
+	# Setup GOPATH so things build
+	rm -rf .gopath
+	mkdir -p .gopath/src/"$(dirname "${GITHUB_URI}")"
+	ln -sf ../../../.. .gopath/src/"${GITHUB_URI}"
+	export GOPATH="${PWD}/.gopath:${PWD}/vendor"
+
+	# build up optional flags
+	local options=(
+		$(usex apparmor 'apparmor')
+		$(usex seccomp 'seccomp')
+	)
+
+	emake BUILDTAGS="${options[*]}" \
+		COMMIT="${RUNC_COMMIT}"
+}
+
+src_install() {
+	dobin runc
+}