[gentoo-commits] repo/gentoo:master commit in: net-p2p/deluge/

["Patrice Clement" <monsieurp@gentoo.org>]

commit:     ba5a4f913f103e6fd27e49d2f7080258b6b18dbc
Author:     PPed72 <paolo.pedroni <AT> iol <DOT> it>
AuthorDate: Wed Mar  9 10:36:49 2016 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Thu Mar 10 10:18:13 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ba5a4f91

net-p2p/deluge: improved systemd support

The ebuild now creates deluge user and group (fix Gentoo bug #566806)
Give notice to systemd users of change in configuration files.

Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>

 net-p2p/deluge/deluge-1.3.12-r3.ebuild | 97 ++++++++++++++++++++++++++++++++++
 1 file changed, 97 insertions(+)

diff --git a/net-p2p/deluge/deluge-1.3.12-r3.ebuild b/net-p2p/deluge/deluge-1.3.12-r3.ebuild
new file mode 100644
index 0000000..cd671e1
--- /dev/null
+++ b/net-p2p/deluge/deluge-1.3.12-r3.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 eutils systemd user
+
+DESCRIPTION="BitTorrent client with a client/server model"
+HOMEPAGE="http://deluge-torrent.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://deluge-torrent.org/${PN}.git
+		http://git.deluge-torrent.org/${PN}"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="http://download.deluge-torrent.org/source/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="geoip gtk libnotify setproctitle sound webinterface"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND=">=net-libs/rb_libtorrent-0.14.9[python]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-util/intltool"
+RDEPEND=">=net-libs/rb_libtorrent-0.14.9[python]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/pyxdg[${PYTHON_USEDEP}]
+	>=dev-python/twisted-core-8.1[${PYTHON_USEDEP}]
+	>=dev-python/twisted-web-8.1[${PYTHON_USEDEP}]
+	geoip? ( dev-libs/geoip )
+	gtk? (
+		sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
+		dev-python/pygobject:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2.12[${PYTHON_USEDEP}]
+		gnome-base/librsvg
+		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+	)
+	setproctitle? ( dev-python/setproctitle[${PYTHON_USEDEP}] )
+	webinterface? ( dev-python/mako[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}"/${PN}-1.3.5-disable_libtorrent_internal_copy.patch
+	)
+
+	distutils-r1_python_prepare_all
+}
+
+_distutils-r1_create_setup_cfg() {
+	# bug 531370: deluge has its own plugin system. No need to relocate its egg info files.
+	# Override this call from the distutils-r1 eclass.
+	# This does not respect the distutils-r1 API. DONOT copy this example.
+	:
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	newinitd "${FILESDIR}"/deluged.init-2 deluged
+	newconfd "${FILESDIR}"/deluged.conf-2 deluged
+	newinitd "${FILESDIR}"/deluge-web.init deluge-web
+	newconfd "${FILESDIR}"/deluge-web.conf deluge-web
+	systemd_newunit "${FILESDIR}"/deluged.service-2 deluged.service
+	systemd_newunit "${FILESDIR}"/deluge-web.service-2 deluge-web.service
+	systemd_install_serviced "${FILESDIR}"/deluged.service.conf
+	systemd_install_serviced "${FILESDIR}"/deluge-web.service.conf
+}
+
+pkg_postinst() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+	elog
+	elog "If after upgrading it doesn't work, please remove the"
+	elog "'~/.config/deluge' directory and try again, but make a backup"
+	elog "first!"
+	elog
+	elog "To start the daemon either run 'deluged' as user"
+	elog "or modify /etc/conf.d/deluged and run"
+	elog "/etc/init.d/deluged start as root"
+	elog "You can still use deluge the old way"
+	elog
+	elog "Systemd unit files for deluged and deluge-web no longer source"
+	elog "/etc/conf.d/deluge* files. Environment variable customization now"
+	elog "happens in /etc/systemd/system/deluged.service.d/00gentoo.conf"
+	elog "and /etc/systemd/system/deluge-web.service.d/00gentoo.conf"
+	elog
+	elog "For more information look at http://dev.deluge-torrent.org/wiki/Faq"
+	elog
+}