[gentoo-commits] repo/gentoo:master commit in: x11-misc/gtkdialog/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     312f6b743606d3bb860e232265736e1196a68d35
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Oct  2 10:41:53 2016 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Oct  2 10:41:53 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=312f6b74

x11-misc/gtkdialog: Depend on x11-libs/vte:0= (bug #595912).

Package-Manager: portage-2.3.1

 x11-misc/gtkdialog/gtkdialog-0.8.3-r2.ebuild | 51 ++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/x11-misc/gtkdialog/gtkdialog-0.8.3-r2.ebuild b/x11-misc/gtkdialog/gtkdialog-0.8.3-r2.ebuild
new file mode 100644
index 00000000..5a95075
--- /dev/null
+++ b/x11-misc/gtkdialog/gtkdialog-0.8.3-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools
+
+DESCRIPTION="A small utility for fast and easy GUI building"
+HOMEPAGE="https://code.google.com/p/gtkdialog/"
+SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="glade vte"
+
+RDEPEND="
+	x11-libs/gtk+:2
+	glade? ( gnome-base/libglade )
+	vte? ( x11-libs/vte:0= )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/flex
+	virtual/yacc
+"
+
+DOCS=(
+	AUTHORS
+	ChangeLog
+	TODO
+)
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.3-optdeps.patch
+)
+
+src_prepare() {
+	mv configure.{in,ac} || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with glade) $(use_with vte)
+}
+
+src_install() {
+	# Stop make install from running gtk-update-icon-cache
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=true install
+}