[gentoo-commits] repo/gentoo:master commit in: www-apps/nanoc/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     639223b33f6b1dca71db8b32b5f2864d75c24d13
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 19 08:09:59 2016 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Fri Feb 19 08:11:11 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=639223b3

www-apps/nanoc: add adsf dependency

Add a dependency on www-servers/adsf to allow the
"nanoc view" command to work as intended.

Thanks for Nick Bowler in bug 572938 for the suggestion.

Package-Manager: portage-2.2.26

 www-apps/nanoc/nanoc-4.1.4-r1.ebuild | 67 ++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/www-apps/nanoc/nanoc-4.1.4-r1.ebuild b/www-apps/nanoc/nanoc-4.1.4-r1.ebuild
new file mode 100644
index 0000000..d1af396
--- /dev/null
+++ b/www-apps/nanoc/nanoc-4.1.4-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby21"
+
+RUBY_FAKEGEM_EXTRADOC="ChangeLog NEWS.md README.md"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_TASK_TEST="test:all"
+
+inherit ruby-fakegem
+
+DESCRIPTION="nanoc is a simple but very flexible static site generator written in Ruby"
+HOMEPAGE="http://nanoc.ws/"
+LICENSE="MIT"
+
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="${IUSE} minimal"
+
+DEPEND+="test? ( app-text/asciidoc app-text/highlight )"
+
+ruby_add_rdepend "!minimal? (
+	dev-ruby/mime-types:*
+	dev-ruby/rack:*
+	www-servers/adsf
+)
+	>=dev-ruby/cri-2.3:0"
+
+ruby_add_bdepend "test? (
+	>=dev-ruby/mocha-0.13
+	dev-ruby/minitest
+	=dev-ruby/rdoc-4*
+	dev-ruby/systemu
+	dev-ruby/vcr
+	dev-ruby/webmock
+	dev-ruby/yard
+)
+doc? (
+	dev-ruby/kramdown
+	dev-ruby/rdiscount
+	dev-ruby/yard
+)"
+
+all_ruby_prepare() {
+	use doc || use test || (rm tasks/doc.rake || die)
+
+	if use test ; then
+		# Avoid dependency on coveralls.
+		sed -i -e '/coverall/I s:^:#:' tasks/test.rake || die
+	else
+		rm -f tasks/test.rake || die
+	fi
+
+	# Avoid non-optional tests for w3c_validators which we don't have
+	# packaged and which require network access.
+	rm test/extra/checking/checks/test_{css,html}.rb || die
+
+	# Skip a test that produces slightly different javascript.
+	sed -i -e '/test_filter_with_options/,/^  end/ s:^:#:' test/filters/test_uglify_js.rb || die
+}
+
+each_ruby_test() {
+	RUBYLIB="${S}/lib" ${RUBY} -S rake test:all || die
+}