From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-877925-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	by finch.gentoo.org (Postfix) with ESMTP id 5D5571381F4
	for <garchives@archives.gentoo.org>; Sat, 23 Apr 2016 12:20:46 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 22988E080B;
	Sat, 23 Apr 2016 12:20:43 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 86F2CE080B
	for <gentoo-commits@lists.gentoo.org>; Sat, 23 Apr 2016 12:20:42 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 8519A340CC4
	for <gentoo-commits@lists.gentoo.org>; Sat, 23 Apr 2016 12:20:41 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 76E66CB
	for <gentoo-commits@lists.gentoo.org>; Sat, 23 Apr 2016 12:20:39 +0000 (UTC)
From: "Jeroen Roovers" <jer@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Jeroen Roovers" <jer@gentoo.org>
Message-ID: <1461414037.c229a1ea54de5ede49e0aba2e08380da05bbca06.jer@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-analyzer/wireshark/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-analyzer/wireshark/Manifest net-analyzer/wireshark/wireshark-2.0.3.ebuild
X-VCS-Directories: net-analyzer/wireshark/
X-VCS-Committer: jer
X-VCS-Committer-Name: Jeroen Roovers
X-VCS-Revision: c229a1ea54de5ede49e0aba2e08380da05bbca06
X-VCS-Branch: master
Date: Sat, 23 Apr 2016 12:20:39 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 140090ec-9776-42f4-9000-7c0aa620d3d7
X-Archives-Hash: b346cf879de852fbd164afd9ef8c8a40

commit:     c229a1ea54de5ede49e0aba2e08380da05bbca06
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 23 12:19:28 2016 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sat Apr 23 12:20:37 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c229a1ea

