[gentoo-commits] repo/gentoo:master commit in: media-gfx/imagemagick/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     b7962c02c818c4062c4bb0b5cc196f55bbdafc0c
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 10 11:32:40 2016 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Oct 10 11:32:40 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b7962c02

media-gfx/imagemagick: Bump to version 6.9.6.1

Package-Manager: portage-2.3.1
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-gfx/imagemagick/Manifest                   |   1 +
 media-gfx/imagemagick/imagemagick-6.9.6.1.ebuild | 178 +++++++++++++++++++++++
 2 files changed, 179 insertions(+)

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index 9ae8a48..09d0a49 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,3 +1,4 @@
 DIST ImageMagick-6.9.5-10.tar.xz 8794440 SHA256 2805ab7945ca92251172335da992df800bcc09fee993eeb4711b20c53efeb233 SHA512 7ee467cf8b1776300c12f135c7fea73afe888d4592c2008e76e578afa436efadccc62e7f2fd9d356aeb8559cc5ff9168ee477bab5474f7495a332756aba294bb WHIRLPOOL 3105e524182f81d1210fd3f56c3457259c04d3d95d5a5a118f0854dd5f5851e43c70256f915221a0c3dd772e344fc5d9e1d36c3d2b77fccde68d70f66471c299
 DIST ImageMagick-6.9.6-0.tar.xz 8785676 SHA256 7905cd179e1d0fabdf58fca77a682ed68443999bfd6e0941f93bf9c08218e5e4 SHA512 be8953be1fa7b66cb914b44a8e21ee5551f9f7537a9da2593b5e8d7a512a07dc9fdd2097fb455444e2cb0e3b94e2161ba7557ea612b9a51740a986c5098afb04 WHIRLPOOL 6db8f0b196c42d39ab667d38d4fd6c922b727e77fa7f87f2e782b6237135774f1ed4a17dea723ad2f324bbd35384bf1069a003dec8c288575b8ff3551aef15b0
+DIST ImageMagick-6.9.6-1.tar.xz 8785568 SHA256 cf9486439ca05e5e0e3738647f077d207c3812a4c5f3925240e0c042010bcc5b SHA512 b81b52a31d8d0af72495daa8b5c158a2f6f98c8e1014833858deeadf09e818cc50244dca8a0a21f9f86669d1033945bd2348e42b886c5da79b745ac837aa3fa2 WHIRLPOOL c507afc3016f06620526af5249c1c643f4b845e4a94a2cf5b5baa88949ad42183ebbb2d7f75aa803c297873aa8d45ec7ae47fe38ef05f5397ef936cfaa7c71f4
 DIST ImageMagick-7.0.3-2.tar.xz 8292420 SHA256 d9ff718c09b88216aa3fba2f3f251b171b9e74fbda9e9e38a581ef3e4af8b363 SHA512 3d7dc8097005cb541e59ebe40dac08059ce8a7087c0ce47f1d42c14b50000e373425df4f6261b48362932df993ac78e56a84ad89ad971205320d30fb1a5e54e6 WHIRLPOOL c45a30e90a955902fa0816047c9e80d5b50877dc7d4b49658f06fd8f7f067864715fc01e018ce3fe8e5d73cb6a0b3cd36fb25a5adc07b26a63acb0cd43e460f6

diff --git a/media-gfx/imagemagick/imagemagick-6.9.6.1.ebuild b/media-gfx/imagemagick/imagemagick-6.9.6.1.ebuild
new file mode 100644
index 00000000..47260e1
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.9.6.1.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+	use q64 && depth=64
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	CONFIG_SHELL=$(type -P bash) \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k openjp2) \
+		$(use_with lcms) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp \
+		--with-gcc-arch=no-automagic
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/ati/card:/dev/dri/card"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}