[gentoo-commits] repo/gentoo:master commit in: app-crypt/gcr/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     f3cf8ba748d9ac6478fec5c98a9006f5c6604348
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 24 19:51:56 2016 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Fri Jun 24 20:06:28 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f3cf8ba7

app-crypt/gcr: Version bump

Package-Manager: portage-2.3.0_rc1

 app-crypt/gcr/Manifest          |  1 +
 app-crypt/gcr/gcr-3.20.0.ebuild | 77 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index d71be51..fdeff4c 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -1,2 +1,3 @@
 DIST gcr-3.16.0.tar.xz 1335348 SHA256 ecfe8df41cc88158364bb15addc670b11e539fe844742983629ba2323888d075 SHA512 1db6e2532d2d0ceb6f339551b009baae5815fcf8a12b76b0eb9e13f301d1205c2e2c9b8f555ae011a84521e55fe9cccb703c3dd539d638b476e0474c34672be4 WHIRLPOOL 88a0d5936b6dd54923fd476f3af0acac9c068268416cb30c65670ae8bf8bec3940cdee84e72e6218c3cf9e59a023508e5961357b2e80a297428e573cddc6bd7b
 DIST gcr-3.18.0.tar.xz 1311368 SHA256 d4d16da5af55148a694055835ccd07ad34daf0ad03bdad929bf7cad15637ce00 SHA512 3733a462c23b0cf1d3579ea4b0b6eea9b5e3eb98e81e7c0e0364e540ec60a7a7bc567d1d159c674df280fb20c305cbaef796dffef73801ece4f4474352786e6b WHIRLPOOL 1bb299e386415c86dbb4f6afb48e365fd69e12a13e7349cefcd05c2685841fb0fb76c499780c2e275114c185a67b6be66989c6f989794ebbf1fd18ca501ed4b6
+DIST gcr-3.20.0.tar.xz 1324216 SHA256 90572c626d8a708225560c42b4421f7941315247fa1679d4ef569bde7f4bb379 SHA512 0acd0fb085a38507b1cc895ac773f91c6f4e14d2ea7e27b8e74c85ef78426597b6ea08ebee696452b0651939ec4a0d8a4a2523c41b3a8a0bd1b0d7b338b1d9c7 WHIRLPOOL f9872c7c0f2480b868451775b5a7c63f7cba0d00702660417b738c6260706c8144bf73d36ddd0339b3acbfc010b4ceddef080a3dc1570de875b061e2053ba46f

diff --git a/app-crypt/gcr/gcr-3.20.0.ebuild b/app-crypt/gcr/gcr-3.20.0.ebuild
new file mode 100644
index 0000000..e1000e9
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.20.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://git.gnome.org/browse/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-3
+
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+COMMON_DEPEND="
+	>=app-crypt/p11-kit-0.19
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3.12:3[X,introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-keyring-3.3
+"
+# gcr was part of gnome-keyring until 3.3
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection-common
+	dev-libs/libxslt
+	dev-libs/vala-common
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+#	dev-libs/vala-common
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid flag changes
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
+src_test() {
+	virtx emake check
+}