[gentoo-commits] repo/gentoo:master commit in: dev-python/flask-mail/

["Tiziano Müller" <dev-zero@gentoo.org>]

commit:     8da4e1146d7d808412e73b5237fa2ff6ef84a3fd
Author:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 13 12:43:15 2016 +0000
Commit:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
CommitDate: Tue Sep 13 12:53:14 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8da4e114

dev-python/flask-mail: rev-bump for EAPI 6 bump and py-3.5 support

Package-Manager: portage-2.3.0

 dev-python/flask-mail/flask-mail-0.9.1-r1.ebuild | 43 ++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-python/flask-mail/flask-mail-0.9.1-r1.ebuild b/dev-python/flask-mail/flask-mail-0.9.1-r1.ebuild
new file mode 100644
index 00000000..a4142ec
--- /dev/null
+++ b/dev-python/flask-mail/flask-mail-0.9.1-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-Mail"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Flask extension for sending email"
+HOMEPAGE="http://pythonhosted.org/Flask-Mail/ https://pypi.python.org/pypi/Flask-Mail"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/speaklater[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy) )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}