From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-863998-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
by finch.gentoo.org (Postfix) with ESMTP id CE1101388BF
for <garchives@archives.gentoo.org>; Thu, 18 Feb 2016 09:38:54 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id A0D09E0835;
Thu, 18 Feb 2016 09:38:52 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 333F8E0835
for <gentoo-commits@lists.gentoo.org>; Thu, 18 Feb 2016 09:38:52 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id E7B59340CF2
for <gentoo-commits@lists.gentoo.org>; Thu, 18 Feb 2016 09:38:50 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id E2AAA1068
for <gentoo-commits@lists.gentoo.org>; Thu, 18 Feb 2016 09:38:48 +0000 (UTC)
From: "Patrick Lauer" <patrick@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Patrick Lauer" <patrick@gentoo.org>
Message-ID: <1455788275.378ace369f0f33aedad3550205c90e91c5cf0766.patrick@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: www-servers/lighttpd/
X-VCS-Repository: repo/gentoo
X-VCS-Files: www-servers/lighttpd/Manifest www-servers/lighttpd/lighttpd-1.4.39.ebuild
X-VCS-Directories: www-servers/lighttpd/
X-VCS-Committer: patrick
X-VCS-Committer-Name: Patrick Lauer
X-VCS-Revision: 378ace369f0f33aedad3550205c90e91c5cf0766
X-VCS-Branch: master
Date: Thu, 18 Feb 2016 09:38:48 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 178c8423-e633-45ca-a959-8ddb50cc6188
X-Archives-Hash: ce1fbcee1658f73c0ec9861facda2045
commit: 378ace369f0f33aedad3550205c90e91c5cf0766
Author: Patrick Lauer <patrick <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 18 09:37:40 2016 +0000
Commit: Patrick Lauer <patrick <AT> gentoo <DOT> org>
CommitDate: Thu Feb 18 09:37:55 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=378ace36
www-servers/lighttpd: Bump
Package-Manager: portage-2.2.27
www-servers/lighttpd/Manifest | 1 +
www-servers/lighttpd/lighttpd-1.4.39.ebuild | 217 ++++++++++++++++++++++++++++
2 files changed, 218 insertions(+)
diff --git a/www-servers/lighttpd/Manifest b/www-servers/lighttpd/Manifest
index 1541bd9..84fb7b7 100644
--- a/www-servers/lighttpd/Manifest
+++ b/www-servers/lighttpd/Manifest
@@ -1,2 +1,3 @@
DIST lighttpd-1.4.35.tar.bz2 665955 SHA256 4a71c1f6d8af41ed894b507720c4c17184dc320590013881d5170ca7f15c5bf7 SHA512 13f8562fb735964fe7ef1b127a15c43907f34be70b6bd2dd4ba61b59275d7c2a8d9a7947ff1a4d7cc5fd7efd309fc66b7de6d954b59424f814ea2eb98fd876b9 WHIRLPOOL edbeb94ae29475be398e9281135fc43f915be68c5836ae3da302f7c94c3af19eeca601cedc9bfe59d552f45c6248a945b2de725613de395087e4e195efe9a62e
DIST lighttpd-1.4.37.tar.xz 574020 SHA256 804e6f60567ca1da2b3927f92b7e9332b93aca9560f282ca135b86b7558979bd SHA512 60870149c78a44ae1cf29bd2ba8737ba18019178f9fd3868523255121d85cdc923c2315b572a2a0fcecc3d6451a501ad030189b78bfc7f25807a05b0300063b3 WHIRLPOOL 08c3d79fa5a65eea999d257a9c8e10ed75d0043a00160f6b69c868c6ef4c1fbf81cf90dd037506e24ecbfd4a9cba15801b4bb0f16af0a400afa885f863ec64ae
+DIST lighttpd-1.4.39.tar.xz 579180 SHA256 7eb9a1853c3d6dd5851682b0733a729ba4158d6bdff80974d5ef5f1f6887365b SHA512 69bf56afe2bec381566defdc20961554e405e5e7f77b0067e1a29a04e65167b9283cf08655b8dae1c2b6fdddde31245253b5506a532a83f363dce066811b61b3 WHIRLPOOL 5f0fe57afd11a555d5aac76c6abb8b78e34d7f56b0b2921a318297efde420b4762048045274a51e4e030279cbd6d14ee0a344d2c91c18755a0a9d5f83f4bafb8
diff --git a/www-servers/lighttpd/lighttpd-1.4.39.ebuild b/www-servers/lighttpd/lighttpd-1.4.39.ebuild
new file mode 100644
index 0000000..2c3832e
--- /dev/null
+++ b/www-servers/lighttpd/lighttpd-1.4.39.ebuild
@@ -0,0 +1,217 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+inherit base autotools eutils readme.gentoo user systemd
+
+DESCRIPTION="Lightweight high-performance web server"
+HOMEPAGE="http://www.lighttpd.net/"
+SRC_URI="http://download.lighttpd.net/lighttpd/releases-1.4.x/${P}.tar.xz"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="bzip2 doc fam gdbm ipv6 kerberos ldap libev libressl lua minimal mmap memcache mysql pcre php rrdtool selinux ssl test webdav xattr zlib"
+
+REQUIRED_USE="kerberos? ( ssl !libressl )"
+
+CDEPEND="
+ bzip2? ( app-arch/bzip2 )
+ fam? ( virtual/fam )
+ gdbm? ( sys-libs/gdbm )
+ ldap? ( >=net-nds/openldap-2.1.26 )
+ libev? ( >=dev-libs/libev-4.01 )
+ lua? ( >=dev-lang/lua-5.1:= )
+ memcache? ( dev-libs/libmemcache )
+ mysql? ( >=virtual/mysql-4.0 )
+ pcre? ( >=dev-libs/libpcre-3.1 )
+ php? ( dev-lang/php:*[cgi] )
+ rrdtool? ( net-analyzer/rrdtool )
+ ssl? (
+ !libressl? ( >=dev-libs/openssl-0.9.7:0=[kerberos?] )
+ libressl? ( dev-libs/libressl:= )
+ )
+ webdav? (
+ dev-libs/libxml2
+ >=dev-db/sqlite-3
+ sys-fs/e2fsprogs
+ )
+ xattr? ( kernel_linux? ( sys-apps/attr ) )
+ zlib? ( >=sys-libs/zlib-1.1 )"
+
+DEPEND="${CDEPEND}
+ virtual/pkgconfig
+ doc? ( dev-python/docutils )
+ test? (
+ virtual/perl-Test-Harness
+ dev-libs/fcgi
+ )"
+
+RDEPEND="${CDEPEND}
+ selinux? ( sec-policy/selinux-apache )
+"
+
+# update certain parts of lighttpd.conf based on conditionals
+update_config() {
+ local config="${D}/etc/lighttpd/lighttpd.conf"
+
+ # enable php/mod_fastcgi settings
+ use php && { sed -i -e 's|#.*\(include.*fastcgi.*$\)|\1|' ${config} || die; }
+
+ # enable stat() caching
+ use fam && { sed -i -e 's|#\(.*stat-cache.*$\)|\1|' ${config} || die; }
+
+ # automatically listen on IPv6 if built with USE=ipv6. Bug #234987
+ use ipv6 && { sed -i -e 's|# server.use-ipv6|server.use-ipv6|' ${config} || die; }
+}
+
+# remove non-essential stuff (for USE=minimal)
+remove_non_essential() {
+ local libdir="${D}/usr/$(get_libdir)/${PN}"
+
+ # text docs
+ use doc || rm -fr "${D}"/usr/share/doc/${PF}/txt
+
+ # non-essential modules
+ rm -f \
+ ${libdir}/mod_{compress,evhost,expire,proxy,scgi,secdownload,simple_vhost,status,setenv,trigger*,usertrack}.*
+
+ # allow users to keep some based on USE flags
+ use pcre || rm -f ${libdir}/mod_{ssi,re{direct,write}}.*
+ use webdav || rm -f ${libdir}/mod_webdav.*
+ use mysql || rm -f ${libdir}/mod_mysql_vhost.*
+ use lua || rm -f ${libdir}/mod_{cml,magnet}.*
+ use rrdtool || rm -f ${libdir}/mod_rrdtool.*
+ use zlib || rm -f ${libdir}/mod_compress.*
+}
+
+pkg_setup() {
+ if ! use pcre ; then
+ ewarn "It is highly recommended that you build ${PN}"
+ ewarn "with perl regular expressions support via USE=pcre."
+ ewarn "Otherwise you lose support for some core options such"
+ ewarn "as conditionals and modules such as mod_re{write,direct}"
+ ewarn "and mod_ssi."
+ fi
+ if use mmap; then
+ ewarn "You have enabled the mmap option. This option may allow"
+ ewarn "local users to trigger SIGBUG crashes. Use this option"
+ ewarn "with EXTRA care."
+ fi
+ enewgroup lighttpd
+ enewuser lighttpd -1 -1 /var/www/localhost/htdocs lighttpd
+
+ DOC_CONTENTS="IPv6 migration guide:\n
+ http://redmine.lighttpd.net/projects/lighttpd/wiki/IPv6-Config"
+}
+
+src_prepare() {
+ base_src_prepare
+ #dev-python/docutils installs rst2html.py not rst2html
+ sed -i -e 's|\(rst2html\)|\1.py|g' doc/outdated/Makefile.am || \
+ die "sed doc/Makefile.am failed"
+ eautoreconf
+}
+
+src_configure() {
+ econf --libdir=/usr/$(get_libdir)/${PN} \
+ --enable-lfs \
+ $(use_enable ipv6) \
+ $(use_enable mmap) \
+ $(use_with bzip2) \
+ $(use_with fam) \
+ $(use_with gdbm) \
+ $(use_with kerberos kerberos5) \
+ $(use_with ldap) \
+ $(use_with libev) \
+ $(use_with lua) \
+ $(use_with memcache) \
+ $(use_with mysql) \
+ $(use_with pcre) \
+ $(use_with ssl openssl) \
+ $(use_with webdav webdav-props) \
+ $(use_with webdav webdav-locks) \
+ $(use_with xattr attr) \
+ $(use_with zlib)
+}
+
+src_compile() {
+ emake
+
+ if use doc ; then
+ einfo "Building HTML documentation"
+ cd doc || die
+ emake html
+ fi
+}
+
+src_test() {
+ if [[ ${EUID} -eq 0 ]]; then
+ default_src_test
+ else
+ ewarn "test skipped, please re-run as root if you wish to test ${PN}"
+ fi
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+
+ # init script stuff
+ newinitd "${FILESDIR}"/lighttpd.initd lighttpd
+ newconfd "${FILESDIR}"/lighttpd.confd lighttpd
+ use fam && has_version app-admin/fam && \
+ { sed -i 's/after famd/need famd/g' "${D}"/etc/init.d/lighttpd || die; }
+
+ # configs
+ insinto /etc/lighttpd
+ doins "${FILESDIR}"/conf/lighttpd.conf
+ doins "${FILESDIR}"/conf/mime-types.conf
+ doins "${FILESDIR}"/conf/mod_cgi.conf
+ doins "${FILESDIR}"/conf/mod_fastcgi.conf
+
+ # update lighttpd.conf directives based on conditionals
+ update_config
+
+ # docs
+ dodoc AUTHORS README NEWS doc/scripts/*.sh
+ newdoc doc/config//lighttpd.conf lighttpd.conf.distrib
+ use ipv6 && readme.gentoo_create_doc
+
+ use doc && dohtml -r doc/*
+
+ docinto txt
+ dodoc doc/outdated/*.txt
+
+ # logrotate
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}"/lighttpd.logrotate-r1 lighttpd
+
+ keepdir /var/l{ib,og}/lighttpd /var/www/localhost/htdocs
+ fowners lighttpd:lighttpd /var/l{ib,og}/lighttpd
+ fperms 0750 /var/l{ib,og}/lighttpd
+
+ #spawn-fcgi may optionally be installed via www-servers/spawn-fcgi
+ rm -f "${D}"/usr/bin/spawn-fcgi "${D}"/usr/share/man/man1/spawn-fcgi.*
+
+ use minimal && remove_non_essential
+
+ systemd_dounit "${FILESDIR}/${PN}.service"
+ systemd_dotmpfilesd "${FILESDIR}/${PN}.tmpfiles.conf"
+}
+
+pkg_postinst () {
+ use ipv6 && readme.gentoo_print_elog
+
+ if [[ -f ${ROOT}etc/conf.d/spawn-fcgi.conf ]] ; then
+ einfo "spawn-fcgi is now provided by www-servers/spawn-fcgi."
+ einfo "spawn-fcgi's init script configuration is now located"
+ einfo "at /etc/conf.d/spawn-fcgi."
+ fi
+
+ if [[ -f ${ROOT}etc/lighttpd.conf ]] ; then
+ elog "Gentoo has a customized configuration,"
+ elog "which is now located in /etc/lighttpd. Please migrate your"
+ elog "existing configuration."
+ fi
+}