[gentoo-commits] repo/gentoo:master commit in: games-board/gambit/

["Austin English" <wizardedit@gentoo.org>]

commit:     5b8de23ab638c51fbc2c80d2a108218ba67c5bd3
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  7 22:15:41 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Wed Sep  7 22:16:14 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5b8de23a

games-board/gambit: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

 games-board/gambit/gambit-1.0.3-r1.ebuild | 55 +++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/games-board/gambit/gambit-1.0.3-r1.ebuild b/games-board/gambit/gambit-1.0.3-r1.ebuild
new file mode 100644
index 00000000..fd41ce5
--- /dev/null
+++ b/games-board/gambit/gambit-1.0.3-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+CMAKE_IN_SOURCE_BUILD=true
+inherit cmake-utils
+
+MY_P="${P^}"
+
+DESCRIPTION="Qt-based chess application + engine \"gupta\""
+HOMEPAGE="https://sourceforge.net/projects/gambitchess/"
+SRC_URI="mirror://sourceforge/project/${PN}chess/${MY_P}/${MY_P}-src.tar.bz2"
+
+LICENSE="CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	dev-qt/qtopengl:4
+	media-libs/mesa
+	x11-libs/libX11"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}-src"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_ENABLE_UPDATE_CHECKER=OFF
+		-DCONFIG_GUPTA_ENGINE_DIRECTORY=/usr/bin
+		-DCONFIG_RESOURCE_PATH_PREFIX=/usr/share/${PN}/
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	emake -C engine/gupta VERBOSE=1 STRIP=/bin/true CFLAGS_RELEASE= release
+}
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins -r data/*
+
+	doicon artwork/icons/${PN}/${PN}.svg
+	make_desktop_entry ${PN}chess ${PN^} ${PN} Game
+	dodoc doc/contributors.txt
+
+	dobin engine/gupta/gupta
+	dobin ${PN}chess
+}