[gentoo-commits] repo/gentoo:master commit in: dev-java/oracle-jre-bin/

["James Le Cuirot" <chewi@gentoo.org>]

commit:     1d508f6f8e641676594cd755f82780652aacfaf6
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  9 22:11:26 2016 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Tue Feb  9 22:19:07 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1d508f6f

dev-java/oracle-jre-bin: Version bump wrt bug #574290

Unlike usual, this is not being raised as a Gentoo security issue as
the reported vulnerability only affects Windows.

Package-Manager: portage-2.2.27

 dev-java/oracle-jre-bin/Manifest                   |   2 +
 .../oracle-jre-bin/oracle-jre-bin-1.8.0.74.ebuild  | 240 +++++++++++++++++++++
 2 files changed, 242 insertions(+)

diff --git a/dev-java/oracle-jre-bin/Manifest b/dev-java/oracle-jre-bin/Manifest
index d2e80a4..f423472 100644
--- a/dev-java/oracle-jre-bin/Manifest
+++ b/dev-java/oracle-jre-bin/Manifest
@@ -4,3 +4,5 @@ DIST jre-7u80-linux-i586.tar.gz 48558751 SHA256 b773aef1458a4adde03af62f8163c7e4
 DIST jre-7u80-linux-x64.tar.gz 47110223 SHA256 4c01efd0d8e80bb6e2f324ec3408ce64f066d4506c7ec93a491f615a4523f4f3 SHA512 e61e78ab1be0313690e8ab8d6cbae7366dd78aa4716f47c8908178196b658b94ee318dd04043965a72c34d8ef5c1cb4902afaa2188e76eb944256f090339107d WHIRLPOOL 1af7417b327402abaf4074445f051924de8b19810668890e089b66a488dddfc7f50cdd96a012130a591940338177164f66c83caf54c5d6d370be27d119a907fe
 DIST jre-8u72-linux-i586.tar.gz 73963723 SHA256 f7cd307bacaf9714858cbbb3cdbbd9e73b6168d4bf59c6f46dc4ba052e647f94 SHA512 c8735e7e6f238748e63e3b641d5b2e7a48d5756fc5d13769a2592b7532aa2b5e65ccf899657767893ca734b9459819907ee3646e02f0295bc767e16e4f74affd WHIRLPOOL 5af965e0d37f3d1ff57d3ed6731716835114e9680e482a26ee5ff371d557aa773a78dee57630b4ee653ca443ef3ebf80d9d3e6805fd8d84604dd352f53dedb15
 DIST jre-8u72-linux-x64.tar.gz 71780497 SHA256 0e287ce637d6115613e53d651313271e75f02299881cc04f444521db1ed11c85 SHA512 85123b9719afe011d518c5bc0d27a5fcc919b1900ab05d9489fc8f69751ac0abea8aa72b8cd0e3194b8a1443a952c5a576d3959d63c06ab4257fc1a9ac5ca288 WHIRLPOOL 1b459ef6ec3d6d78a75b638bb61fb309f4de63ef028b0c4d50bcb1c38e379cb4a5ffa12ce4def10b510161406e83aec334d03ccb503db891aced1880f4c23e4f
+DIST jre-8u74-linux-i586.tar.gz 73961061 SHA256 215f2f7cac2dfa2ff4eb019f5d649a7c9a8ff0fcecfe11d739fac810aacd323a SHA512 663a2edc1e28a26531a6dcd96f471dfbd18fcc3fc9188300642d6cf798b65432d4496470648a9387d5d1dffc1e658dc554df56b6bdff76019eb122ae20074fa3 WHIRLPOOL 0df44c3853c71f99cafc69e06124ab3f2d74b1d8835a497ec44ce906a1c0065264d852e17a82d634b742ec793f93716dce95068f1f6ee280df967f7b48fac12a
+DIST jre-8u74-linux-x64.tar.gz 71774923 SHA256 9c8663a5a67429d423ed1da554a7f93d1c7e50f6bb4bc5e0bbde1f512cf36d95 SHA512 a63695d4296f417d454f44b4e33b591f4de687789fd533b312edc838786ce76ab9b360cd9206e1bf20eff91eb74b7da29baddbdf626527d93754ab42f1a998c5 WHIRLPOOL cd0d47ddfb44749835974976d82083ef43956938c6aab280e74f9ab5171314827fe0f9f0c791633d964900eb9b3240363869213233b73f58eb7ade12399ebb0b

