[gentoo-commits] repo/gentoo:master commit in: dev-python/os-client-config/

["Matt Thode" <prometheanfire@gentoo.org>]

commit:     291da11caea77e262716676a89e80084c301466e
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 25 23:37:35 2016 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Fri Mar 25 23:39:15 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=291da11c

dev-python/os-client-config: bup for mitaka

Package-Manager: portage-2.2.26

 dev-python/os-client-config/Manifest               |  1 +
 .../os-client-config-1.16.0.ebuild                 | 83 ++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/dev-python/os-client-config/Manifest b/dev-python/os-client-config/Manifest
index b11b002..850b7d7 100644
--- a/dev-python/os-client-config/Manifest
+++ b/dev-python/os-client-config/Manifest
@@ -1,2 +1,3 @@
+DIST os-client-config-1.16.0.tar.gz 53367 SHA256 d25dfb1b74552339442875bedb1e9328de66c5644b8dff0b31cc140f1d6ac9fd SHA512 a10a877dd3bc0245c6bbdaa0cb6daa5a17b519cc4fa73b368626a2e58dd44427309e1d839a3db14128ab4ed4d12fd36aaf366617ded88e14335ced8929c7f527 WHIRLPOOL 58fa3908c9ab756a610e4ce9cd99bf4f0e33602a79a773b71b8c5d5677c251d92b0e13ae33bf5d7ce9c671f672e0edef3d5780d9d806e8c72a2790f369ad5724
 DIST os-client-config-1.6.1.tar.gz 28783 SHA256 24323a33fe4ec4ff0c71a91aa16d26f4c4320f0b0234c5ac22d08f99e2f5c24d SHA512 3f71b17d70f2e7a75e6530203f84a5d32d9bb8c517d1379033ad5fb1d864bcb58c2b026bd2f177fe415b6c03498518bb5abb23df710c66ffd828619aeaf2a4f4 WHIRLPOOL 326c912ae153ad0bcbc7988743be880cb4b7be17762fee8a7ae82946f3502ca9085d0f17726c7d5f7aec4a81968d134674dfc55de3a14d91773279c66db445cb
 DIST os-client-config-1.6.3.tar.gz 25695 SHA256 c7bf7c91bd99e9501a6a2e5415ce4026f0d022d5df9d6123bc935db6108a423f SHA512 411e32c38fec5146eaf01c9fa0f7e1c5ff61c35847604ae2d3a4316a06bfc1b86be83166bf6cd0debef3a352483ee9119471e7a535ff01e264c42f516499b3b4 WHIRLPOOL 5799f8f4ac684e389888c0f5511d5c11ae39dde038d53b74deb29508b0d631cb17e72ea94bf4a343c5f7816aae5f92e19c53d490f46f40c723be69b82d543c65

diff --git a/dev-python/os-client-config/os-client-config-1.16.0.ebuild b/dev-python/os-client-config/os-client-config-1.16.0.ebuild
new file mode 100644
index 0000000..abd4aaa
--- /dev/null
+++ b/dev-python/os-client-config/os-client-config-1.16.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenStack Client Configuation Library"
+HOMEPAGE="http://www.openstack.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND="dev-python/pbr[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		dev-python/extras[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
+		!~dev-python/jsonschema-2.5.0[${PYTHON_USEDEP}]
+		<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		>=dev-python/python-glanceclient-0.18.0[${PYTHON_USEDEP}]
+		>=dev-python/python-keystoneclient-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.5.1[${PYTHON_USEDEP}]
+		<dev-python/oslotest-1.6.0[${PYTHON_USEDEP}]
+		>=dev-python/reno-0.1.1[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-0.9.36[${PYTHON_USEDEP}]
+		!~dev-python/testtools-1.2.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		<dev-python/oslo-sphinx-2.6.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/pyyaml-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.1.1[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	local PATCHES=(
+		"${FILESDIR}"/test_get_all_clouds.patch
+	)
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}