[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-tweak-tool/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     5e566f0c83aaa287ee7586b324aea172e4f33b08
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 25 18:37:03 2016 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 18:43:17 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e566f0c

gnome-extra/gnome-tweak-tool: Version bump, drop obsolete patches

Package-Manager: portage-2.3.0_rc1

 gnome-extra/gnome-tweak-tool/Manifest              |  1 +
 .../gnome-tweak-tool-3.20.1.ebuild                 | 72 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/gnome-extra/gnome-tweak-tool/Manifest b/gnome-extra/gnome-tweak-tool/Manifest
index afc7505..72e0ff4 100644
--- a/gnome-extra/gnome-tweak-tool/Manifest
+++ b/gnome-extra/gnome-tweak-tool/Manifest
@@ -1 +1,2 @@
 DIST gnome-tweak-tool-3.18.1.tar.xz 252716 SHA256 5c2c1103237648413c2d63a941e06b7057d6b102276b5968517753075de29430 SHA512 0e7d05292dc961e25efb8b410fca20281541ac9cecde307a733c0c95a370255cf790dcef0d708544b1174c95184550a966466ac510ced6ba69d2e82508433cf5 WHIRLPOOL 35d4049d370ada31ec558881e93f4f22ac3384b9e6ae8f6b78eebe7a732283555021a2cd98cfa6238570baaa23d6cba2ee0a3603e9e0a84e3cd745e67a8c3e9b
+DIST gnome-tweak-tool-3.20.1.tar.xz 255988 SHA256 5171b2f75ceeea9455543e999a83a71e8566947f89eb9157aaff7969b7e446ba SHA512 d1943a9f0d7e4ec0c2399276342dfc9418ed161a5583eb44543e76f22d883b39c54dc701ad3aae8827624f75f7ee53f3b8e4e7804a07ff11716d1a134fc25ddf WHIRLPOOL 84478cabaf6d7513dab84ebb83cb9c93bfdcbbb537e642840f96671131c93cd1084d39e79e16d47b7dfe181941febe6a0e36aa38d16faeff1cf7d47bbcfe3215

diff --git a/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.20.1.ebuild b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.20.1.ebuild
new file mode 100644
index 0000000..273eed2
--- /dev/null
+++ b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.20.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils gnome2 python-r1
+
+DESCRIPTION="Tool to customize GNOME 3 options"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/GnomeTweakTool"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Newer pygobject needed due upstream bug #723951
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	dev-libs/glib:2[dbus]
+	>=dev-python/pygobject-3.10.2:3[${PYTHON_USEDEP}]
+	>=gnome-base/gsettings-desktop-schemas-3.4
+"
+# g-s-d, gnome-desktop, gnome-shell etc. needed at runtime for the gsettings schemas
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/gnome-desktop-3.6.0.1:3=[introspection]
+	>=x11-libs/gtk+-3.12:3[introspection]
+
+	net-libs/libsoup:2.4[introspection]
+	x11-libs/libnotify[introspection]
+
+	>=gnome-base/gnome-settings-daemon-3
+	gnome-base/gnome-shell
+	>=gnome-base/nautilus-3
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Add contents of Gentoo's cursor theme directory to cursor theme list
+	eapply "${FILESDIR}/${PN}-3.10.1-gentoo-cursor-themes.patch"
+
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	install_python() {
+		gnome2_src_install
+		python_doscript gnome-tweak-tool || die
+	}
+	python_foreach_impl run_in_build_dir install_python
+}