[gentoo-commits] repo/gentoo:master commit in: app-text/apvlv/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     1563003afc5abf3ff5fb84fa84a6a0c8024ec223
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 30 10:45:25 2016 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Jan 30 12:23:04 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1563003a

app-text/apvlv: Disable optional webkit support to not rely on obsolete versions (with security issues (#572980)

Package-Manager: portage-2.2.27

 app-text/apvlv/apvlv-0.1.5-r1.ebuild | 62 ++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/app-text/apvlv/apvlv-0.1.5-r1.ebuild b/app-text/apvlv/apvlv-0.1.5-r1.ebuild
new file mode 100644
index 0000000..e91b58b
--- /dev/null
+++ b/app-text/apvlv/apvlv-0.1.5-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils cmake-utils gnome2-utils
+
+DESCRIPTION="Alf's PDF Viewer Like Vim"
+HOMEPAGE="https://naihe2010.github.com/apvlv/"
+SRC_URI="https://github.com/naihe2010/apvlv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug djvu"
+
+RDEPEND="
+	>=app-text/poppler-0.18:=[cairo,xpdf-headers(+)]
+	dev-libs/glib:2
+	x11-libs/gtk+:3
+	djvu? ( app-text/djvu:= )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# preserve cflags
+	epatch "${FILESDIR}/${PN}-0.1.5-cflags.patch"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONFDIR=/etc/${PN}
+		-DDOCDIR=/usr/share/${PN}
+		-DMANDIR=/usr/share/man
+		-DAPVLV_WITH_HTML=OFF
+		-DAPVLV_WITH_UMD=OFF
+		-DAPVLV_WITH_TXT=ON
+		$(cmake-utils_use djvu APVLV_WITH_DJVU)
+		$(cmake-utils_use debug APVLV_ENABLE_DEBUG)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc AUTHORS NEWS README THANKS TODO
+	newicon -s 32 icons/pdf.png ${PN}.png
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}