[gentoo-commits] repo/gentoo:master commit in: dev-python/python-redmine/

["Michael Orlitzky" <mjo@gentoo.org>]

commit:     f0c9c075174acb6491e14ce2b1cf414339974da0
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 14 20:39:16 2016 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Tue Nov 15 12:45:59 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0c9c075

dev-python/python-redmine: new python interface to the redmine API.

Package-Manager: portage-2.3.0

 dev-python/python-redmine/Manifest                 |  1 +
 dev-python/python-redmine/metadata.xml             | 12 ++++++
 .../python-redmine/python-redmine-1.5.1.ebuild     | 47 ++++++++++++++++++++++
 3 files changed, 60 insertions(+)

diff --git a/dev-python/python-redmine/Manifest b/dev-python/python-redmine/Manifest
new file mode 100644
index 00000000..49ec196
--- /dev/null
+++ b/dev-python/python-redmine/Manifest
@@ -0,0 +1 @@
+DIST python-redmine-1.5.1.tar.gz 465595 SHA256 8a2ba7292693579656434e74817f7308e24e76ca05cf179a7645420f1203edcd SHA512 51a5deaaccc401f31f2ba74ad164c9d9a7df90b200121664779f1eee4cb871a2fdd139509e6201abb6e5203a46e00b98ca5ddcccf88e7e3a2fb9f509ffc36665 WHIRLPOOL 0113cd703badb0d6c90b1d8d3744f1fcbb839a6c990337b7581607ba7c3dcada9d4f75864b810f18b866ba18f3c2a50c0160443b02dfe8387c694f250b007374

diff --git a/dev-python/python-redmine/metadata.xml b/dev-python/python-redmine/metadata.xml
new file mode 100644
index 00000000..53f98ba
--- /dev/null
+++ b/dev-python/python-redmine/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>mjo@gentoo.org</email>
+    <name>Michael Orlitzky</name>
+  </maintainer>
+
+  <upstream>
+    <remote-id type="pypi">python-redmine</remote-id>
+  </upstream>
+</pkgmetadata>

diff --git a/dev-python/python-redmine/python-redmine-1.5.1.ebuild b/dev-python/python-redmine/python-redmine-1.5.1.ebuild
new file mode 100644
index 00000000..d623990
--- /dev/null
+++ b/dev-python/python-redmine/python-redmine-1.5.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface to the Redmine REST API"
+HOMEPAGE="https://github.com/maxtepkeev/python-redmine"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/requests[${PYTHON_USEDEP}]"
+
+# This package bundles dev-python/requests, so setup.py won't check for
+# it. As a result, we don't need RDEPEND in DEPEND unconditionally.
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/coverage[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# Remove the bundled copy of dev-python/requests...
+	rm -r redmine/packages \
+		|| die 'failed to remove the bundled copy of dev-python/requests'
+
+	# and replace its local import statement with a global one.
+	sed -i 's/from .packages import requests/import requests/' \
+		redmine/__init__.py \
+		|| die 'failed to replace the dev-python/requests library import'
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests || die "tests failed under ${EPYTHON}"
+}