[gentoo-commits] repo/gentoo:master commit in: net-analyzer/ssldump/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     e23e05c4049f1bc4f8101d1df6d1da3f48b047d3
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 27 05:12:36 2016 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Wed Jul 27 05:12:36 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e23e05c4

net-analyzer/ssldump: Fix HOMEPAGE/SRC_URI (bug #589784 by Jonas Stein), remove autotools-utils.

Package-Manager: portage-2.3.0
RepoMan-Options: --force

 net-analyzer/ssldump/ssldump-0.9-r2.ebuild    | 65 --------------------------
 net-analyzer/ssldump/ssldump-0.9_beta3.ebuild | 67 +++++++++++++++++++++++++++
 2 files changed, 67 insertions(+), 65 deletions(-)

diff --git a/net-analyzer/ssldump/ssldump-0.9-r2.ebuild b/net-analyzer/ssldump/ssldump-0.9-r2.ebuild
deleted file mode 100644
index fb82381..0000000
--- a/net-analyzer/ssldump/ssldump-0.9-r2.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-
-AUTOTOOLS_IN_SOURCE_BUILD=1
-AUTOTOOLS_AUTORECONF=1
-inherit autotools-utils eutils toolchain-funcs
-
-MY_P="${PN}-0.9b3"
-
-DESCRIPTION="An SSLv3/TLS network protocol analyzer"
-HOMEPAGE="http://www.rtfm.com/ssldump/"
-SRC_URI="${HOMEPAGE}${MY_P}.tar.gz"
-
-LICENSE="openssl"
-SLOT="0"
-KEYWORDS="amd64 ~arm ppc sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
-IUSE="ssl"
-
-RDEPEND="net-libs/libpcap
-	ssl? ( >=dev-libs/openssl-1 )"
-DEPEND="${RDEPEND}"
-
-S="${WORKDIR}/${MY_P}"
-
-src_prepare() {
-	epatch \
-		"${FILESDIR}"/${P}-libpcap-header.patch \
-		"${FILESDIR}"/${P}-configure-dylib.patch \
-		"${FILESDIR}"/${P}-openssl-0.9.8.compile-fix.patch \
-		"${FILESDIR}"/${P}-DLT_LINUX_SLL.patch \
-		"${FILESDIR}"/${P}-prefix-fix.patch \
-		"${FILESDIR}"/${P}-declaration.patch \
-		"${FILESDIR}"/${P}-includes.patch
-
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	local myeconfargs=(
-		--with-pcap-inc="${EPREFIX}/usr/include"
-		--with-pcap-lib="${EPREFIX}/usr/$(get_libdir)"
-	)
-
-	if use ssl; then
-		myeconfargs+=(
-			--with-openssl-inc="${EPREFIX}/usr/include"
-			--with-openssl-lib="${EPREFIX}/usr/$(get_libdir)"
-		)
-	else
-		myeconfargs+=( "--without-openssl" )
-	fi
-
-	tc-export CC
-
-	autotools-utils_src_configure
-}
-
-src_install() {
-	dosbin ssldump
-	doman ssldump.1
-	dodoc ChangeLog CREDITS README
-}

diff --git a/net-analyzer/ssldump/ssldump-0.9_beta3.ebuild b/net-analyzer/ssldump/ssldump-0.9_beta3.ebuild
new file mode 100644
index 0000000..c662c04
--- /dev/null
+++ b/net-analyzer/ssldump/ssldump-0.9_beta3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+AUTOTOOLS_IN_SOURCE_BUILD=1
+AUTOTOOLS_AUTORECONF=1
+inherit autotools eutils toolchain-funcs
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="An SSLv3/TLS network protocol analyzer"
+HOMEPAGE="http://ssldump.sourceforge.net/"
+SRC_URI="
+	http://downloads.sourceforge.net/project/${PN}/${PN}/${MY_PV}/${MY_P}.tar.gz
+"
+
+LICENSE="openssl"
+SLOT="0"
+KEYWORDS="amd64 ~arm ppc sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="ssl"
+
+RDEPEND="
+	net-libs/libpcap
+	ssl? ( >=dev-libs/openssl-1 )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9-libpcap-header.patch
+	"${FILESDIR}"/${PN}-0.9-configure-dylib.patch
+	"${FILESDIR}"/${PN}-0.9-openssl-0.9.8.compile-fix.patch
+	"${FILESDIR}"/${PN}-0.9-DLT_LINUX_SLL.patch
+	"${FILESDIR}"/${PN}-0.9-prefix-fix.patch
+	"${FILESDIR}"/${PN}-0.9-declaration.patch
+	"${FILESDIR}"/${PN}-0.9-includes.patch
+)
+
+src_prepare() {
+	default
+
+	eapply_user
+
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	econf \
+		--with-pcap-inc="${EPREFIX}/usr/include" \
+		--with-pcap-lib="${EPREFIX}/usr/$(get_libdir)" \
+		$(usex ssl --with-openssl-inc="${EPREFIX}/usr/include" '--without-openssl') \
+		$(usex ssl --with-openssl-lib="${EPREFIX}/usr/$(get_libdir)" '--without-openssl')
+}
+
+src_install() {
+	dosbin ssldump
+	doman ssldump.1
+	dodoc ChangeLog CREDITS README
+}