[gentoo-commits] repo/gentoo:master commit in: sys-fs/encfs/

["Anthony G. Basile" <blueness@gentoo.org>]

commit:     42d370f628d41c3297c2efaaae197cef74fe80d8
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 30 00:01:32 2016 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Wed Mar 30 00:03:00 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=42d370f6

sys-fs/encfs: add libressl support

Package-Manager: portage-2.2.26

 sys-fs/encfs/encfs-1.8.1-r1.ebuild | 51 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/sys-fs/encfs/encfs-1.8.1-r1.ebuild b/sys-fs/encfs/encfs-1.8.1-r1.ebuild
new file mode 100644
index 0000000..de939a3
--- /dev/null
+++ b/sys-fs/encfs/encfs-1.8.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+inherit autotools eutils multilib
+
+DESCRIPTION="An implementation of encrypted filesystem in user-space using FUSE"
+HOMEPAGE="https://vgough.github.io/encfs/"
+SRC_URI="https://github.com/vgough/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~sparc ~x86"
+IUSE="xattr nls libressl"
+
+RDEPEND="dev-libs/boost:=
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	dev-libs/rlog
+	sys-fs/fuse
+	sys-libs/zlib"
+# Your libc probably provides xattrs, but to be safe
+# we'll dep on sys-apps/attr.  This should be fixed
+# if we ever create a virtual/attr.
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	virtual/pkgconfig
+	xattr? ( sys-apps/attr )
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	# configure searches for either attr/xattr.h or sys/xattr.h
+	use xattr || export ac_cv_header_{attr,sys}_xattr_h=no
+
+	econf \
+		$(use_enable nls) \
+		--disable-valgrind \
+		--enable-openssl \
+		--disable-dependency-tracking
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog README.md
+	find "${D}" -name '*.la' -delete
+}