[gentoo-commits] repo/gentoo:master commit in: mate-extra/mate-sensors-applet/

["NP Hardass" <np-hardass@gentoo.org>]

commit:     60e0cd720791cf42671ef89c1f9e398f5fbd5f25
Author:     NP-Hardass <NP-Hardass <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  9 01:39:39 2016 +0000
Commit:     NP Hardass <np-hardass <AT> gentoo <DOT> org>
CommitDate: Tue Feb  9 02:46:45 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=60e0cd72

mate-extra/mate-sensors-applet: Import 1.10.x from Project:MATE repo

Package-Manager: portage-2.2.26

 mate-extra/mate-sensors-applet/Manifest            |  1 +
 .../mate-sensors-applet-1.10.4-r1.ebuild           | 72 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/mate-extra/mate-sensors-applet/Manifest b/mate-extra/mate-sensors-applet/Manifest
index 4089b03..c13b754 100644
--- a/mate-extra/mate-sensors-applet/Manifest
+++ b/mate-extra/mate-sensors-applet/Manifest
@@ -1 +1,2 @@
+DIST mate-sensors-applet-1.10.4.tar.xz 377664 SHA256 dbcada771877ddbfd9c95945e6e776dcf6789ab2f74920c0be6daa283858d795 SHA512 3f6521d605f66cc0c836a605988415293af0b63ddf0ef3ace4712c136f8da1394b95ccc8ca2ead454a706d36711d067d38b7cfc1c0c4dce8952363770e373e0b WHIRLPOOL e4a0d0fef7578d258afc3125ece56ad02092339f3b4f0f074fccccd1909d2ec252ec6b1e7d0901d4277c50675b3ccb1fcd997bd0eb457d980c4dff9f4f30934f
 DIST mate-sensors-applet-1.8.0.tar.xz 352128 SHA256 9bc6f42eae4b866f83d0fa9566e0111fd379dc6cf9dcc020b1fcca1c8a49d410 SHA512 8074900157c0d62b060f273fa975efcfa3808afb9c81c44089c1f255ce95ed34744070f98893d7b6bbb16d076ae7b7ddec391ef46459e06646d2586797df85fc WHIRLPOOL d245ed9cce0a9bd9eed1e3996529227e3fa909ba9dba37975599409783bd7f34ead6ca0d477dbac6d41462c85ba599ecb14f18a80e6ab604a29bfce413289bfe

diff --git a/mate-extra/mate-sensors-applet/mate-sensors-applet-1.10.4-r1.ebuild b/mate-extra/mate-sensors-applet/mate-sensors-applet-1.10.4-r1.ebuild
new file mode 100644
index 0000000..8b53e02
--- /dev/null
+++ b/mate-extra/mate-sensors-applet/mate-sensors-applet-1.10.4-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 eutils versionator
+
+MATE_BRANCH="$(get_version_component_range 1-2)"
+
+SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
+DESCRIPTION="MATE panel applet to display readings from hardware sensors"
+HOMEPAGE="http://mate-desktop.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+dbus hddtemp libnotify lm_sensors video_cards_fglrx video_cards_nvidia"
+
+RDEPEND="app-text/rarian:0
+	>=dev-libs/glib-2.36:2
+	>=mate-base/mate-panel-1.10:0
+	>=x11-libs/cairo-1.0.4:0
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-2.24:2
+	virtual/libintl:0
+	hddtemp? (
+		dbus? (
+			>=dev-libs/dbus-glib-0.80:0
+			>=dev-libs/libatasmart-0.16:0 )
+		!dbus? ( >=app-admin/hddtemp-0.3_beta13:0 ) )
+	libnotify? ( >=x11-libs/libnotify-0.7:0 )
+	lm_sensors? ( sys-apps/lm_sensors:0 )
+	video_cards_fglrx? ( x11-drivers/ati-drivers:* )
+	video_cards_nvidia? ( || (
+		>=x11-drivers/nvidia-drivers-100.14.09:0[static-libs,tools]
+		media-video/nvidia-settings:0
+	) )"
+
+DEPEND="${RDEPEND}
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools:0
+	dev-util/intltool:*
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+# Requires libxslt only for use by gnome-doc-utils.
+PDEPEND="hddtemp? ( dbus? ( sys-fs/udisks:0 ) )"
+
+src_configure() {
+	local myconf
+
+	if use hddtemp && use dbus; then
+		myconf="${myconf} $(use_enable dbus udisks)"
+	else
+		myconf="${myconf} --disable-udisks"
+	fi
+
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable libnotify) \
+		$(use_with lm_sensors libsensors) \
+		$(use_with video_cards_fglrx aticonfig) \
+		$(use_with video_cards_nvidia nvidia) \
+		${myconf}
+}
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"