net-analyzer/wireshark: Version bump (bug #580882 by Frank Krömmelbein).

Package-Manager: portage-2.2.28

 net-analyzer/wireshark/Manifest               |   1 +
 net-analyzer/wireshark/wireshark-2.0.3.ebuild | 266 ++++++++++++++++++++++++++
 2 files changed, 267 insertions(+)

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index b35335a..da24a94 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -1 +1,2 @@
 DIST wireshark-2.0.2.tar.bz2 31073440 SHA256 e921fb072085a5654d899949bb561d0687f4819f7b63ba35777bb949a9b6b9c1 SHA512 a3645f0c2600091d3af76d12db4b73f83e6af4686a1bd7a336a420e4d7505ed281dfabb05c05cd6f58084fa3f25b6b9014b6f273b875c713ee39c77b4c5c715f WHIRLPOOL 4041698412d96ce495e2b564c897b4d770eea1851e431b43b2ef1bc6834bf57460ace5cc2e3f9ae6e05babbbec85e096ee1a87bc68211677202215c4dd0b53e5
+DIST wireshark-2.0.3.tar.bz2 31110988 SHA256 e196376e75fe21fdef41b4eaa27ce2e1b2b561e7f7b20328a8e96657cc4465fc SHA512 37d64b5f84249f263eae3159794450f642857c91d4fffe483cd562fa8abc93cc8a3152f66ca6b6230b2990e36c28a4ffbf696ff630058990154946eed457f076 WHIRLPOOL 7bb07556b047e9bee0ef7eac7a42dd47c32d93a44dde4abc0bff946e06f8f3685c273707246f9429f32a4d8802a1912a29078aceb78a712a171691ccdccf2831

diff --git a/net-analyzer/wireshark/wireshark-2.0.3.ebuild b/net-analyzer/wireshark/wireshark-2.0.3.ebuild
new file mode 100644
index 0000000..6ac1120
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-2.0.3.ebuild
@@ -0,0 +1,266 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils fcaps flag-o-matic multilib qmake-utils qt4-r2 user
+
+DESCRIPTION="A network protocol analyzer formerly known as ethereal"
+HOMEPAGE="http://www.wireshark.org/"
+SRC_URI="${HOMEPAGE}download/src/all-versions/${P/_/}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="
+	adns androiddump +caps crypt doc doc-pdf geoip +gtk3 ipv6 kerberos lua
+	+netlink +pcap portaudio +qt4 qt5 selinux sbc smi tfshark
+	cpu_flags_x86_sse4_2 ssl zlib
+"
+REQUIRED_USE="
+	ssl? ( crypt )
+	?? ( qt4 qt5 )
+"
+
+S=${WORKDIR}/${P/_/}
+
+GTK_COMMON_DEPEND="
+	x11-libs/gdk-pixbuf
+	x11-libs/pango
+	x11-misc/xdg-utils
+"
+CDEPEND="
+	>=dev-libs/glib-2.14:2
+	netlink? ( dev-libs/libnl:3 )
+	adns? ( >=net-dns/c-ares-1.5 )
+	crypt? ( dev-libs/libgcrypt:0 )
+	caps? ( sys-libs/libcap )
+	geoip? ( dev-libs/geoip )
+	gtk3? (
+		${GTK_COMMON_DEPEND}
+		x11-libs/gtk+:3
+	)
+	kerberos? ( virtual/krb5 )
+	lua? ( >=dev-lang/lua-5.1:* )
+	pcap? ( net-libs/libpcap )
+	portaudio? ( media-libs/portaudio )
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4[accessibility]
+		x11-misc/xdg-utils
+		)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+		x11-misc/xdg-utils
+	)
+	sbc? ( media-libs/sbc )
+	smi? ( net-libs/libsmi )
+	ssl? ( net-libs/gnutls )
+	zlib? ( sys-libs/zlib !=sys-libs/zlib-1.2.4 )
+"
+# We need perl for `pod2html`.  The rest of the perl stuff is to block older
+# and broken installs. #455122
+DEPEND="
+	${CDEPEND}
+	dev-lang/perl
+	!<virtual/perl-Pod-Simple-3.170
+	!<perl-core/Pod-Simple-3.170
+	doc? (
+		app-doc/doxygen
+		app-text/asciidoc
+		dev-libs/libxml2
+		dev-libs/libxslt
+		doc-pdf? ( dev-java/fop )
+		www-client/lynx
+	)
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+RDEPEND="
+	${CDEPEND}
+	gtk3? ( virtual/freedesktop-icon-theme )
+	qt4? ( virtual/freedesktop-icon-theme )
+	qt5? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+
+pkg_setup() {
+	enewgroup wireshark
+}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.6.13-ldflags.patch \
+		"${FILESDIR}"/${PN}-1.11.0-oldlibs.patch \
+		"${FILESDIR}"/${PN}-99999999-pkgconfig.patch \
+		"${FILESDIR}"/${PN}-1.99.8-qtchooser.patch \
+		"${FILESDIR}"/${PN}-2.0.0-androiddump-pcap.patch \
+		"${FILESDIR}"/${PN}-2.1.0-sse4_2.patch
+
+	epatch_user
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				myconf+=( "--with-ssl" )
+				;;
+		esac
+	fi
+
+	# Enable wireshark binary with any supported GUI toolkit (bug #473188)
+	if use gtk3 || use qt4 || use qt5; then
+		myconf+=( "--enable-wireshark" )
+	else
+		myconf+=( "--disable-wireshark" )
+	fi
+
+	if ! use qt4 && ! use qt5; then
+		myconf+=( "--with-qt=no" )
+	fi
+
+	if use qt4; then
+		export QT_MIN_VERSION=4.6.0
+	fi
+
+	if use qt5; then
+		export QT_MIN_VERSION=5.3.0
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# Hack around inability to disable doxygen/fop doc generation
+	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
+	use doc-pdf || export ac_cv_prog_HAVE_FOP=false
+
+	# dumpcap requires libcap
+	# --disable-profile-build bugs #215806, #292991, #479602
+	econf \
+		$(use androiddump && use pcap && echo --enable-androiddump-use-libpcap=yes) \
+		$(use_enable androiddump) \
+		$(use_enable ipv6) \
+		$(use_enable tfshark) \
+		$(use_with adns c-ares) \
+		$(use_with caps libcap) \
+		$(use_with crypt gcrypt) \
+		$(use_with geoip) \
+		$(use_with gtk3) \
+		$(use_with kerberos krb5) \
+		$(use_with lua) \
+		$(use_with pcap dumpcap-group wireshark) \
+		$(use_with pcap) \
+		$(use_with portaudio) \
+		$(usex qt4 --with-qt=4 '') \
+		$(usex qt5 --with-qt=5 '') \
+		$(usex qt4 MOC=$(qt4_get_bindir)/moc '') \
+		$(usex qt4 RCC=$(qt4_get_bindir)/rcc '') \
+		$(usex qt4 UIC=$(qt4_get_bindir)/uic '') \
+		$(usex qt5 MOC=$(qt5_get_bindir)/moc '') \
+		$(usex qt5 RCC=$(qt5_get_bindir)/rcc '') \
+		$(usex qt5 UIC=$(qt5_get_bindir)/uic '') \
+		$(use_with sbc) \
+		$(use_with smi libsmi) \
+		$(use_with ssl gnutls) \
+		$(use_with zlib) \
+		$(usex netlink --with-libnl=3 --without-libnl) \
+		$(usex cpu_flags_x86_sse4_2 --enable-sse4_2 '') \
+		--disable-profile-build \
+		--disable-usr-local \
+		--disable-warnings-as-errors \
+		--sysconfdir="${EPREFIX}"/etc/wireshark \
+		--without-adns \
+		${myconf[@]}
+}
+
+src_compile() {
+	default
+	if use doc; then
+		use doc-pdf && addpredict "/root/.java"
+		emake -j1 -C docbook
+	fi
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		dohtml -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
+		if use doc-pdf; then
+			insinto /usr/share/doc/${PF}/pdf/
+			doins docbook/{developer,user}-guide-{a4,us}.pdf docbook/release-notes.pdf
+		fi
+	fi
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
+		doc/{randpkt.txt,README*}
+
+	# install headers
+	local wsheader
+	for wsheader in \
+		color.h \
+		config.h \
+		epan/*.h \
+		epan/crypt/*.h \
+		epan/dfilter/*.h \
+		epan/dissectors/*.h \
+		epan/ftypes/*.h \
+		epan/wmem/*.h \
+		register.h \
+		wiretap/*.h \
+		ws_symbol_export.h \
+		wsutil/*.h
+	do
+		insinto /usr/include/wireshark/$( dirname ${wsheader} )
+		doins ${wsheader}
+	done
+
+	#with the above this really shouldn't be needed, but things may be looking in wiretap/ instead of wireshark/wiretap/
+	insinto /usr/include/wiretap
+	doins wiretap/wtap.h
+
+	if use gtk3 || use qt4 || use qt5; then
+		local c d
+		for c in hi lo; do
+			for d in 16 32 48; do
+				insinto /usr/share/icons/${c}color/${d}x${d}/apps
+				newins image/${c}${d}-app-wireshark.png wireshark.png
+			done
+		done
+		for d in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${d}x${d}/mimetypes
+			newins image/WiresharkDoc-${d}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	# Add group for users allowed to sniff.
+	enewgroup wireshark
+
+	if use pcap; then
+		fcaps -o 0 -g wireshark -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the wireshark group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}