[gentoo-commits] repo/gentoo:master commit in: app-emulation/libvirt/

["Matthias Maier" <tamiko@gentoo.org>]

commit:     2640179a1d7f4763688398dd3bd6462a87f09b67
Author:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  9 14:33:55 2016 +0000
Commit:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Sat Jul  9 15:10:13 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2640179a

app-emulation/libvirt: version bump to 2.0.0

Package-Manager: portage-2.2.28

 app-emulation/libvirt/Manifest             |   1 +
 app-emulation/libvirt/libvirt-2.0.0.ebuild | 390 +++++++++++++++++++++++++++++
 2 files changed, 391 insertions(+)

diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index 7e8e347..92ee3fa 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -1,3 +1,4 @@
 DIST libvirt-1.2.21-20151222.tar.xz 1684 SHA256 6c97f288470ec58bcbe98507563c6a191892c6f8813a7b9688c09b823934cbe5 SHA512 4fd43f0e12434b78ac3e671ad8eb0e402d384cff6278f6d0db322a068c2c8807c7c7f7e5774aa9d19e2a85e49f6d9888908b32fca5fc04980134edaccba0afe2 WHIRLPOOL 2bfbc3cbf1ca44a2bb06ddf2e8eabeb116165560b9c73d649d7b8cc9baba851f5e9246414bfc2c4740f27d0d0d42b6176eaec43b05e8c1e54de2804150c2cde1
 DIST libvirt-1.2.21.tar.gz 29848954 SHA256 8d406582f5fe88d739d1d83e0ba7ac7f91f5a8da4be82162ab85631744d8925b SHA512 5c15d0ba5d75c13f735c6a60dfdbad007426f77e113f95894d520f7fc358fa4361d5cce7bb9a548a436f323b845f13b8940abbad568b8b146418430068bb970e WHIRLPOOL d53bbb07c85b3aa2d9b0f38ff2edd3cd0a2a5300627f3e2f0a82bc057303617cab9d6f1d8a9a771bd968b0496d38d3a39a0154f88bdca44dda359a65fdc2c650
 DIST libvirt-1.3.5.tar.gz 35109092 SHA256 93a23c44eb431da46c9458f95a66e29c9b98e37515d44b6be09e75b35ec94ac8 SHA512 6c6a09623d3d4d426311bfa7039f5e39584d5f891b8e761bbdb3022601ea066b8e1c3f8d609326e8ba4081ae40b7b03086fbc8ba5759d218b8616ec98200a89d WHIRLPOOL 88ac308cc461efff842c27e40263a3b25ce0bc0ca310fb6e9def9126ab893fe43aed01bda9fc3615439ee797c36e2800f741b346e0b3d96aac64e7909c269879
+DIST libvirt-2.0.0.tar.xz 13161096 SHA256 10e90af55e613953c0ddc60b4ac3a10c73c0f3493d7014259e3f012b2ffc9acb SHA512 1182346e9268ec50cfd191a18172ad8ca80615a111547cc72fbe227cbbe9579263a1236f80cb36542272bdbf092e2184c9060b65c56dc2098076bbd1a89dd66c WHIRLPOOL 3d6d9e307228f54993c6082f7787d678b2afe84d96b47889d1565e38da489fb99691aeb598831dff04cd9fe47448ea35dc1f5a44b3c6638816cf61533155688c

