[gentoo-commits] repo/gentoo:master commit in: games-board/pasang-emas/

["Austin English" <wizardedit@gentoo.org>]

commit:     2d48e29f876a48d8f821a3d1cda0009ef4966b8e
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Thu Aug  4 18:35:02 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Fri Aug  5 00:22:42 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2d48e29f

games-board/pasang-emas: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

 .../pasang-emas/pasang-emas-3.1.0-r1.ebuild        | 70 ++++++++++++++++++++++
 1 file changed, 70 insertions(+)

diff --git a/games-board/pasang-emas/pasang-emas-3.1.0-r1.ebuild b/games-board/pasang-emas/pasang-emas-3.1.0-r1.ebuild
new file mode 100644
index 0000000..1347235
--- /dev/null
+++ b/games-board/pasang-emas/pasang-emas-3.1.0-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils gnome2-utils
+
+DESCRIPTION="A traditional game of Brunei"
+HOMEPAGE="http://pasang-emas.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	extras? ( mirror://sourceforge/${PN}/pasang-emas-themes-1.0.tar.bz2
+	          mirror://sourceforge/${PN}/pet-marble.tar.bz2
+	          mirror://sourceforge/${PN}/pet-fragrance.tar.bz2 )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="extras nls"
+
+RDEPEND="app-text/gnome-doc-utils
+	>=x11-libs/gtk+-2.18.2:2
+	virtual/libintl"
+DEPEND="${RDEPEND}
+	app-text/rarian
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-build.patch
+)
+
+src_prepare() {
+	default
+	sed -i \
+		-e '/Encoding/d' \
+		-e '/Icon/s:\.png::' \
+		data/pasang-emas.desktop.in || die
+	gnome2_omf_fix
+}
+
+src_configure() {
+	econf \
+		--localedir=/usr/share/locale \
+		--with-omf-dir=/usr/share/omf \
+		--with-help-dir=/usr/share/gnome/help \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+	if use extras; then
+		insinto /usr/share/${PN}/themes
+		doins -r \
+			"${WORKDIR}"/marble \
+			"${WORKDIR}"/pasang-emas-themes-1.0/{conteng,kaca} \
+			"${WORKDIR}"/fragrance
+	fi
+	use nls || rm -rf "${D}"usr/share/locale
+}
+
+pkg_preinst() {
+	gnome2_scrollkeeper_savelist
+}
+
+pkg_postinst() {
+	gnome2_scrollkeeper_update
+}
+
+pkg_postrm() {
+	gnome2_scrollkeeper_update
+}