[gentoo-commits] repo/gentoo:master commit in: net-irc/weechat/

["Tim Harder" <radhermit@gentoo.org>]

commit:     65210f217303ca532ac9d588b4f4c204c24c6b85
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Mon May  2 21:29:08 2016 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Mon May  2 21:29:47 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65210f21

net-irc/weechat: version bump to 1.5

 net-irc/weechat/Manifest           |   1 +
 net-irc/weechat/weechat-1.5.ebuild | 143 +++++++++++++++++++++++++++++++++++++
 2 files changed, 144 insertions(+)

diff --git a/net-irc/weechat/Manifest b/net-irc/weechat/Manifest
index 4fe5d7f..2f5404a 100644
--- a/net-irc/weechat/Manifest
+++ b/net-irc/weechat/Manifest
@@ -2,3 +2,4 @@ DIST weechat-1.1.1.tar.bz2 2305377 SHA256 810bf0584fd5888246797fc7f1bbc4facb064a
 DIST weechat-1.2.tar.bz2 2367277 SHA256 7c4501401f3794d551331b3cede354895962858acc50437567ffd40fa7af684d SHA512 dd806c1e63e5abab8fcc2f84a615eae8769fc9271f89abb19fae9ef4489e86e132a8d6a4843714a3c772c064c9060e4b63f7433fe6beddd3e675ba08a744a1f9 WHIRLPOOL 8d9d5db2f3628e41f7b186ae80189113645f64dff407b5b64f602deefcf821b2457225d57d2cb1dee6b4c014704013c48fbc26423f6a39b762a0c55439bfb908
 DIST weechat-1.3.tar.bz2 2402422 SHA256 703dd771f74a2391bab656992712331d9151a227ac3210393a4ecf6458605148 SHA512 82159f1c630bf389e7a3b8baf29b67c50711e1a767040440c71bfd7d3cd0c3005b7423e6dd53c2437512cc68953f540039971a4e6f6d7a4cdb4a4e74e4c3985b WHIRLPOOL 325b0feec0571d07494b2b5c863999d4f0bfa8f9698144624e5b8ec4c3c3180a1c3bc252647f3ba52f4cc46de788a450a122f2f3ac028ca333cb0c124fb70d8c
 DIST weechat-1.4.tar.bz2 2464362 SHA256 e06d9949ccececdd9692c95c41304c2f7fe9ec47b5eedd0d0a8529f6a3c1ddd4 SHA512 4c4bf25da513c25a16b24d94c1a6971db12d5cf168c83aa97570ffff53c634f7b25e92f1dbe54fefd09eeb69ece9ddc4be115bb6f6fc078ef7682dcb1df21f04 WHIRLPOOL 1db202131c1cd68e0f436f2e316ad73d0887d48533c417c1446a671bc620fdaaedb6198ac23876d62a51458ab55231d528635fc4e7fa2aa0067c60f656e3d6e5
+DIST weechat-1.5.tar.bz2 2546183 SHA256 326e27c4f0548a7c6f21302516356f1e9e3541262b31058e37181f95205c8c58 SHA512 8999ffd4f5034f973f790bf7e0e6b1bacd73ab588d7dce7dcbea15861efb766510d1a2f722b9fa86b52a8345aef37918f3c949b85a0451e19485cee4e76d45b2 WHIRLPOOL 51f91af5fccfe242712f5e21a9934d75747ca2a2ea31bd25194c6a37ba32e3dc519eb46da13fdf15f6483c2cc9bc0a80a1a6f296c0f31069b0339fe4fad6d5c3

