[gentoo-commits] repo/gentoo:master commit in: media-libs/opencollada/

["Amy Winston" <amynka@gentoo.org>]

commit:     cac421555fb2e9112905a35ca1da2987df864d80
Author:     Jonathan Scruggs <j.scruggs <AT> gmail <DOT> com>
AuthorDate: Sun Jun  5 07:06:23 2016 +0000
Commit:     Amy Winston <amynka <AT> gentoo <DOT> org>
CommitDate: Sun Jun 12 17:52:17 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cac42155

media-libs/opencollada: Version bump to 1.6.18 and update to EAPI 6

-Version bump to v1.6.18: Upstream releasing proper versions now
-Using full EAPI compliance for new and live ebuild
-Delete old patches not in use anymore
-Closes Gentoo Bug: 584670
-Fixes based on help from gentoo-proxy-maint
-Changed comments to explain that certain things are needed

 media-libs/opencollada/Manifest                  |  1 +
 media-libs/opencollada/opencollada-1.6.18.ebuild | 77 ++++++++++++++++++++
 media-libs/opencollada/opencollada-9999.ebuild   | 89 ++++++++++--------------
 3 files changed, 115 insertions(+), 52 deletions(-)

diff --git a/media-libs/opencollada/Manifest b/media-libs/opencollada/Manifest
index a7fa6d3..312c011 100644
--- a/media-libs/opencollada/Manifest
+++ b/media-libs/opencollada/Manifest
@@ -1 +1,2 @@
 DIST opencollada-1.2.2_p20150207.tar.gz 11715849 SHA256 b6a4362c559d790a04dfef4606cb0a0ffe01e34708f898bf3453e69318bc5cc1 SHA512 0780e4401f130832d9802ddd6183ac11294ed84f43e0b497673c66fa2c1ae47ebc853484f8e68871887a1e99ab1f1df786cfc6ebd5868f039d9101ab82646f09 WHIRLPOOL 4cf7c7f03caf37e4c9342e139ed036b3c43984917ac4a3876e464f2065e2c515e2e85e5408d32901572d6b56a94d82963f5a2e6d3bb17dec04ecf35ee8be2d98
+DIST opencollada-1.6.18.tar.gz 11807970 SHA256 9835aa0b6efdb6602e58a84ee245a443002dc7196af3b7660e6888680d5d5990 SHA512 e4f72c41c8c619bbfb842517fb1217f616ebe6d9576ef0b7fd8bcb26443b66245107e8d04475c32946b7b73bf093977d1911d486f2d2ae92a165cfde55f67baa WHIRLPOOL 7d35758667c7a1293c376712d47cae0f87ea243e04de9fc526297805fa59f405510584ac6d79c13f77f80f1ef0e6cbea05692b3c65a09d88031dd220b4132ead

diff --git a/media-libs/opencollada/opencollada-1.6.18.ebuild b/media-libs/opencollada/opencollada-1.6.18.ebuild
new file mode 100644
index 0000000..53164b4
--- /dev/null
+++ b/media-libs/opencollada/opencollada-1.6.18.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+EGIT_REPO_URI="https://github.com/KhronosGroup/OpenCOLLADA.git"
+inherit multilib cmake-utils
+[[ ${PV} == "9999" ]] && inherit git-r3
+
+DESCRIPTION="Stream based read/write library for COLLADA files"
+HOMEPAGE="http://www.opencollada.org/"
+[[ ${PV} == "9999" ]] || \
+	SRC_URI="https://github.com/KhronosGroup/OpenCOLLADA/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+[[ ${PV} == "9999" ]] || \
+	KEYWORDS="~amd64 ~ppc64 ~x86" \
+	S="${WORKDIR}"/OpenCOLLADA-${PV}
+
+IUSE="expat static-libs"
+
+# This is still needed to have so version numbers
+MY_SOVERSION="1.6"
+
+RDEPEND="dev-libs/libpcre
+	dev-libs/zziplib
+	media-libs/lib3ds
+	sys-libs/zlib
+	expat? ( dev-libs/expat )
+	!expat? ( dev-libs/libxml2 )"
+DEPEND="${RDEPEND}"
+
+# This is needed or you get an error on install
+BUILD_DIR="${S}"/build
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0_p864-expat.patch
+	"${FILESDIR}"/${PN}-1.2.2-soversion.patch
+	"${FILESDIR}"/${PN}-1.2.2-no-undefined.patch
+	"${FILESDIR}"/${PN}-1.2.2-libdir.patch
+)
+
+src_prepare() {
+	edos2unix CMakeLists.txt
+
+	default
+
+	# Remove bundled depends that have portage equivalents
+	rm -R Externals/{expat,lib3ds,LibXML,pcre,zlib,zziplib} || die
+
+	# Remove unused build systems
+	rm Makefile scripts/{unixbuild.sh,vcproj2cmake.rb} || die
+	find "${S}" -name SConscript -delete || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_SHARED=ON
+		-DUSE_STATIC=$(usex static-libs ON OFF)
+		-DUSE_EXPAT=$(usex expat ON OFF)
+		-DUSE_LIBXML=$(usex !expat ON OFF)
+		-Dsoversion=${MY_SOVERSION}
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	echo "LDPATH=/usr/$(get_libdir)/opencollada" > "${T}"/99${PN}; \
+		doenvd "${T}"/99${PN}
+
+	dobin build/bin/OpenCOLLADAValidator
+}

