[gentoo-commits] repo/gentoo:master commit in: x11-wm/xpra/

["Michael Weber" <xmw@gentoo.org>]

commit:     41242054998465c31e550afb229ebdc6f785b467
Author:     Michael Weber <xmw <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 22 11:41:40 2016 +0000
Commit:     Michael Weber <xmw <AT> gentoo <DOT> org>
CommitDate: Mon Feb 22 11:41:40 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=41242054

x11-wm/xpra: RDEPEND on dev-python/pyopengl_accelerate (bug 572122), dev-python/pycups (bug 571978), dev-python/lz4 and dev-python/python-lzo (bug 571976). Thanks to thanks Fabian Henze for the reports.

Package-Manager: portage-2.2.27

 x11-wm/xpra/metadata.xml           |   9 +--
 x11-wm/xpra/xpra-0.15.10-r1.ebuild | 121 +++++++++++++++++++++++++++++++++++++
 2 files changed, 126 insertions(+), 4 deletions(-)

diff --git a/x11-wm/xpra/metadata.xml b/x11-wm/xpra/metadata.xml
index bc86193..60f9071 100644
--- a/x11-wm/xpra/metadata.xml
+++ b/x11-wm/xpra/metadata.xml
@@ -10,14 +10,15 @@
 </upstream>
 <use>
 	<flag name="client">Build client-side code</flag>
-	<flag name="server">Build server-side code</flag>
 	<flag name="clipboard">Enable clipboard support</flag>
-	<flag name="rencode">Enable rencode support</flag>
-	<flag name="vpx">Enable vpx image format support</flag>
-	<flag name="webp">Enable webp image format support</flag>
 	<flag name="csc">Enable csc softscaler support</flag>
 	<flag name="dec_av">Enable dec_avcodec support</flag>
 	<flag name="dec_av2">Enable dec_avcodec2 support</flag>
+	<flag name="lz4">Enable support for lz4 compression</flag>
+	<flag name="rencode">Enable rencode support</flag>
+	<flag name="server">Build server-side code</flag>
+	<flag name="vpx">Enable vpx image format support</flag>
+	<flag name="webp">Enable webp image format support</flag>
 	<flag name="x265">Enable x265 support</flag>
 </use>
 </pkgmetadata>

diff --git a/x11-wm/xpra/xpra-0.15.10-r1.ebuild b/x11-wm/xpra/xpra-0.15.10-r1.ebuild
new file mode 100644
index 0000000..19dfed8
--- /dev/null
+++ b/x11-wm/xpra/xpra-0.15.10-r1.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+EAPI=5
+
+# PyCObject_Check and PyCObject_AsVoidPtr vanished with python 3.3, and setup.py not python3.2 copmat
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1 eutils
+
+DESCRIPTION="X Persistent Remote Apps (xpra) and Partitioning WM (parti) based on wimpiggy"
+HOMEPAGE="http://xpra.org/ http://xpra.org/src/"
+SRC_URI="http://xpra.org/src/${P}.tar.xz"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+client +clipboard csc cups dec_av2 libav lz4 lzo opengl pulseaudio server sound vpx webp x264 x265"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	clipboard? ( || ( server client ) )
+	opengl? ( client )
+	|| ( client server )"
+
+# x264/old-libav.path situation see bug 459218
+COMMON_DEPEND=""${PYTHON_DEPS}"
+	dev-python/pygobject:2[${PYTHON_USEDEP}]
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	csc? (
+		!libav? ( >=media-video/ffmpeg-1.2.2:0= )
+		libav? ( media-video/libav:0= )
+	)
+	dec_av2? (
+		!libav? ( >=media-video/ffmpeg-2:0= )
+		libav? ( media-video/libav:0= )
+	)
+	opengl? ( dev-python/pygtkglext )
+	pulseaudio? ( media-sound/pulseaudio )
+	sound? ( media-libs/gstreamer:0.10
+		media-libs/gst-plugins-base:0.10
+		dev-python/gst-python:0.10 )
+	vpx? ( media-libs/libvpx virtual/ffmpeg )
+	webp? ( media-libs/libwebp )
+	x264? ( media-libs/x264
+		!libav? ( >=media-video/ffmpeg-1.0.4:0= )
+		libav? ( media-video/libav:0= )
+	)
+	x265? ( media-libs/x265
+		!libav? ( >=media-video/ffmpeg-2:0= )
+		libav? ( media-video/libav:0= )
+	)"
+
+RDEPEND="${COMMON_DEPEND}
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/rencode[${PYTHON_USEDEP}]
+	virtual/ssh
+	x11-apps/setxkbmap
+	x11-apps/xmodmap
+	cups? ( dev-python/pycups[${PYTHON_USEDEP}] )
+	lz4? ( dev-python/lz4[${PYTHON_USEDEP}] )
+	lzo? ( dev-python/python-lzo[${PYTHON_USEDEP}] )
+	opengl? (
+		client? ( dev-python/pyopengl_accelerate[${PYTHON_USEDEP}] )
+	)
+	server? ( x11-base/xorg-server[-minimal,xvfb]
+		x11-drivers/xf86-input-void
+		x11-drivers/xf86-video-dummy
+	)"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	>=dev-python/cython-0.16[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	rm -rf rencode || die
+
+	epatch \
+		"${FILESDIR}"/${PN}-0.13.1-ignore-gentoo-no-compile.patch \
+		"${FILESDIR}"/${PN}-0.15.0-prefix.patch
+
+	if use libav ; then
+		if ! has_version ">=media-video/libav-9" ; then
+			epatch patches/old-libav.patch
+		fi
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	mydistutilsargs=(
+		$(use_with client)
+		$(use_with clipboard)
+		$(use_with csc csc_swscale)
+		$(use_with cups printing)
+		$(use_with dec_av2 dec_avcodec2)
+		$(use_with opengl)
+		$(use_with server shadow)
+		$(use_with server)
+		$(use_with sound)
+		$(use_with vpx)
+		$(use_with webp)
+		$(use_with x264 enc_x264)
+		$(use_with x265 enc_x265)
+		--with-Xdummy
+		--with-gtk2
+		--without-gtk3
+		--with-strict
+		--with-warn
+		--with-x11
+		--without-PIC
+		--without-debug )
+}