diff --git a/app-emulation/libvirt/libvirt-2.0.0.ebuild b/app-emulation/libvirt/libvirt-2.0.0.ebuild
new file mode 100644
index 0000000..5e159aa
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-2.0.0.ebuild
@@ -0,0 +1,390 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils user autotools-utils linux-info systemd readme.gentoo
+
+BACKPORTS=""
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://libvirt.org/libvirt.git"
+	SRC_URI=""
+	KEYWORDS=""
+	SLOT="0"
+else
+	# Versions with 4 numbers are stable updates:
+	if [[ ${PV} =~ ^[0-9]+(\.[0-9]+){3} ]]; then
+		SRC_URI="http://libvirt.org/sources/stable_updates/${P}.tar.xz"
+	else
+		SRC_URI="http://libvirt.org/sources/${P}.tar.xz"
+	fi
+	SRC_URI+=" ${BACKPORTS:+
+		https://dev.gentoo.org/~cardoe/distfiles/${P}-${BACKPORTS}.tar.xz
+		https://dev.gentoo.org/~tamiko/distfiles/${P}-${BACKPORTS}.tar.xz}"
+	KEYWORDS="~amd64 ~x86"
+	SLOT="0/${PV}"
+fi
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="http://www.libvirt.org/"
+LICENSE="LGPL-2.1"
+IUSE="apparmor audit avahi +caps firewalld fuse glusterfs iscsi +libvirtd lvm \
+	lxc +macvtap nfs nls numa openvz parted pcap phyp policykit +qemu rbd sasl \
+	selinux systemd +udev uml +vepa virtualbox virt-network wireshark-plugins \
+	xen"
+
+REQUIRED_USE="
+	firewalld? ( virt-network )
+	libvirtd? ( || ( lxc openvz qemu uml virtualbox xen ) )
+	lxc? ( caps libvirtd )
+	openvz? ( libvirtd )
+	qemu? ( libvirtd )
+	uml? ( libvirtd )
+	vepa? ( macvtap )
+	virt-network? ( libvirtd )
+	virtualbox? ( libvirtd )
+	xen? ( libvirtd )"
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
+# package will use 3 by default. Since we don't have slot pinning in an API,
+# we must go with the most recent
+RDEPEND="
+	app-misc/scrub
+	dev-libs/libgcrypt:0
+	dev-libs/libnl:3
+	>=dev-libs/libxml2-2.7.6
+	|| ( >=net-analyzer/netcat6-1.0-r2 >=net-analyzer/openbsd-netcat-1.105-r1 )
+	>=net-libs/gnutls-1.0.25:0=
+	net-libs/libssh2
+	>=net-misc/curl-7.18.0
+	sys-apps/dmidecode
+	>=sys-apps/util-linux-2.17
+	sys-devel/gettext
+	sys-libs/ncurses:0=
+	sys-libs/readline:=
+	apparmor? ( sys-libs/libapparmor )
+	audit? ( sys-process/audit )
+	avahi? ( >=net-dns/avahi-0.6[dbus] )
+	caps? ( sys-libs/libcap-ng )
+	firewalld? ( net-firewall/firewalld )
+	fuse? ( >=sys-fs/fuse-2.8.6 )
+	glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
+	iscsi? ( sys-block/open-iscsi )
+	lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
+	lxc? ( !systemd? ( sys-power/pm-utils ) )
+	nfs? ( net-fs/nfs-utils )
+	numa? (
+		>sys-process/numactl-2.0.2
+		sys-process/numad
+	)
+	openvz? ( sys-kernel/openvz-sources:* )
+	parted? (
+		>=sys-block/parted-1.8[device-mapper]
+		sys-fs/lvm2
+	)
+	pcap? ( >=net-libs/libpcap-1.0.0 )
+	policykit? ( >=sys-auth/polkit-0.9 )
+	qemu? (
+		>=app-emulation/qemu-0.13.0
+		dev-libs/yajl
+		!systemd? ( sys-power/pm-utils )
+	)
+	rbd? ( sys-cluster/ceph )
+	sasl? ( dev-libs/cyrus-sasl )
+	selinux? ( >=sys-libs/libselinux-2.0.85 )
+	systemd? ( sys-apps/systemd )
+	virt-network? (
+		net-dns/dnsmasq[script]
+		net-firewall/ebtables
+		>=net-firewall/iptables-1.4.10[ipv6]
+		net-misc/radvd
+		sys-apps/iproute2[-minimal]
+	)
+	virtualbox? ( || ( app-emulation/virtualbox >=app-emulation/virtualbox-bin-2.2.0 ) )
+	wireshark-plugins? ( net-analyzer/wireshark:= )
+	xen? (
+		app-emulation/xen
+		app-emulation/xen-tools:=
+	)
+	udev? (
+		virtual/udev
+		>=x11-libs/libpciaccess-0.10.9
+	)"
+
+DEPEND="${RDEPEND}
+	app-text/xhtml1
+	dev-lang/perl
+	dev-libs/libxslt
+	dev-perl/XML-XPath
+	virtual/pkgconfig"
+
+pkg_setup() {
+	enewgroup qemu 77
+	enewuser qemu 77 -1 -1 qemu kvm
+
+	# Some people used the masked ebuild which was not adding the qemu
+	# user to the kvm group originally. This results in VMs failing to
+	# start for some users. bug #430808
+	egetent group kvm | grep -q qemu
+	if [[ $? -ne 0 ]]; then
+		gpasswd -a qemu kvm
+	fi
+
+	# Check kernel configuration:
+	CONFIG_CHECK=""
+	use fuse && CONFIG_CHECK+="
+		~FUSE_FS"
+
+	use lvm && CONFIG_CHECK+="
+		~BLK_DEV_DM
+		~DM_MULTIPATH
+		~DM_SNAPSHOT"
+
+	use lxc && CONFIG_CHECK+="
+		~BLK_CGROUP
+		~CGROUP_CPUACCT
+		~CGROUP_DEVICE
+		~CGROUP_FREEZER
+		~CGROUP_NET_PRIO
+		~CGROUP_PERF
+		~CGROUPS
+		~CGROUP_SCHED
+		~CPUSETS
+		~DEVPTS_MULTIPLE_INSTANCES
+		~IPC_NS
+		~MACVLAN
+		~NAMESPACES
+		~NET_CLS_CGROUP
+		~NET_NS
+		~PID_NS
+		~POSIX_MQUEUE
+		~SECURITYFS
+		~USER_NS
+		~UTS_NS
+		~VETH
+		~!GRKERNSEC_CHROOT_MOUNT
+		~!GRKERNSEC_CHROOT_DOUBLE
+		~!GRKERNSEC_CHROOT_PIVOT
+		~!GRKERNSEC_CHROOT_CHMOD
+		~!GRKERNSEC_CHROOT_CAPS"
+	# Handle specific kernel versions for different features
+	kernel_is lt 3 6 && CONFIG_CHECK+=" ~CGROUP_MEM_RES_CTLR"
+	if $(kernel_is ge 3 6); then
+		CONFIG_CHECK+=" ~MEMCG ~MEMCG_SWAP "
+		if $(kernel_is lt 4 5); then
+			CONFIG_CHECK+=" ~MEMCG_KMEM "
+		fi
+	fi
+
+	use macvtap && CONFIG_CHECK+="
+		~MACVTAP"
+
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_MARK_T
+		~BRIDGE_NF_EBTABLES
+		~NETFILTER_ADVANCED
+		~NETFILTER_XT_CONNMARK
+		~NETFILTER_XT_MARK
+		~NETFILTER_XT_TARGET_CHECKSUM"
+	# Bandwidth Limiting Support
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_T_NAT
+		~NET_ACT_POLICE
+		~NET_CLS_FW
+		~NET_CLS_U32
+		~NET_SCH_HTB
+		~NET_SCH_INGRESS
+		~NET_SCH_SFQ"
+
+	ERROR_USER_NS="Optional depending on LXC configuration."
+
+	if [[ -n ${CONFIG_CHECK} ]]; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	touch "${S}/.mailmap"
+
+	if [[ ${PV} = *9999* ]]; then
+		# git checkouts require bootstrapping to create the configure script.
+		# Additionally the submodules must be cloned to the right locations
+		# bug #377279
+		./bootstrap || die "bootstrap failed"
+		(
+			git submodule status | sed 's/^[ +-]//;s/ .*//'
+			git hash-object bootstrap.conf
+		) >.git-module-status
+	fi
+
+	epatch \
+		"${FILESDIR}"/${PN}-1.3.0-do_not_use_sysconf.patch \
+		"${FILESDIR}"/${PN}-1.2.16-fix_paths_in_libvirt-guests_sh.patch \
+		"${FILESDIR}"/${PN}-1.3.1-fix_paths_for_apparmor.patch \
+		"${FILESDIR}"/${PN}-1.3.4-glibc-2.23.patch
+
+	[[ -n ${BACKPORTS} ]] &&
+		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" \
+			EPATCH_SOURCE="${WORKDIR}/patches" epatch
+
+	epatch_user
+
+	# Tweak the init script:
+	cp "${FILESDIR}/libvirtd.init-r16" "${S}/libvirtd.init" || die
+	sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
+		-e "s/USE_FLAG_AVAHI/$(usex avahi 'use avahi-daemon' '')/" \
+		-e "s/USE_FLAG_ISCSI/$(usex iscsi 'use iscsid' '')/" \
+		-e "s/USE_FLAG_RBD/$(usex rbd 'use ceph' '')/" \
+		-i "${S}/libvirtd.init" || die "sed failed"
+
+	AUTOTOOLS_AUTORECONF=true
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with apparmor)
+		$(use_with apparmor apparmor-profiles)
+		$(use_with audit)
+		$(use_with avahi)
+		$(use_with caps capng)
+		$(use_with firewalld)
+		$(use_with fuse)
+		$(use_with glusterfs)
+		$(use_with glusterfs storage-gluster)
+		$(use_with iscsi storage-iscsi)
+		$(use_with libvirtd)
+		$(use_with lvm storage-lvm)
+		$(use_with lvm storage-mpath)
+		$(use_with lxc)
+		$(use_with macvtap)
+		$(use_enable nls)
+		$(use_with numa numactl)
+		$(use_with numa numad)
+		$(use_with openvz)
+		$(use_with parted storage-disk)
+		$(use_with pcap libpcap)
+		$(use_with phyp)
+		$(use_with policykit polkit)
+		$(use_with qemu)
+		$(use_with qemu yajl)
+		$(use_with rbd storage-rbd)
+		$(use_with sasl)
+		$(use_with selinux)
+		$(use_with systemd systemd-daemon)
+		$(usex systemd --with-init-script=systemd '')
+		$(use_with udev)
+		$(use_with uml)
+		$(use_with vepa virtualport)
+		$(use_with virt-network network)
+		$(use_with wireshark-plugins wireshark-dissector)
+		$(use_with xen)
+		$(use_with xen xen-inotify)
+		$(usex xen --with-libxl '')
+
+		--without-hal
+		--without-netcf
+		--without-sanlock
+		--without-xenapi
+		--with-esx
+		--with-qemu-group=$(usex caps qemu root)
+		--with-qemu-user=$(usex caps qemu root)
+		--with-remote
+		--with-storage-fs
+		--with-vmware
+
+		--disable-static
+		--disable-werror
+
+		--with-html-subdir=${PF}/html
+		--localstatedir=/var
+	)
+
+	if use virtualbox && has_version app-emulation/virtualbox-ose; then
+		myeconfargs+=( --with-vbox=/usr/lib/virtualbox-ose/ )
+	else
+		myeconfargs+=( $(use_with virtualbox vbox) )
+	fi
+
+	autotools-utils_src_configure
+
+	if [[ ${PV} = *9999* ]]; then
+		# Restore gnulib's config.sub and config.guess
+		# bug #377279
+		(cd .gnulib && git reset --hard > /dev/null)
+	fi
+
+	# Workaround: Sometimes this subdirectory is missing and leads to a
+	# build failure.
+	mkdir -p "${BUILD_DIR}"/docs/internals
+}
+
+src_test() {
+	# Explicitly allow parallel build of tests
+	export VIR_TEST_DEBUG=1
+	HOME="${T}" emake check || die "tests failed"
+}
+
+src_install() {
+	autotools-utils_src_compile install \
+		DESTDIR="${D}" \
+		SYSTEMD_UNIT_DIR="$(systemd_get_unitdir)"
+
+	find "${D}" -name '*.la' -delete || die
+
+	# Remove bogus, empty directories. They are either not used, or
+	# libvirtd is able to create them on demand
+	rm -rf "${D}"/etc/sysconfig
+	rm -rf "${D}"/var/cache
+	rm -rf "${D}"/var/run
+	rm -rf "${D}"/var/log
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	use systemd && systemd_install_serviced \
+		"${FILESDIR}"/libvirtd.service.conf libvirtd.service
+
+	systemd_newtmpfilesd "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
+
+	newinitd "${S}/libvirtd.init" libvirtd || die
+	newinitd "${FILESDIR}/libvirt-guests.init-r2" libvirt-guests || die
+	newinitd "${FILESDIR}/virtlockd.init-r1" virtlockd || die
+	newinitd "${FILESDIR}/virtlogd.init-r1" virtlogd || die
+
+	newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd || die
+	newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests || die
+
+	DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r1")
+	DISABLE_AUTOFORMATTING=true
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	# we only ever want to generate this once
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
+	fi
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml
+	fi
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	if [[ -n ${REPLACING_VERSIONS} ]] && ! version_is_at_least 1.2.18-r2 ${REPLACING_VERSIONS} ]]; then
+		FORCE_PRINT_ELOG=true
+	fi
+
+	DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r1")
+	DISABLE_AUTOFORMATTING=true
+	readme.gentoo_print_elog
+}