[gentoo-commits] repo/gentoo:master commit in: dev-java/emma/

["Patrice Clement" <monsieurp@gentoo.org>]

commit:     f08bc4b8cfa3ace7716a2c063b63915db0d92227
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  5 08:33:13 2016 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Wed Oct  5 08:35:45 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f08bc4b8

dev-java/emma: EAPI 5 bump.

Package-Manager: portage-2.3.0

 dev-java/emma/emma-2.0.5312-r3.ebuild | 50 +++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-java/emma/emma-2.0.5312-r3.ebuild b/dev-java/emma/emma-2.0.5312-r3.ebuild
new file mode 100644
index 00000000..a27aa9c
--- /dev/null
+++ b/dev-java/emma/emma-2.0.5312-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+JAVA_PKG_IUSE="source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Free Java code coverage tool"
+HOMEPAGE="http://emma.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.zip"
+
+LICENSE="CPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~x86-fbsd"
+
+IUSE="+launcher"
+
+CDEPEND="
+	dev-java/ant-core
+	launcher? ( !sci-biology/emboss )"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6"
+
+EANT_BUILD_TARGET="build"
+
+java_prepare() {
+	epatch "${FILESDIR}/${P}-java15api.patch"
+	# bcp mangling unneccessary for 1.4+ and breaks with IBM 1.6 - bug #220463
+	sed -e '/bootclasspathref/d' -e '/extdirs/d' -i build.xml || die
+}
+
+src_install() {
+	java-pkg_dojar "dist/${PN}.jar"
+	java-pkg_dojar "dist/${PN}_ant.jar"
+	java-pkg_register-ant-task
+
+	use launcher && java-pkg_dolauncher ${PN} --main emmarun
+
+	# One of these does not have java sources
+	use source && java-pkg_dosrc */*/com 2> /dev/null
+}