[gentoo-commits] repo/gentoo:master commit in: app-office/texstudio/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     615dca623599f5c7cf0f811183fca0f58a1aae84
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 29 10:59:20 2016 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Sat Oct 29 10:59:36 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=615dca62

app-office/texstudio: revision bump with various fixes

* Port to EAPI 6 and remove deprecated Qt 4 support (by Andreas Sturmlechner)
* Fix build with quazip-0.7.2
* Add missing sys-libs/zlib dependency
* Sort dependencies
* Update GTK icon cache
* Add subslot operator for app-text/hunspell and remove from app-text/poppler
  (since the stable qt5 interface is used)

Gentoo-bug: 597876
Gentoo-bug: 597930

Package-Manager: portage-2.3.2

 app-office/texstudio/texstudio-2.11.2-r1.ebuild | 97 +++++++++++++++++++++++++
 1 file changed, 97 insertions(+)

diff --git a/app-office/texstudio/texstudio-2.11.2-r1.ebuild b/app-office/texstudio/texstudio-2.11.2-r1.ebuild
new file mode 100644
index 00000000..2003689
--- /dev/null
+++ b/app-office/texstudio/texstudio-2.11.2-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit fdo-mime gnome2-utils prefix qmake-utils
+
+DESCRIPTION="Free cross-platform LaTeX editor (fork from texmakerX)"
+HOMEPAGE="http://texstudio.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/TeXstudio%20${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="video"
+
+COMMON_DEPEND="
+	app-text/hunspell:=
+	app-text/poppler[qt5]
+	>=dev-libs/quazip-0.7.2[qt5]
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtscript:5
+	dev-qt/qtsingleapplication[qt5,X]
+	dev-qt/qtsvg:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXext
+	video? ( media-libs/phonon[qt5] )"
+RDEPEND="${COMMON_DEPEND}
+	app-text/ghostscript-gpl
+	app-text/psutils
+	media-libs/netpbm
+	virtual/latex-base"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}
+
+src_prepare() {
+	default
+	find hunspell quazip utilities/poppler-data qtsingleapplication -delete || die
+
+	if use video; then
+		sed "/^PHONON/s:$:true:g" -i ${PN}.pro || die
+	fi
+
+	sed \
+		-e '/qtsingleapplication.pri/d' \
+		-i ${PN}.pro || die
+
+#	cat >> ${PN}.pro <<- EOF
+#	exists(texmakerx_my.pri):include(texmakerx_my.pri)
+#	EOF
+
+	cp "${FILESDIR}"/texmakerx_my.pri ${PN}.pri || die
+	eprefixify ${PN}.pri
+
+	# fix build with quazip-0.7.2 - bug 597930
+	sed -i ${PN}.pro -e "s|include/quazip|&5|" || die
+	sed -i ${PN}.pri -i ${PN}.pro -e "s/-lquazip/&5/" || die
+}
+
+src_configure() {
+	eqmake5 USE_SYSTEM_HUNSPELL=1 USE_SYSTEM_QUAZIP=1
+}
+
+src_install() {
+	local i
+	for i in 16x16 22x22 32x32 48x48 64x64 128x128; do
+		insinto /usr/share/icons/hicolor/${i}/apps
+		newins utilities/${PN}${i}.png ${PN}.png
+	done
+	emake DESTDIR="${D}" INSTALL_ROOT="${ED}" install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}