diff --git a/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.74.ebuild b/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.74.ebuild
new file mode 100644
index 0000000..c863fcb
--- /dev/null
+++ b/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.74.ebuild
@@ -0,0 +1,240 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils java-vm-2 prefix versionator
+
+# This URIs need updating when bumping!
+JRE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jre8-downloads-2133155.html"
+JCE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jce8-download-2133166.html"
+
+if [[ "$(get_version_component_range 4)" == 0 ]] ; then
+	S_PV="$(get_version_component_range 1-3)"
+else
+	MY_PV_EXT="u$(get_version_component_range 4)"
+	S_PV="$(get_version_component_range 1-4)"
+fi
+
+MY_PV="$(get_version_component_range 2)${MY_PV_EXT}"
+
+AT_amd64="jre-${MY_PV}-linux-x64.tar.gz"
+AT_x86="jre-${MY_PV}-linux-i586.tar.gz"
+
+JCE_DIR="UnlimitedJCEPolicyJDK8"
+JCE_FILE="jce_policy-8.zip"
+
+DESCRIPTION="Oracle's Java SE Runtime Environment"
+HOMEPAGE="http://www.oracle.com/technetwork/java/javase/"
+SRC_URI="
+	amd64? ( ${AT_amd64} )
+	x86? ( ${AT_x86} )
+	jce? ( ${JCE_FILE} )"
+
+LICENSE="Oracle-BCLA-JavaSE"
+SLOT="1.8"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa cups +fontconfig headless-awt javafx jce nsplugin pax_kernel selinux"
+
+RESTRICT="fetch preserve-libs strip"
+QA_PREBUILT="*"
+
+# NOTES:
+#
+# * cups is dlopened.
+#
+# * libpng is also dlopened but only by libsplashscreen, which isn't
+#   important, so we can exclude that.
+#
+# * We still need to work out the exact AWT and JavaFX dependencies
+#   under MacOS. It doesn't appear to use many, if any, of the
+#   dependencies below.
+#
+RDEPEND="!x64-macos? (
+		!headless-awt? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			x11-libs/libXtst
+		)
+		javafx? (
+			dev-libs/glib:2
+			dev-libs/libxml2:2
+			dev-libs/libxslt
+			media-libs/freetype:2
+			x11-libs/cairo
+			x11-libs/gtk+:2
+			x11-libs/libX11
+			x11-libs/libXtst
+			x11-libs/libXxf86vm
+			x11-libs/pango
+			virtual/opengl
+		)
+	)
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	fontconfig? ( media-libs/fontconfig:1.0 )
+	!prefix? ( sys-libs/glibc:* )
+	selinux? ( sec-policy/selinux-java )"
+
+# A PaX header isn't created by scanelf so depend on paxctl to avoid
+# fallback marking. See bug #427642.
+DEPEND="app-arch/zip
+	jce? ( app-arch/unzip )
+	pax_kernel? ( sys-apps/paxctl )"
+
+S="${WORKDIR}/jre"
+
+pkg_nofetch() {
+	local AT_ARCH="AT_${ARCH}"
+	local AT="${!AT_ARCH}"
+
+	einfo "Please download '${AT}' from:"
+	einfo "'${JRE_URI}'"
+	einfo "and move it to '${DISTDIR}'"
+
+	if use jce; then
+		einfo "Also download '${JCE_FILE}' from:"
+		einfo "'${JCE_URI}'"
+		einfo "and move it to '${DISTDIR}'"
+	fi
+
+	einfo
+	einfo "If the above mentioned urls do not point to the correct version anymore,"
+	einfo "please download the files from Oracle's java download archive:"
+	einfo
+	einfo "   http://www.oracle.com/technetwork/java/javase/downloads/java-archive-javase8-2177648.html#jre-${MY_PV}-oth-JPR"
+	einfo
+
+}
+
+src_unpack() {
+	default
+
+	# Upstream is changing their versioning scheme every release around 1.8.0.*;
+	# to stop having to change it over and over again, just wildcard match and
+	# live a happy life instead of trying to get this new jre1.8.0_05 to work.
+	mv "${WORKDIR}"/jre* "${S}" || die
+}
+
+src_prepare() {
+	if use jce ; then
+		mv "${WORKDIR}"/${JCE_DIR} lib/security/ || die
+	fi
+
+	# Remove the hook that calls Oracle's evil usage tracker. Not just
+	# because it's evil but because it breaks the sandbox during builds
+	# and we can't find any other feasible way to disable it or make it
+	# write somewhere else. See bug #559936 for details.
+	zip -d lib/rt.jar sun/misc/PostVMInitHook.class || die
+}
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}${dest#/}"
+
+	# Create files used as storage for system preferences.
+	mkdir .systemPrefs || die
+	touch .systemPrefs/.system.lock || die
+	touch .systemPrefs/.systemRootModFile || die
+
+	if ! use alsa ; then
+		rm -vf lib/*/libjsoundalsa.* || die
+	fi
+
+	if use headless-awt ; then
+		rm -vf lib/*/lib*{[jx]awt,splashscreen}* \
+		   bin/{javaws,policytool} || die
+	fi
+
+	if ! use javafx ; then
+		rm -vf lib/*/lib*{decora,fx,glass,prism}* \
+		   lib/*/libgstreamer-lite.* lib/{,ext/}*fx* || die
+	fi
+
+	if ! use nsplugin ; then
+		rm -vf lib/*/libnpjp2.* || die
+	else
+		local nsplugin=$(echo lib/*/libnpjp2.*)
+	fi
+
+	# Even though plugins linked against multiple ffmpeg versions are
+	# provided, they generally lag behind what Gentoo has available.
+	rm -vf lib/*/libavplugin* || die
+
+	dodoc COPYRIGHT
+	dodir "${dest}"
+	cp -pPR	bin lib man "${ddest}" || die
+
+	if use jce ; then
+		dodir ${dest}/lib/security/strong-jce
+		mv "${ddest}"/lib/security/US_export_policy.jar \
+			"${ddest}"/lib/security/strong-jce || die
+		mv "${ddest}"/lib/security/local_policy.jar \
+			"${ddest}"/lib/security/strong-jce || die
+		dosym "${dest}"/lib/security/${JCE_DIR}/US_export_policy.jar \
+			"${dest}"/lib/security/US_export_policy.jar
+		dosym "${dest}"/lib/security/${JCE_DIR}/local_policy.jar \
+			"${dest}"/lib/security/local_policy.jar
+	fi
+
+	if use nsplugin ; then
+		local nsplugin_link=${nsplugin##*/}
+		nsplugin_link=${nsplugin_link/./-${PN}-${SLOT}.}
+		dosym "${dest}/${nsplugin}" "/usr/$(get_libdir)/nsbrowser/plugins/${nsplugin_link}"
+	fi
+
+	# Install desktop file for the Java Control Panel.
+	# Using ${PN}-${SLOT} to prevent file collision with jre and or other slots.
+	# make_desktop_entry can't be used as ${P} would end up in filename.
+	newicon lib/desktop/icons/hicolor/48x48/apps/sun-jcontrol.png \
+		sun-jcontrol-${PN}-${SLOT}.png || die
+	sed -e "s#Name=.*#Name=Java Control Panel for Oracle JRE ${SLOT}#" \
+		-e "s#Exec=.*#Exec=/opt/${P}/bin/jcontrol#" \
+		-e "s#Icon=.*#Icon=sun-jcontrol-${PN}-${SLOT}#" \
+		-e "s#Application;##" \
+		-e "/Encoding/d" \
+		lib/desktop/applications/sun_java.desktop > \
+		"${T}"/jcontrol-${PN}-${SLOT}.desktop || die
+	domenu "${T}"/jcontrol-${PN}-${SLOT}.desktop
+
+	# Prune all fontconfig files so libfontconfig will be used and only install
+	# a Gentoo specific one if fontconfig is disabled.
+	# http://docs.oracle.com/javase/8/docs/technotes/guides/intl/fontconfig.html
+	rm "${ddest}"/lib/fontconfig.* || die
+	if ! use fontconfig ; then
+		cp "${FILESDIR}"/fontconfig.Gentoo.properties "${T}"/fontconfig.properties || die
+		eprefixify "${T}"/fontconfig.properties
+		insinto "${dest}"/lib/
+		doins "${T}"/fontconfig.properties
+	fi
+
+	# This needs to be done before CDS - #215225
+	java-vm_set-pax-markings "${ddest}"
+
+	# see bug #207282
+	einfo "Creating the Class Data Sharing archives"
+	case ${ARCH} in
+		arm|ia64)
+			${ddest}/bin/java -client -Xshare:dump || die
+			;;
+		x86)
+			${ddest}/bin/java -client -Xshare:dump || die
+			# limit heap size for large memory on x86 #467518
+			# this is a workaround and shouldn't be needed.
+			${ddest}/bin/java -server -Xms64m -Xmx64m -Xshare:dump || die
+			;;
+		*)
+			${ddest}/bin/java -server -Xshare:dump || die
+			;;
+	esac
+
+	# Remove empty dirs we might have copied.
+	find "${D}" -type d -empty -exec rmdir -v {} + || die
+
+	set_java_env
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}