[gentoo-commits] repo/gentoo:master commit in: net-libs/rest/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     50b612131a7ff349a7b0487ddd44189d8918a5c2
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  2 12:24:48 2016 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Apr  2 12:28:02 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=50b61213

net-libs/rest: Stop relying on libsoup-gnome

Package-Manager: portage-2.2.28

 net-libs/rest/rest-0.7.93-r1.ebuild | 61 +++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/net-libs/rest/rest-0.7.93-r1.ebuild b/net-libs/rest/rest-0.7.93-r1.ebuild
new file mode 100644
index 0000000..ad507b8
--- /dev/null
+++ b/net-libs/rest/rest-0.7.93-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2 multilib-minimal virtualx
+
+DESCRIPTION="Helper library for RESTful services"
+HOMEPAGE="https://wiki.gnome.org/Projects/Librest"
+
+LICENSE="LGPL-2.1"
+SLOT="0.7"
+IUSE="+introspection test"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Coverage testing should not be enabled
+RDEPEND="
+	app-misc/ca-certificates
+	>=dev-libs/glib-2.24:2[${MULTILIB_USEDEP}]
+	dev-libs/libxml2:2[${MULTILIB_USEDEP}]
+	net-libs/libsoup:2.4[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.6.7:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	test? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
+"
+
+multilib_src_configure() {
+	# gnome support only adds dependency on obsolete libsoup-gnome
+	# https://bugzilla.gnome.org/show_bug.cgi?id=758166
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-static \
+		--disable-gcov \
+		--without-gnome \
+		--with-ca-certificates="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
+		$(multilib_native_use_enable introspection)
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/reference/rest/html docs/reference/rest/html || die
+	fi
+}
+
+multilib_src_test() {
+	# Tests need dbus
+	Xemake check
+}
+
+multilib_src_compile() {
+	gnome2_src_compile
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}