diff --git a/media-libs/opencollada/opencollada-9999.ebuild b/media-libs/opencollada/opencollada-9999.ebuild
index 821ee69..53164b4 100644
--- a/media-libs/opencollada/opencollada-9999.ebuild
+++ b/media-libs/opencollada/opencollada-9999.ebuild
@@ -1,65 +1,54 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
-if [[ ${PV} == *9999* ]] ; then
-	SCM_ECLASS="git-r3"
-else
-	SCM_ECLASS="vcs-snapshot"
-fi
-
-inherit versionator eutils multilib cmake-utils ${SCM_ECLASS}
+EGIT_REPO_URI="https://github.com/KhronosGroup/OpenCOLLADA.git"
+inherit multilib cmake-utils
+[[ ${PV} == "9999" ]] && inherit git-r3
 
 DESCRIPTION="Stream based read/write library for COLLADA files"
 HOMEPAGE="http://www.opencollada.org/"
-LICENSE="MIT"
-IUSE="expat"
-
-# seems like the Khronos Group hasnt invented the SOVERSION yet
-MY_SOVERSION="1.2"
+[[ ${PV} == "9999" ]] || \
+	SRC_URI="https://github.com/KhronosGroup/OpenCOLLADA/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
+LICENSE="MIT"
 SLOT="0"
+[[ ${PV} == "9999" ]] || \
+	KEYWORDS="~amd64 ~ppc64 ~x86" \
+	S="${WORKDIR}"/OpenCOLLADA-${PV}
+
+IUSE="expat static-libs"
 
-if [[ ${PV} != *9999* ]]; then
-	#
-	# UPDATE THE COMMIT WHEN BUMPING!
-	COMMIT="ceb409cabdccda3000aa2e5c065850b8fde60b0f"
-	#
-	SRC_URI="https://github.com/KhronosGroup/OpenCOLLADA/tarball/${COMMIT} -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~ppc64 ~x86"
-else
-	EGIT_REPO_URI="https://github.com/KhronosGroup/OpenCOLLADA.git"
-fi
+# This is still needed to have so version numbers
+MY_SOVERSION="1.6"
 
 RDEPEND="dev-libs/libpcre
 	dev-libs/zziplib
 	media-libs/lib3ds
 	sys-libs/zlib
-	>=sys-devel/gcc-4.7
 	expat? ( dev-libs/expat )
 	!expat? ( dev-libs/libxml2 )"
-DEPEND="${RDEPEND}
-	sys-apps/findutils
-	sys-apps/sed"
+DEPEND="${RDEPEND}"
 
+# This is needed or you get an error on install
 BUILD_DIR="${S}"/build
 
-src_prepare() {
-
-	# Remove some bundled dependencies
-	edos2unix CMakeLists.txt || die
+PATCHES=(
+	"${FILESDIR}"/${PN}-0_p864-expat.patch
+	"${FILESDIR}"/${PN}-1.2.2-soversion.patch
+	"${FILESDIR}"/${PN}-1.2.2-no-undefined.patch
+	"${FILESDIR}"/${PN}-1.2.2-libdir.patch
+)
 
-	epatch "${FILESDIR}"/${PN}-0_p864-expat.patch
+src_prepare() {
+	edos2unix CMakeLists.txt
 
-	epatch "${FILESDIR}"/${PN}-1.2.2-soversion.patch
-	epatch "${FILESDIR}"/${PN}-1.2.2-no-undefined.patch
-	epatch "${FILESDIR}"/${PN}-1.2.2-libdir.patch
+	default
 
+	# Remove bundled depends that have portage equivalents
 	rm -R Externals/{expat,lib3ds,LibXML,pcre,zlib,zziplib} || die
-	ewarn "$(echo "Remaining bundled dependencies:";
-		find Externals -mindepth 1 -maxdepth 1 -type d | sed 's|^|- |')"
 
 	# Remove unused build systems
 	rm Makefile scripts/{unixbuild.sh,vcproj2cmake.rb} || die
@@ -67,16 +56,13 @@ src_prepare() {
 }
 
 src_configure() {
-	local mycmakeargs=" -DUSE_SHARED=ON -DUSE_STATIC=OFF"
-
-	# Master CMakeLists.txt says "EXPAT support not implemented"
-	# Something like "set(LIBEXPAT_LIBRARIES expat)" is missing to make it build
-	use expat \
-		&& mycmakeargs+=' -DUSE_EXPAT=ON -DUSE_LIBXML=OFF' \
-		|| mycmakeargs+=' -DUSE_EXPAT=OFF -DUSE_LIBXML=ON'
-
-	# Seems like the Khronos Group hasnt invented the SOVERSION yet.
-	mycmakeargs+=" -Dsoversion=${MY_SOVERSION}"
+	local mycmakeargs=(
+		-DUSE_SHARED=ON
+		-DUSE_STATIC=$(usex static-libs ON OFF)
+		-DUSE_EXPAT=$(usex expat ON OFF)
+		-DUSE_LIBXML=$(usex !expat ON OFF)
+		-Dsoversion=${MY_SOVERSION}
+	)
 
 	cmake-utils_src_configure
 }
@@ -84,9 +70,8 @@ src_configure() {
 src_install() {
 	cmake-utils_src_install
 
-	dodir /etc/env.d || die
-	echo "LDPATH=/usr/$(get_libdir)/opencollada" \
-			> "${D}"/etc/env.d/99opencollada || die
+	echo "LDPATH=/usr/$(get_libdir)/opencollada" > "${T}"/99${PN}; \
+		doenvd "${T}"/99${PN}
 
-	dobin build/bin/OpenCOLLADAValidator || die
+	dobin build/bin/OpenCOLLADAValidator
 }