[gentoo-commits] repo/gentoo:master commit in: dev-python/irc/

["Alice Ferrazzi" <alicef@gentoo.org>]

commit:     946ef289ad82f79015438e3d997f05c0dd6247fd
Author:     Louis Sautier <sautier.louis <AT> gmail <DOT> com>
AuthorDate: Thu Sep 29 22:37:48 2016 +0000
Commit:     Alice Ferrazzi <alicef <AT> gentoo <DOT> org>
CommitDate: Thu Sep 29 12:35:28 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=946ef289

dev-python/irc: bump to 15.0.2

Package-Manager: portage-2.3.1

Signed-off-by: Alice Ferrazzi <alicef <AT> gentoo.org>

 dev-python/irc/Manifest          |  1 +
 dev-python/irc/irc-15.0.2.ebuild | 61 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/irc/Manifest b/dev-python/irc/Manifest
index aaa9586..7cb311f 100644
--- a/dev-python/irc/Manifest
+++ b/dev-python/irc/Manifest
@@ -1,3 +1,4 @@
 DIST irc-11.0.1.zip 120409 SHA256 25d818003780fd6d62e93d3ff32580e74c0e527c6290ae14b47af50b58339233 SHA512 fca2fe653d921c9ec65dfb2b072c16658d88d4a22ae91568b1eaf722a90179920808db157f587afe6de0055af3a04a528eb9022122e539150e5635f05b58f466 WHIRLPOOL dd9b9e8624e6bd86d27fead1f3006a2b80832d236ad21f50c147c07a27b2cc4933d68efd951dece44398dbc0299b73ba7a98e4eff2061d0e3a8a01833518113b
 DIST irc-14.2.2.tar.gz 86511 SHA256 4844413b09c8bba226bb86c7269b07ea6c925ecfc5a98758e72849e90895d828 SHA512 daa5f6ed2a5b3f0bdbd58f638d1f90a8b06769c9b7874c577cdb0753aea4a7947c82857aa1ebe6b396ea605756fa176bcca4a9d8e4bf28ef53609f96fccd0e7b WHIRLPOOL 85609370a800b82d59c46595eb5f18dcd33936469cd10692f13a6e2a519406e3725239fbddb5dc0f8d20ad7ab0c6bdb7c8770a9b5f44a86e67c430b3e5287710
 DIST irc-15.0.1.tar.gz 81773 SHA256 ea2ee4b27f821f10423790f1e87d0d3b81e1b81a23cc1f6c2f005a4236583a88 SHA512 249071491c96001344081d3b7b93dcc9d8360a0b03d73d2e1bee1f046c9a82762fd4d51c00fc358843629d17e16b9533228bea09787ea41e3ffc7fc03164fe8f WHIRLPOOL f5aff2f506778c45b826380581e367e1a026f3faee5329756feb9d612c19821f3eeab222ab28c1559f0044644e92bf23e89d15de45c91f34eee4da2e7219fab6
+DIST irc-15.0.2.tar.gz 81790 SHA256 23893c1fb21826fd9b3edf6ef49b0e1080c846761900ab06b4f1980f5cb8e2e3 SHA512 5f6daa539a9ae665b0153d97ab11f246040963d9109d84efde0a92cbe200c2a6e8126120eee11b4bc92d65d415946627116b62cde07bebeb68a7105af40f98ab WHIRLPOOL 1f28b3e343328a2c78af406944fcfac4be25a61834e1807d7a1636834a2ea9fa9775856380e8ea75df7917913756a4b971e76ab47a06e0379304dfd2e5d81e61

diff --git a/dev-python/irc/irc-15.0.2.ebuild b/dev-python/irc/irc-15.0.2.ebuild
new file mode 100644
index 00000000..683a6e5
--- /dev/null
+++ b/dev-python/irc/irc-15.0.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	dev-python/jaraco-stream[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+	dev-python/jaraco-logging[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-1.5[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	py.test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		insinto "/usr/share/doc/${PF}"
+		docompress -x "/usr/share/doc/${PF}/scripts"
+		doins -r scripts
+	fi
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}