[gentoo-commits] repo/gentoo:master commit in: games-rpg/kqlives/

["Austin English" <wizardedit@gentoo.org>]

commit:     8e0b4113b8d8532fadfeb203da7ccddf663ea3aa
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 15 10:24:36 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Sat Oct 15 11:08:15 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e0b4113

games-rpg/kqlives: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

 games-rpg/kqlives/kqlives-0.99-r1.ebuild | 48 ++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/games-rpg/kqlives/kqlives-0.99-r1.ebuild b/games-rpg/kqlives/kqlives-0.99-r1.ebuild
new file mode 100644
index 00000000..21db6f6
--- /dev/null
+++ b/games-rpg/kqlives/kqlives-0.99-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+MY_P=${P/lives}
+
+DESCRIPTION="A console-style role playing game"
+HOMEPAGE="http://kqlives.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cheats nls"
+
+RDEPEND="
+	dev-lang/lua:0
+	>=gnome-base/libglade-2.4
+	media-libs/aldumb
+	media-libs/allegro:0
+	>=x11-libs/gtk+-2.8:2
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	econf \
+		$(use_enable cheats) \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+
+	local x
+	for x in diff draw draw2 dump; do
+		mv -vf "${D}/etc"/map${x} "${D}/etc"/kq-map${x}
+	done
+
+	doicon "${FILESDIR}"/${PN}.xpm
+	make_desktop_entry kq KqLives ${PN}
+}