diff --git a/net-irc/weechat/weechat-1.5.ebuild b/net-irc/weechat/weechat-1.5.ebuild
new file mode 100644
index 0000000..6c4d473
--- /dev/null
+++ b/net-irc/weechat/weechat-1.5.ebuild
@@ -0,0 +1,143 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+inherit eutils python-single-r1 multilib cmake-utils
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/weechat/weechat.git"
+else
+	SRC_URI="https://weechat.org/files/src/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Portable and multi-interface IRC client"
+HOMEPAGE="http://weechat.org/"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+NETWORKS="+irc"
+PLUGINS="+alias +charset +exec +fifo +logger +relay +scripts +spell +trigger +xfer"
+#INTERFACES="+ncurses gtk"
+# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
+SCRIPT_LANGS="guile lua +perl +python ruby tcl"
+LANGS=" cs de es fr hu it ja pl pt pt_BR ru tr"
+IUSE="doc nls +ssl test ${LANGS// / linguas_} ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
+#REQUIRED_USE=" || ( ncurses gtk )"
+
+RDEPEND="
+	dev-libs/libgcrypt:0=
+	net-misc/curl[ssl]
+	sys-libs/ncurses:0=
+	sys-libs/zlib
+	charset? ( virtual/libiconv )
+	guile? ( dev-scheme/guile:12 )
+	lua? ( dev-lang/lua:0[deprecated] )
+	nls? ( virtual/libintl )
+	perl? ( dev-lang/perl )
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( || ( dev-lang/ruby:2.3 dev-lang/ruby:2.2 dev-lang/ruby:2.1 dev-lang/ruby:2.0 ) )
+	ssl? ( net-libs/gnutls )
+	spell? ( app-text/aspell )
+	tcl? ( >=dev-lang/tcl-8.4.15:0= )
+"
+#	ncurses? ( sys-libs/ncurses )
+#	gtk? ( x11-libs/gtk+:2 )
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/asciidoc
+		dev-util/source-highlight
+	)
+	nls? ( >=sys-devel/gettext-0.15 )
+	test? ( dev-util/cpputest )
+"
+
+DOCS="AUTHORS.asciidoc ChangeLog.asciidoc ReleaseNotes.asciidoc README.asciidoc"
+
+# tests need to be fixed to not use system plugins if weechat is already installed
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.2-tinfo.patch )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+
+	epatch "${PATCHES[@]}"
+
+	# fix libdir placement
+	sed -i \
+		-e "s:lib/:$(get_libdir)/:g" \
+		-e "s:lib\":$(get_libdir)\":g" \
+		CMakeLists.txt || die "sed failed"
+
+	# install only required translations
+	local i
+	for i in ${LANGS} ; do
+		if ! use linguas_${i} ; then
+			sed -i \
+				-e "/${i}.po/d" \
+				po/CMakeLists.txt || die
+		fi
+	done
+
+	# install only required documentation ; en always
+	for i in `grep ADD_SUBDIRECTORY doc/CMakeLists.txt \
+			| sed -e 's/.*ADD_SUBDIRECTORY( \(..\) ).*/\1/' -e '/en/d'`; do
+		if ! use linguas_${i} ; then
+			sed -i \
+				-e '/ADD_SUBDIRECTORY( '${i}' )/d' \
+				doc/CMakeLists.txt || die
+		fi
+	done
+}
+
+src_configure() {
+	# $(cmake-utils_use_enable gtk)
+	# $(cmake-utils_use_enable ncurses)
+	local mycmakeargs=(
+		"-DENABLE_NCURSES=ON"
+		"-DENABLE_LARGEFILE=ON"
+		"-DENABLE_DEMO=OFF"
+		"-DENABLE_GTK=OFF"
+		"-DENABLE_JAVASCRIPT=OFF"
+		$(cmake-utils_use_enable alias)
+		$(cmake-utils_use_enable doc)
+		$(cmake-utils_use_enable charset)
+		$(cmake-utils_use_enable exec)
+		$(cmake-utils_use_enable fifo)
+		$(cmake-utils_use_enable guile)
+		$(cmake-utils_use_enable irc)
+		$(cmake-utils_use_enable logger)
+		$(cmake-utils_use_enable lua)
+		$(cmake-utils_use_enable nls)
+		$(cmake-utils_use_enable perl)
+		$(cmake-utils_use_enable python)
+		$(cmake-utils_use_enable relay)
+		$(cmake-utils_use_enable ruby)
+		$(cmake-utils_use_enable scripts)
+		$(cmake-utils_use_enable scripts script)
+		$(cmake-utils_use_enable spell ASPELL)
+		$(cmake-utils_use_enable ssl GNUTLS)
+		$(cmake-utils_use_enable tcl)
+		$(cmake-utils_use_enable test TESTS)
+		$(cmake-utils_use_enable trigger)
+		$(cmake-utils_use_enable xfer)
+	)
+
+	if use python; then
+		python_export PYTHON_LIBPATH
+		mycmakeargs+=(
+			-DPYTHON_EXECUTABLE="${PYTHON}"
+			-DPYTHON_LIBRARY="${PYTHON_LIBPATH}"
+		)
+	fi
+
+	cmake-utils_src_configure
+}