* [gentoo-commits] repo/gentoo:master commit in: sci-physics/lightspeed/, sci-physics/lightspeed/files/
@ 2016-10-04 19:16 David Seifert
0 siblings, 0 replies; only message in thread
From: David Seifert @ 2016-10-04 19:16 UTC (permalink / raw
To: gentoo-commits
commit: c4f70b4a13c25530e06860bb234eab86b5070367
Author: Gerhard Bräunlich <wippbox <AT> gmx <DOT> net>
AuthorDate: Tue Sep 27 16:44:55 2016 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Tue Oct 4 19:15:22 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c4f70b4a
sci-physics/lightspeed: EAPI bump 4 -> 6
Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/2425
Signed-off-by: David Seifert <soap <AT> gentoo.org>
.../files/lightspeed-1.2a-libpng15.patch | 4 +-
sci-physics/lightspeed/lightspeed-1.2a-r2.ebuild | 76 ++++++++++++++++++++++
2 files changed, 78 insertions(+), 2 deletions(-)
diff --git a/sci-physics/lightspeed/files/lightspeed-1.2a-libpng15.patch b/sci-physics/lightspeed/files/lightspeed-1.2a-libpng15.patch
index c3909a7..db0d0faa1 100644
--- a/sci-physics/lightspeed/files/lightspeed-1.2a-libpng15.patch
+++ b/sci-physics/lightspeed/files/lightspeed-1.2a-libpng15.patch
@@ -1,5 +1,5 @@
---- src/snapshot.c
-+++ src/snapshot.c
+--- a/src/snapshot.c
++++ b/src/snapshot.c
@@ -26,6 +26,7 @@
#include "lightspeed.h"
diff --git a/sci-physics/lightspeed/lightspeed-1.2a-r2.ebuild b/sci-physics/lightspeed/lightspeed-1.2a-r2.ebuild
new file mode 100644
index 00000000..5ff012c
--- /dev/null
+++ b/sci-physics/lightspeed/lightspeed-1.2a-r2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils
+
+DEB_PATCH="${PN}_${PV}-7"
+DESCRIPTION="OpenGL interactive relativistic simulator"
+HOMEPAGE="http://lightspeed.sourceforge.net/"
+SRC_URI="
+ mirror://sourceforge/${PN}/${P}.tar.gz
+ mirror://sourceforge/${PN}/objects-1.tar.gz
+ mirror://debian/pool/main/${PN:0:1}/${PN}/${DEB_PATCH}.diff.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="nls truetype l10n_es"
+
+RDEPEND="
+ media-libs/libpng:0=
+ media-libs/tiff:0
+ virtual/opengl
+ x11-libs/gtkglext
+ x11-libs/gtkglarea:2
+ x11-libs/gtk+:2
+ x11-libs/libXmu
+ truetype? ( media-libs/ftgl )"
+
+DEPEND="${RDEPEND}
+ virtual/pkgconfig"
+
+PATCHES=(
+ "${WORKDIR}/${DEB_PATCH}.diff"
+ "${FILESDIR}"/${P}-autoconf.patch
+ "${FILESDIR}"/${P}-libpng15.patch
+)
+
+src_prepare() {
+ default
+ mv configure.{in,ac} || die
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ --with-gtk=2 \
+ $(use_enable nls) \
+ $(use_with truetype ftgl)
+}
+
+src_compile() {
+ emake
+ use l10n_es && emake es.gmo
+}
+
+src_install() {
+ default
+ newicon src/icon.xpm lightspeed.xpm
+ make_desktop_entry ${PN} "Light Speed! Relativistic Simulator"
+ newdoc debian/changelog ChangeLog.Debian
+ cd "${WORKDIR}/objects" || die
+ newdoc README objects-README
+ insinto /usr/share/${PN}
+ doins *.3ds *.lwo
+}
+
+pkg_postinst() {
+ elog
+ elog "Some 3d models have been placed in /usr/share/${PN}"
+ elog "You can load them in Light Speed! from the File menu."
+ elog
+}
^ permalink raw reply related [flat|nested] only message in thread
only message in thread, other threads:[~2016-10-04 19:16 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2016-10-04 19:16 [gentoo-commits] repo/gentoo:master commit in: sci-physics/lightspeed/, sci-physics/lightspeed/files/ David Seifert
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox