From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-866566-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
by finch.gentoo.org (Postfix) with ESMTP id B4BF31388C1
for <garchives@archives.gentoo.org>; Wed, 2 Mar 2016 08:06:32 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 47611E07FA;
Wed, 2 Mar 2016 08:06:32 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id C6383E07FA
for <gentoo-commits@lists.gentoo.org>; Wed, 2 Mar 2016 08:06:31 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 5785D3408D4
for <gentoo-commits@lists.gentoo.org>; Wed, 2 Mar 2016 08:06:30 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id CB56518A7
for <gentoo-commits@lists.gentoo.org>; Wed, 2 Mar 2016 08:06:27 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1456905983.0a9e92dba02bc31189313dd1c500e7e57f9304fe.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-vcs/mercurial/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-vcs/mercurial/Manifest dev-vcs/mercurial/mercurial-3.7.2.ebuild
X-VCS-Directories: dev-vcs/mercurial/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 0a9e92dba02bc31189313dd1c500e7e57f9304fe
X-VCS-Branch: master
Date: Wed, 2 Mar 2016 08:06:27 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 3bcc7fd0-723a-4ef7-8d56-9f63d9cc3ecc
X-Archives-Hash: 788571d2d35bd16e22a489335f2d62ec
commit: 0a9e92dba02bc31189313dd1c500e7e57f9304fe
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 2 08:05:53 2016 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Mar 2 08:06:23 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0a9e92db
dev-vcs/mercurial: Bump to version 3.7.2
Package-Manager: portage-2.2.27
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
dev-vcs/mercurial/Manifest | 1 +
dev-vcs/mercurial/mercurial-3.7.2.ebuild | 140 +++++++++++++++++++++++++++++++
2 files changed, 141 insertions(+)
diff --git a/dev-vcs/mercurial/Manifest b/dev-vcs/mercurial/Manifest
index 0acabff..8a3d306 100644
--- a/dev-vcs/mercurial/Manifest
+++ b/dev-vcs/mercurial/Manifest
@@ -4,3 +4,4 @@ DIST mercurial-3.4.2.tar.gz 4296407 SHA256 dcc90e4a8476149ecc8af13c08202860b4c9c
DIST mercurial-3.5.2.tar.gz 4415307 SHA256 23fdc038503911b21dc9e556118803f7b1d4150eb14933d2ea3d0ff0dc60ab5d SHA512 d0a4007763186ab72e7ef6e6f6fa84719fcdc2d16208bc99cc32f44cecdc0ccdf5719e18fbc8a5d0735f6441acc0d82bcac05d7c75fee15966c88ee75e7b6bdd WHIRLPOOL 10ec5dd3d1d2e3487f4a290bc0d32fe2237cc450b54774503e7e9e25b12e895c8065f1c2e27dcaa03deac82d1e10e58dd8ea18e9bacf4f24f58a52a3d5c0fea4
DIST mercurial-3.6.3.tar.gz 4521749 SHA256 402731f27256beb9a575a6991ca3d7059976197c905337f4f5729fd940329fa8 SHA512 e5b39e5456a35e19f2ac02838946305023de957590c5aa2828f7c37e9b5f6f2e6376526d0845ebd1ca198860425d11e208b3c36e12e189e0b02871e9c91aad9a WHIRLPOOL 36f0f6caa43ce2c65c7c2bdfb3fa3935cec1e47c25fae6a6a3c7b00165d1aff9b71c73dd10faad2e2ba096d55cc633366170135d95452c162936fef93571dbf1
DIST mercurial-3.7.1.tar.gz 4630846 SHA256 96d37d1f444a032295e190318b3166e9d05abb55916d2b3adb618a8f16c5cfed SHA512 32df161756d7c76abd792bfe5dc3d3f2ea39facdc9c9bd8d93193ecd6cc171f050a4e6dae18255614087ba6fa8f9d787aac41b137c233fa9c3f32217a9cad112 WHIRLPOOL 894a9bd7c61f6a6262ec46f8c80b1894348f765216159458795210fed504a4700e8b4b263e305f3c746d180ef27ab1de11fd4926a2969883d529a613dc93e17a
+DIST mercurial-3.7.2.tar.gz 4634748 SHA256 5ba9438d6ab0db93f7b0786ba632138eb64a9dc0d93e30dde2b17b328fdc6d7a SHA512 573b35052ec50f4672cdd5afd93080edc864deb854b890c8cedba53c40d6d3a37a560e364b94b819cfc6d9fc5c07c0411a13167f0888007e5c9366bc94154306 WHIRLPOOL 782a80d5ee09b6868f9da62ff5e7733e8431323ab7adc8fae52ec0d3e43e88c6ef9cdc90bcb61481e971acf60e43965216f414ed9e88dd9f09546d86561baabc
diff --git a/dev-vcs/mercurial/mercurial-3.7.2.ebuild b/dev-vcs/mercurial/mercurial-3.7.2.ebuild
new file mode 100644
index 0000000..18f93f9
--- /dev/null
+++ b/dev-vcs/mercurial/mercurial-3.7.2.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads"
+
+inherit bash-completion-r1 elisp-common eutils distutils-r1 flag-o-matic
+
+DESCRIPTION="Scalable distributed SCM"
+HOMEPAGE="http://mercurial.selenic.com/"
+SRC_URI="http://mercurial.selenic.com/release/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="bugzilla emacs gpg test tk"
+
+RDEPEND="bugzilla? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+ gpg? ( app-crypt/gnupg )
+ tk? ( dev-lang/tk )
+ app-misc/ca-certificates"
+DEPEND="emacs? ( virtual/emacs )
+ test? ( app-arch/unzip
+ dev-python/pygments[${PYTHON_USEDEP}] )"
+
+SITEFILE="70${PN}-gentoo.el"
+
+PATCHES=( "${FILESDIR}/${PN}-3.0.1-po_fixes.patch" )
+
+python_prepare_all() {
+ # fix up logic that won't work in Gentoo Prefix (also won't outside in
+ # certain cases), bug #362891
+ sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+ strip-flags -ftracer -ftree-vectorize
+ # Note: make it impl-conditional if py3 is supported
+ append-flags -fno-strict-aliasing
+
+ "${PYTHON}" setup.py build_mo || die
+}
+
+python_compile_all() {
+ rm -r contrib/{win32,macosx} || die
+ if use emacs; then
+ cd contrib || die
+ elisp-compile mercurial.el || die "elisp-compile failed!"
+ fi
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ newbashcomp contrib/bash_completion hg
+
+ insinto /usr/share/zsh/site-functions
+ newins contrib/zsh_completion _hg
+
+ rm -f doc/*.?.txt
+ dodoc CONTRIBUTORS
+ cp hgweb*.cgi "${ED}"/usr/share/doc/${PF}/ || die
+
+ dobin hgeditor
+ dobin contrib/hgk
+ python_foreach_impl python_doscript contrib/hg-ssh
+
+ if use emacs; then
+ elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
+ elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+ fi
+
+ local RM_CONTRIB=(hgk hg-ssh bash_completion zsh_completion wix buildrpm plan9
+ *.el mercurial.spec)
+ for f in ${RM_CONTRIB[@]}; do
+ rm -r contrib/$f || die
+ done
+
+ dodoc -r contrib
+ docompress -x /usr/share/doc/${PF}/contrib
+ doman doc/*.?
+
+ cat > "${T}/80mercurial" <<-EOF
+HG="${EPREFIX}/usr/bin/hg"
+EOF
+ doenvd "${T}/80mercurial"
+
+ insinto /etc/mercurial/hgrc.d
+ doins "${FILESDIR}/cacerts.rc"
+}
+
+src_test() {
+ pushd tests &>/dev/null || die
+ rm -rf *svn* # Subversion tests fail with 1.5
+ rm -f test-archive* # Fails due to verbose tar output changes
+ rm -f test-convert-baz* # GNU Arch baz
+ rm -f test-convert-cvs* # CVS
+ rm -f test-convert-darcs* # Darcs
+ rm -f test-convert-git* # git
+ rm -f test-convert-mtn* # monotone
+ rm -f test-convert-tla* # GNU Arch tla
+ #rm -f test-doctest* # doctest always fails with python 2.5.x
+ rm -f test-largefiles* # tends to time out
+
+ popd &>/dev/null || die
+ distutils-r1_src_test
+}
+
+python_test() {
+ local TEST_DIR
+
+ rm -rf "${TMPDIR}"/test
+ distutils_install_for_testing
+ cd tests || die
+ "${PYTHON}" run-tests.py --verbose \
+ --tmpdir="${TMPDIR}"/test \
+ --with-hg="${TEST_DIR}"/scripts/hg \
+ || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ elog "If you want to convert repositories from other tools using convert"
+ elog "extension please install correct tool:"
+ elog " dev-vcs/cvs"
+ elog " dev-vcs/darcs"
+ elog " dev-vcs/git"
+ elog " dev-vcs/monotone"
+ elog " dev-vcs/subversion"
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}